Please Help. compare two excel files. Can't get the find command to work

Question

Hello, I'm new to applescript.  I'm trying to write a script to compare column B of one excel file to column B of the another excel file.
I will have to had a repeat loop to proceed down the column but I'm stuck on the find command. 
Below is some of the code I have so far.  The applescript error message is "Microsoft Excel got an error: The object you are trying to access does not exist. It highlights the find column." 
set patientFile to choose file with prompt "Please select the patient Excel file:"
set patientName to name of (info for patientFile)
tell application "Microsoft Excel"
open patientFile
set thepatientFile to workbook patientName
end tell
display dialog "Is your patient SNP data in column B of the " & " " & patientName & " " & "excel file?" buttons {"No", "Yes"} default button 2
if the button returned of the result is "No" then
display dialog "Please put your data in column B" buttons {"Cancel"} default button 1
if the button returned of the result is "Cancel" then
end if
else
display dialog "Is column E empty? The results of this program will be stored in column E of the" & " " & patientName & " " & "excel file." buttons {"No", "Yes"} default button 2
if the button returned of the result is "No" then
  display dialog "Please put your data in empty column E" buttons {"Cancel"} default button 1
  if the button returned of the result is "Cancel" then
  end if
else
  set relativeFile to choose file with prompt "Please select the relative Excel file:"
  set relativeName to name of (info for relativeFile)
  tell application "Microsoft Excel"
  open relativeFile
  set therelativeFile to workbook relativeName
  end tell
end if
end if
display dialog "Is your relative SNP data in column B of the" & " " & relativeName & " " & "excel file?" buttons {"No", "Yes"} default button 2
if the button returned of the result is "No" then
display dialog "Please put your data in column B" buttons {"Cancel"} default button 1
if the button returned of the result is "Cancel" then
end if
else
display dialog "Does column C contain the result data you would like copied from" & " " & relativeName & " " & "excel file?" buttons {"No", "Yes"} default button 2
if the button returned of the result is "No" then
  display dialog "Please put the data you would like copied in column C." buttons {"Cancel"} default button 1
  if the button returned of the result is "Cancel" then
  end if
else
  tell application "Microsoft Excel"
  activate object workbook patientName
  copy value of cell "A1" to cellPatientFile
  find (range "B:B" of workbook relativeName) what cellPatientFile
  if cellPatientFile is true then
  set bold of font object of cellPatientFile to true
  end if
  end tell
end if
end if
Does any one have any hints towards solving this problem?  Thank you for any help.

Answer 1

