Performance issue with BSEG

Question

Hi,
          I am having serious performance issue due to BSEG table .I am having a change request in which I have to solve the performance issue with regard to BSEG. The situation was that previously they had used select * on both BKPF and BSEG. I removed the select * and selected only those fields which are required as shown below. I also tried using cursors. But the problem is happening in the TEST server where BSEG is having more than 1 crore entries. I have gone through some threads but still not able to understand how to solve this problem. Please help
select bukrs belnr gjahr bldat bstat from bkpf into table T_BKPF_p
                                                WHERE BUKRS IN sd_bukrs AND
                                                BLDAT < s_bldat-low
                                                and  BSTAT = ' ' .
select bukrs belnr gjahr shkzg dmbtr hkont from bseg into table T_BSEG_C
                                        FOR ALL ENTRIES IN t_BKPF_p
                                        WHERE BUKRS = T_bkpf_p-bukrs
                                        AND   BELNR = T_bkpf_p-belnr
                                        AND   GJAHR = T_bkpf_p-gjahr
                                        AND   HKONT = SKB1-SAKNR.

Answer 1

Hi Kunal,
Here is my take on your issue.
In your select statement on BKPF you are selecting every BKPF record for a specified company code and blank document status that was created before a specified date. If your company has implemented SAP 10 years ago, and your user enters todays date and leaves the company code field blank you will effectively be retrieving almost all the records from BKPF (excluding the ones created today or those with non-blank document status). This would effectively be a huge amount of data. After that you are looking for the corresponding BSEG records for all the records that you have selected in BKPF.
My question to you is why do you need to look at all the records before a given date? Why not ask the user to enter a smaller date range and make the document date and the company code a mandatory entry? You do not have to look at 10 years worth of data especially if you are running this online (as opposed to in the background).
Your BSEG select looks correct. There is very little that you can do except for adding BUZEI to the field list. If you use for all entries and do not include the entire primary key you could lose data.
TABLES: bkpf,
        skb1.
SELECT-OPTIONS: s_bldat  FOR bkpf-bldat OBLIGATORY,
                sd_bukrs FOR bkpf-bukrs OBLIGATORY.
TYPES: BEGIN OF ty_bkpf,
        bukrs TYPE bkpf-bukrs,
        belnr TYPE bkpf-belnr,
        gjahr TYPE bkpf-gjahr,
        bldat TYPE bkpf-bldat,
        bstat TYPE bkpf-bstat,
      END OF ty_bkpf,
      BEGIN OF ty_bseg,
        bukrs TYPE bseg-bukrs,
        belnr TYPE bseg-belnr,
        gjahr TYPE bseg-gjahr,
        buzei TYPE bseg-buzei,
        shkzg TYPE bseg-shkzg,
        dmbtr TYPE bseg-dmbtr,
        hkont TYPE bseg-hkont,
      END OF ty_bseg.
DATA: t_bkpf_p TYPE TABLE OF ty_bkpf,
      t_bseg_c TYPE TABLE OF ty_bseg.
SELECT bukrs
       belnr
       gjahr
       bldat
       bstat
FROM bkpf
INTO TABLE t_bkpf_p
WHERE bukrs IN sd_bukrs
AND   bldat IN s_bldat
AND   bstat EQ space .
IF NOT t_bkpf_p[] IS INITIAL.
  SELECT bukrs
         belnr
         gjahr
         buzei
         shkzg
         dmbtr
         hkont
    FROM bseg
    INTO TABLE t_bseg_c
    FOR ALL ENTRIES IN t_bkpf_p
    WHERE bukrs EQ t_bkpf_p-bukrs
    AND   belnr EQ t_bkpf_p-belnr
    AND   gjahr EQ t_bkpf_p-gjahr
    AND   hkont EQ skb1-saknr.
ENDIF.