PDF file created from Oracle Report is attached wrongly

Question

Hi,
Please help. It is very urgent.
I am using Oracle Developer 10gR2, Oracle Report 10.1.2 on Windows 2000.
I would like to attach the PDF file created by Oracle Report to the Notification sent from Workflow.
I use the following package procedure in my Workflow.
procedure Create_File_Attachment (document_id   in varchar2, display_type  in varchar2, document      in out blob, document_type in out varchar2)
is
     l_itemtype          varchar2(100);
     l_itemkey           varchar2(100);
     l_output_directory  varchar2(30);
     l_filename          varchar2(255);
     src_loc             bfile;
     bdoc                blob;
     src_offset          number := 1;
     dst_offset          number := 1;
     amount              number;
begin
     l_itemtype := substr(document_id, 1, instr(document_id, ':') - 1);
     l_itemkey := substr(document_id, instr(document_id, ':') + 1, length(document_id) - 2);
     l_output_directory := 'USR_TMP_DIR';
     l_filename := Wf_Engine.GetItemAttrText(l_itemtype, l_itemkey, 'ATR_FILENAME');
     src_loc := bfilename(l_output_directory,l_filename);
     dbms_lob.createTemporary(bdoc, FALSE, dbms_lob.call);
     dbms_lob.fileopen(src_loc, dbms_lob.file_readonly);
     dbms_lob.loadblobfromfile(bdoc,src_loc,dbms_lob.lobmaxsize,src_offset,dst_offset);
     dbms_lob.fileclose(src_loc);
     amount := dbms_lob.getLength(bdoc);
     dbms_lob.copy(document,bdoc,amount,1,1);
     document_type := 'application/pdf; name=attach.pdf';
end Create_File_Attachment;Oracle Report created the PDF file correctly (original.pdf).
I tried to attach the PDF into my Workflow.
I can see the file is attached (attach.pdf), but it cannot be opened.
The Adobe shows : 'A drawing error occured.' each time I open the attachment.
I compare the original.pdf and the attach.pdf
However, there is one specific difference
- in original.pdf, the line started with '.' (single period)
in attach.pdf, the line is started with '..' (two periods)
Thus the attachment cannot be opened.
After I delete the period, it can be opened.
Question:
- Has someone ever succeed in attaching the PDF created from Report?
- Are the codes above is wrong?
- Or perhaps the DBMS_LOB.LOADBLOBFROMFILE always double the single period on front of the line?
- Is there any solution on this?
Note:
I have succeed in attaching PDF files unless the PDF created by the Report.
Sorry for the long post.
Please help. It is very urgent.
Any help is appreciated.
Many thanks,
Buntoro

Answer 1

The code looks absolutely good. I have the same code working in my system. Only difference is I use TRUE and DBMS_LOB.Session for the BLOB I use to read from the BFILE.
I can suggest one more way to handle to binary attachments if you are on Oracle 9i DB are later versions.
procedure attach_document (p_document_id   in varchar2,
                           p_display_type  in varchar2,
                           p_document      in out nocopy clob,
                           p_document_type in out nocopy varchar2)
is
  l_nid        number;
  l_directory  varchar2(100);
  l_filename   varchar2(100);
  l_content_type varchar2(100);
  l_src_offset binary_integer := 1;
  l_dst_offset binary_integer := 1;
  l_err_msg    varchar2(100);
  l_amount     number;
  l_bfile BFILE;
  l_blob  BLOB;
  l_clob  CLOB;
  file_not_found exception;
  pragma EXCEPTION_INIT(file_not_found, -22288);
begin
  l_nid := to_number(p_document_id);
  l_directory := trim(wf_notification.GetAttrText(l_nid, 'ATTR_DIRECTORY'));
  l_filename := trim(wf_notification.GetAttrText(l_nid, 'ATTR_FILENAME'));
  l_content_type := trim(wf_notification.GetAttrText(l_nid, 'ATTR_CONTENT_TYPE'));
  l_bfile := BFILENAME(l_directory, l_filename);
  dbms_lob.createtemporary(l_blob, true, dbms_lob.Session);
  dbms_lob.createtemporary(l_clob, true, dbms_lob.Session);
  begin
    dbms_lob.FileOpen(l_bfile, dbms_lob.File_Readonly);
  exception
    when file_not_found then
      l_err_msg := to_char(sqlcode)||' - Attachment File "'||l_filename||'" is not found.';
      raise_application_error(-20002, l_err_msg);
  end;
  dbms_lob.LoadBLOBFromFile(l_blob, l_bfile, dbms_lob.LobMaxSize, l_src_offset, l_dst_offset);
  dbms_lob.FileClose(l_bfile);
  -- Encode the BLOB content to BASE64 and attach to notification  
  wf_mail_util.EncodeBLOB(l_blob, l_clob);
  l_amount := dbms_lob.GetLength(l_clob);
  dbms_lob.Copy(p_document, l_clob, l_amount, 1, 1);
  -- Mention an appropriate Content Type so that Notification System
  -- understands the attachment content
  p_document_type := l_content_type||'; encoding=base64; name='||l_filename;
end attach_document;Here I read the BLOB from the filesystem and base64 encode it before giving it to the Mailer. Please note that this is a PLSQLCLOB based attachment as against PLSQLBLOB that you are using.
Thanks - Vijay