Hi,
taffners wrote:
Thank you everyone for your help.  I attached my code.  It works now but kinda slow.  Does anyone have any hints on making it faster.
Important : when you use the find command, it's preferable to use the properties ( look in and look at).
Example : find searchRange what searchTerm look in values look at whole
Otherwise, it will search according to the criteria of your last find.
Example, if you uncheck 'Find entire cells only', and after that you run the script,
find column 2 what 10.0 -->  match 110.0 or 1110.0 or 310.0, .... , because it look at part.
set screen updating to false : Yes it improves the speed.
Here are my tests (no duplicate values in the Excel column ) on old computer (Powermac G5) .
set screen updating to false without any activate object command
2000 rows --> 3.7 minutes,  your script : 11.5 minutes
4000 rows --> 7.5 minutes, your script : 23 minutes
8000 rows --> 15 minutes,  your script : 46 minutes
But, it's faster to search through a list without using the Excel find command, no need to set the screen updating, You can continue working on the workbook or another workbook, this will not disturb the script.
Tests on my script :
2000 rows --> 4 seconds
4000 rows --> 21 seconds
8000 rows --> 1.3 minutes
17000 rows --> 6 minutes
Here is the script :
main()
display dialog "Done"
on main()
      script o
            property patientSNP_list : {}
            property relativeSNP_list : {}
            property resultsList : {}
            property copyAnswerList : {}
            on findLookAtWhole(value) -- case sensitive
                  set {low, high} to {1, count my relativeSNP_list}
                  considering case
                        repeat while low ≠ high
                              set mid_ to (low + high) div 2
                              if value is in items low thru mid_ of my relativeSNP_list then
                                    set high to mid_
                              else
                                    set low to mid_ + 1
                              end if
                        end repeat
                  end considering
                  if (item low of my relativeSNP_list is value) then
                        set end of my resultsList to item low of my copyAnswerList
                  else
                        set end of my resultsList to {"no"}
                  end if
            end findLookAtWhole
      end script
      --opens File1.  Names it patientName
      set patientFile to choose file with prompt "Please select the patient Excel file:"
      set patientName to name of (info for patientFile)
      tell application "Microsoft Excel"
            open patientFile
            set thepatientFile to workbook patientName
            set patientSheet to sheet (name of active sheet) of thepatientFile
      end tell
      --This Dialog assigns where the data is stored for file1
      display dialog "What Column is your patient SNP data of the " & " " & patientName & " " & "excel file?" default answer "" buttons {"submit"} default button 1
      set PatientSNPCol to (text returned of the result)
      --This Dialog assigns what row your data starts at for file1
      display dialog "What row does your patient SNP data start in the " & " " & patientName & " " & "excel file?" default answer "" buttons {"submit"} default button 1
      set patientSNPRow to (text returned of the result)
      set patientStartCell to PatientSNPCol & patientSNPRow
      --This Dialog assigns the last row of data for file1
      display dialog "What row is the last row of you patient SNP data start of the " & " " & patientName & " " & "excel file?" default answer "" buttons {"submit"} default button 1
      set patientLastRow to (text returned of the result)
      set patientLastCell to PatientSNPCol & patientLastRow
      --This Dialog assigns the location of the data copied from file2
      display dialog "What column would you like the results of this program stored in of the" & " " & patientName & " " & "excel file." default answer "" buttons {"submit"} default button 1
      set resultsLocation to (text returned of the result)
      --opens File2.  Names it relativeName
      set relativeFile to choose file with prompt "Please select the relative Excel file:"
      set relativeName to name of (info for relativeFile)
      tell application "Microsoft Excel"
            open relativeFile
            set therelativeFile to workbook relativeName
            set relativeSheet to sheet (name of active sheet) of therelativeFile
      end tell
      --This dialog assigns the column of data in file2
      display dialog "What Column is your relative SNP data of the " & " " & relativeName & " " & "excel file?" default answer "" buttons {"submit"} default button 1
      set relativeSNPCol to (text returned of the result)
      --This dialog assigns the column of data begining copied to excel file1.
      display dialog "What Column contains the data you would like copied to the " & " " & patientName & " " & "excel file in column" & " " & resultsLocation & " " & "?" default answer "" buttons {"submit"} default button 1
      set copyAnswer to (text returned of the result)
      tell application "Microsoft Excel" -- get values
            set o's patientSNP_list to value of range (PatientSNPCol & patientSNPRow & ":" & PatientSNPCol & patientLastRow) of patientSheet
            set lastrow to first row index of (last cell of used range of relativeSheet)
            set o's relativeSNP_list to value of range (relativeSNPCol & "1:" & relativeSNPCol & lastrow) of relativeSheet
            set o's copyAnswerList to value of range (copyAnswer & "1:" & copyAnswer & lastrow) of relativeSheet
      end tell
      set tc to (count o's relativeSNP_list)
      repeat with i from 1 to tc --convert list of lists to one list
            set item i of o's relativeSNP_list to item 1 of item i of o's relativeSNP_list
      end repeat
      set tc to (count o's patientSNP_list)
      repeat with i from 1 to tc -- AppleScript find method, not the Excel Find
            o's findLookAtWhole(item 1 of (item i of o's patientSNP_list))
      end repeat
      tell application "Microsoft Excel" -- set values
            set value of range (resultsLocation & patientSNPRow & ":" & resultsLocation & patientLastRow) of patientSheet to o's resultsList
      end tell
end main
If you have lots of rows and you want it to go faster.
I have another script that uses the power of (/usr/bin/awk and his associative arrays) in a do shell script
17000 rows --> awk : 2 seconds, applescript : 6 seconds, total : 8 seconds
34000 rows --> awk : 3 seconds, applescript : 11 seconds, total : 14 seconds