Please help converting filenames

Question

Thanks a lot for your help
I am trying to set the creation date as the new file name in series of files within a folder
I try to modify various scripts I found for my purpose
[applescript]
set source_folder to choose folder with prompt "Please select directory."
set destination to choose folder with prompt "Please select directory."
tell application "Finder"
          set file_list to every file of folder source_folder
end tell
tell application "Finder"
          launch
          try
                    duplicate source_folder to destination
          on error errorMsg number errorNum
                    display dialog "Error (" & errorNum & "):" & return & return & errorMsg buttons "Cancel" default button 1 with icon caution
          end try
          repeat with aFile in file_list
                    set file_info to info for (aFile as alias)
                    set file_creation_date to creation date of file_info
                    set tPath to quoted form of (POSIX path of aFile)
                    set tName to name of (info for aFile)
                    set MD to do shell script "mdls -name kMDItemContentCreationDate " & aFile
                    set TID to AppleScript's text item delimiters
                    set AppleScript's text item delimiters to "= ("
                    set tDates to text item 1 of MD
                    set AppleScript's text item delimiters to ")"
                    set tDates to (text item 1 of tDates) as text
                    set AppleScript's text item delimiters to TID
                    set dateInfo to text 30 thru -1 of tDates
                    set newFilename to dateInfo
                    try
                              tell application "Finder" to set name of aFile to newFilename
                    end try
          end repeat
end tell
[/applescript]
the error I get is:
Can’t make «class docf» "10 - TXT.doc" of «class cfol» "result" of «class cfol» "newfolder" of «class cfol» "ecco" of «class cfol» "my folder" of «class cfol» "Documents" of «class cfol» "ZZZ" of «class cfol» "Users" of «class sdsk» of application "Finder" into the expected type.

Answer 1

OK, to do that you just need to tell the Finder to duplicate the file first (you had originally set a destination folder, but didn't do anything with it) - note that there isn't any error handing (a duplicate file name for example), the script just logs the error:
set source_folder to (choose folder with prompt "Please select source directory.")
set destination to choose folder with prompt "Please select destination directory."
tell application "Finder"
   set file_list to every file of folder source_folder as alias list
end tell
repeat with aFile in file_list
   set tPath to quoted form of POSIX path of aFile
   set newFilename to (do shell script "mdls -name kMDItemContentCreationDate -raw " & tPath)
   set TID to AppleScript's text item delimiters
   set AppleScript's text item delimiters to ":"
   set pieces to text items of newFilename
   set AppleScript's text item delimiters to "-"
   set newFilename to pieces as text
   set AppleScript's text item delimiters to TID
   try
      tell application "Finder"
         set copiedFile to (duplicate aFile to destination)
         set name of copiedFile to newFilename
         -- set name of copiedFile to text 1 thru 19 of newFilename -- strip off time offset
      end tell
   on error errorMsg number errorNum
      log errorMsg
   end try
end repeat
You can find information about the AppleScript language in the AppleScript Language Guide, and an application's scripting dictionary (if it has one) can be opened in the AppleScript Editor to view the additional commands that it provides.