Plsql table initialize

Question

hi,
plz help regarding initializing a plsql table
declare
type numlist is table of integer;
nums numlist;
c varcar2(20) := '10,20,30'
begin
nums := numlist(c); --i want to use the variable here but it's showing error
end;
i need a method for this. the value is coming through a comma separated string.
plz help me out.
regards,
akp

Answer 1

AKP,
Try this:
declare
  type numlist is table of integer index by binary_integer;
  nums numlist;
  c varchar2(200) := '10, 20, 30';
  procedure comma_to_array (i_list in varchar2, o_array out numlist)
  is
    l_list varchar2(4000) := i_list;
    l_first_comma binary_integer;
    i binary_integer := 1;
  begin
    while length(l_list) > 0 loop
      l_first_comma := instr(l_list, ',');
      begin
        if l_first_comma > 0 then
          o_array(i) := to_number(substr(l_list, 1, l_first_comma-1));
        else
          o_array(i) := to_number(l_list);
          l_first_comma := length(l_list);
        end if;
      exception
        when others then
          -- Handle errors of number conversion here. For this example simply setting value to -1
          o_array(i) := -1;
      end;
      l_list := substr(l_list, l_first_comma+1);
      i := i + 1;
    end loop;     
  end comma_to_array;
begin
  comma_to_array(c, nums);
  if nums.count > 0 then
    for i in nums.first .. nums.last
    loop
      dbms_output.put_line('num('||i||')='||nums(i));
    end loop;
  end if;
end;I hope that helps.
-Roger