PL/SQL Max character

Question

Hi All,
What is the maximum length that can be stored in a variable for executing a query.
var := 'SELECT * FROM TAB WHERE A='CLKJDJFAJDJFLA' AND B='DFLKAJSFJSKLAFJL'
UNION ALL
SELECT * FROM TAB WHERE A='CLKJDJFAJDJFLA' AND B='DFLKAJSFJSKLAFJL
UNION ALL
SELECT * FROM TAB WHERE A='CLKJDJFAJDJFLA' AND B='DFLKAJSFJSKLAFJL
UNION ALL
SELECT * FROM TAB WHERE A='CLKJDJFAJDJFLA' AND B='DFLKAJSFJSKLAFJL
execute query using var.
Thanks & Regards,
CDPrasad

Answer 1

cdprasad wrote:
Hi all,
As suggested
I'm trying to run a SQL query in PL/SQL which is of lenght more than 32000 bytes.
Since execute immediate cannot execute CLOB datatype,It can in 11g r2 onwards.
Im divinding the strings into multiple pieces and trying to store in a varchar2(32000) datatype.
Then I'l append these variables in execute immediate statement. I donno whether it will work or not.Right sort of idea (for 10g), but not with execute immediate. You have to use DBMS_SQL package instead and split it into 256 character chunks for the DBMS_SQL.VARCHAR2S array structure...
SQL> ed
Wrote file afiedt.buf
  1  declare
  2    v_large_sql  CLOB;
  3    v_num        NUMBER := 0;
  4    v_upperbound NUMBER;
  5    v_sql        DBMS_SQL.VARCHAR2S;
  6    v_cur        INTEGER;
  7    v_ret        NUMBER;
  8  begin
  9    -- Build a very large SQL statement in the CLOB
10    LOOP
11      IF v_num = 0 THEN
12        v_large_sql := 'CREATE VIEW vw_tmp AS SELECT ''The number of this row is : '||to_char(v_num,'fm0999999')||''' as col1 FROM DUAL';
13      ELSE
14        v_large_sql := v_large_sql || ' UNION ALL SELECT ''The number of this row is : '||to_char(v_num,'fm0999999')||''' as col1 FROM DUAL';
15      END IF;
16      v_num := v_num + 1;
17      EXIT WHEN DBMS_LOB.GETLENGTH(v_large_sql) > 40000 OR v_num > 800;
18    END LOOP;
19    DBMS_OUTPUT.PUT_LINE('Length:'||DBMS_LOB.GETLENGTH(v_large_sql));
20    DBMS_OUTPUT.PUT_LINE('Num:'||v_num);
21    --
22    -- Now split that large SQL statement into chunks of 256 characters and put in VARCHAR2S array
23    v_upperbound := CEIL(DBMS_LOB.GETLENGTH(v_large_sql)/256);
24    FOR i IN 1..v_upperbound
25    LOOP
26      v_sql(i) := DBMS_LOB.SUBSTR(v_large_sql
27                                 ,256 -- amount
28                                 ,((i-1)*256)+1 -- offset
29                                 );
30    END LOOP;
31    --
32    -- Now parse and execute the SQL statement
33    v_cur := DBMS_SQL.OPEN_CURSOR;
34    DBMS_SQL.PARSE(v_cur, v_sql, 1, v_upperbound, FALSE, DBMS_SQL.NATIVE);
35    v_ret := DBMS_SQL.EXECUTE(v_cur);
36    DBMS_OUTPUT.PUT_LINE('View Created');
37* end;
SQL> /
Length:40015
Num:548
View Created
PL/SQL procedure successfully completed.
SQL> select count(*) from vw_tmp;
  COUNT(*)
       548
SQL> select * from vw_tmp where rownum <= 10;
COL1
The number of this row is : 0000000
The number of this row is : 0000001
The number of this row is : 0000002
The number of this row is : 0000003
The number of this row is : 0000004
The number of this row is : 0000005
The number of this row is : 0000006
The number of this row is : 0000007
The number of this row is : 0000008
The number of this row is : 0000009
10 rows selected.
SQL>