Pl/sql or numeric value error

Question

Hi
I'm trying to append CLOB to CLOB (assuming both are not null and lenght is less than the max allowed) and getting the error, Why is that error coming, the length cobined is only 50k.
PK_UTILITIES.sp_get_recs(site_id_i, entity_id_i, false, v_clob_str);
v_len := DBMS_LOB.getlength(v_clob_str);
IF (NVL(v_len,0) > 0 ) THEN
DBMS_OUTPUT.PUT_LINE('Length: '||v_len);
DBMS_LOB.WRITEAPPEND(XML_o,length(v_clob_str),v_clob_str);
END IF;
Thanks in advance
Murthy

Answer 1

We are using the same DBMS_LOB.appendAs I said above, you must do a DBMS_LOB.CreateTemporary to create and populate a LOB correctly.
SQL> declare
  2    lob CLOB ;
  3  begin
  4    for idx in 1 .. 100
  5    loop
  6      dbms_lob.writeappend(lob, 4000, RPAD('*', 4000, '*')) ;
  7    end loop ;
  8    dbms_output.put_line(dbms_lob.getlength(lob)) ;
  9  end ;
10  /
declare
ERROR at line 1:
ORA-06502: PL/SQL: numeric or value error: invalid LOB locator specified: ORA-22275
ORA-06512: at "SYS.DBMS_LOB", line 789
ORA-06512: at line 6
SQL> declare
  2    lob CLOB ;
  3  begin
  4    lob := NULL ;
  5    for idx in 1 .. 100
  6    loop
  7      dbms_lob.writeappend(lob, 4000, RPAD('*', 4000, '*')) ;
  8    end loop ;
  9    dbms_output.put_line(dbms_lob.getlength(lob)) ;
10  end ;
11  /
declare
ERROR at line 1:
ORA-06502: PL/SQL: numeric or value error: invalid LOB locator specified: ORA-22275
ORA-06512: at "SYS.DBMS_LOB", line 789
ORA-06512: at line 7
SQL> declare
  2    lob CLOB ;
  3  begin
  4    dbms_lob.createtemporary(lob, TRUE) ;
  5    for idx in 1 .. 100
  6    loop
  7      dbms_lob.writeappend(lob, 4000, RPAD('*', 4000, '*')) ;
  8    end loop ;
  9    dbms_output.put_line(dbms_lob.getlength(lob)) ;
10    dbms_lob.freetemporary(lob) ;
11  end ;
12  /
400000
PL/SQL procedure successfully completed.
SQL>