Possible bug with TREAT and EXECUTE IMMEDIATE

Question

Hello, i experienced a strange behavior which seems to be a bug.
Consider following definitions:
CREATE OR REPLACE TYPE T_Base FORCE AS OBJECT (
  DummyProperty NUMBER
) NOT FINAL;
CREATE OR REPLACE TYPE T_Child UNDER T_Base (
  AnotherDummyProperty  NUMBER
CREATE OR REPLACE FUNCTION SpecificValidation (iValue T_Child) RETURN NUMBER IS
BEGIN
  -- some specific validation is done here, not important for the example
  RETURN NULL;
END;
CREATE OR REPLACE PROCEDURE ValidateIt (iValue T_Child) IS
  lResult NUMBER;
BEGIN
  -- The principle used here is that each client can have its own implementation of validation function, and when it does not exist, we do not care.
  -- In reality we put functions and procedures into packages, I narrowed it to a minimal working example.
  BEGIN
    EXECUTE IMMEDIATE 'BEGIN :lResult := SpecificValidation(:iValue); END;'
      USING OUT lResult, IN iValue;
  EXCEPTION WHEN OTHERS THEN
    IF INSTR(SQLERRM, 'PLS-00201') = 0 THEN
      RAISE;
    END IF;
  END;
END;
CREATE OR REPLACE PROCEDURE Process (iValue T_Base) IS
BEGIN
  -- in fact we know that iValue must be of typ T_Child, it is checked using IS OF ( ) operator and exception is raised if this check fails
  -- This does not work for some reason.
  -- It fails in EXECUTE IMMEDIATE with PLS-00306. I don't really get why, because ValidateIt accepts a value of type T_Child and it passes it to the validation procedure, which also expects value of type T_Child.
  ValidateIt(TREAT(iValue AS T_Child));
END;
CREATE OR REPLACE PROCEDURE Process2 (iValue T_Base) IS
  lChild  T_Child;
BEGIN
  -- The only difference here is that result of TREAT is saved to a variable.
  -- This works as expected.
  lChild := TREAT(iValue AS T_Child);
  ValidateIt(lChild);
END;
In reality it is much more complex, I narrowed it to a minimal working example.
Now when running this:
DECLARE
  lItem T_Base := T_Child(5, 2);
BEGIN
  BEGIN
    -- This call will end up with PLS-00306 error.
    Process(lItem);
    dbms_output.put_line('Process completed successfully.');
  EXCEPTION WHEN OTHERS THEN
    dbms_output.put_line('Exception when calling Process.');
    dbms_output.put_line(SQLERRM);
    dbms_output.put_line(DBMS_UTILITY.FORMAT_ERROR_BACKTRACE);
  END;
  BEGIN
    Process2(lItem);
    dbms_output.put_line('Process2 completed successfully.');
  EXCEPTION WHEN OTHERS THEN
    dbms_output.put_line('Exception when calling Process2.');
    dbms_output.put_line(SQLERRM);
    dbms_output.put_line(DBMS_UTILITY.FORMAT_ERROR_BACKTRACE);
  END;
END;
then call to Process fails with PLS-00306 on EXECUTE IMMEDIATE.
The only difference between Process and Process2 is that in Process2, result of TREAT is saved to a variable of type T_Child.
Is this behavior documented somwhere or is it a bug?

Answer 1

That's interesting. I would say it is, or should be, a bug.
Also interesting is, when I re-write your example to eliminate dynamic SQL and instead rely on dynamic method dispatch, the problem goes away... first, the changes:
drop type T_Child;
drop type T_Base
CREATE OR REPLACE TYPE T_Base FORCE AS OBJECT ( 
  DummyProperty NUMBER 
) NOT FINAL
CREATE OR REPLACE TYPE T_Child UNDER T_Base ( 
  AnotherDummyProperty  NUMBER 
create or replace type T_Base_Processor as object (
  dummyProperty    number
, static FUNCTION GetClientProcessor(iClientId varchar2) RETURN T_Base_Processor
, member FUNCTION SpecificValidation (iValue T_Child) RETURN NUMBER
, member PROCEDURE ValidateIt (iValue T_Child)
, member PROCEDURE Process (iValue T_Base)
, member PROCEDURE Process2 (iValue T_Base)
) NOT FINAL
create or replace type T_Another_Processor under T_Base_Processor (
  overriding member FUNCTION SpecificValidation (iValue T_Child) RETURN NUMBER
create or replace type body T_Base_Processor
is
  static FUNCTION GetClientProcessor(iClientId varchar2) RETURN T_Base_Processor IS
BEGIN
  return    case
        when upper(iClientId) = 'ADMINISTRATOR' then
            new T_Another_Processor(null)
        else
            new T_Base_Processor(null)
        end;
END;
  member FUNCTION SpecificValidation (iValue T_Child) RETURN NUMBER IS 
BEGIN 
  -- some specific validation is done here, not important for the example 
  dbms_output.put_line('T_Base_Processor.SpecificValidation');
  RETURN NULL; 
END; 
  member PROCEDURE ValidateIt (iValue T_Child) IS 
  lResult NUMBER; 
BEGIN 
  -- No more need for dynamic SQL, instead rely on dynamic dispatch
  lResult := SpecificValidation(iValue);
END; 
  member PROCEDURE Process (iValue T_Base) IS 
BEGIN 
  -- in fact we know that iValue must be of typ T_Child, it is checked using IS OF ( ) operator and exception is raised if this check fails 
  -- This does not work for some reason. 
  -- It fails in EXECUTE IMMEDIATE with PLS-00306. I don't really get why, because ValidateIt accepts a value of type T_Child and it passes it to the validation procedure, which also expects value of type T_Child. 
  ValidateIt(TREAT(iValue AS T_Child)); 
END; 
  member PROCEDURE Process2 (iValue T_Base) IS 
  lChild  T_Child; 
BEGIN 
  -- The only difference here is that result of TREAT is saved to a variable. 
  -- This works as expected. 
  lChild := TREAT(iValue AS T_Child); 
  ValidateIt(lChild); 
END;
end;
create or replace type body T_Another_Processor
is
  overriding member FUNCTION SpecificValidation (iValue T_Child) RETURN NUMBER
is
begin
  -- some other specific validation is done here, not important for the example 
  -- You could even call the overridden method as well using
  --   treat(self as T_Base_Processor).SpecificValidation(iValue)
  dbms_output.put_line('T_Another_Processor.SpecificValidation');
  RETURN NULL; 
end;
end;
And again with slight modifications, your test block:
DECLARE 
  lProcessor T_Base_Processor := T_Base_Processor.getClientProcessor('JOE');
  lItem T_Base := T_Child(5, 2); 
BEGIN 
  BEGIN 
    -- This call no longer throws a PLS-00306 error. 
    lProcessor.Process(lItem); 
    dbms_output.put_line('Process completed successfully.'); 
  EXCEPTION WHEN OTHERS THEN 
    dbms_output.put_line('Exception when calling Process.'); 
    dbms_output.put_line(SQLERRM); 
    dbms_output.put_line(DBMS_UTILITY.FORMAT_ERROR_BACKTRACE); 
  END; 
  -- Demonstrate dynamic dispatch by choosing a different processor
  lProcessor := T_Base_Processor.getClientProcessor('ADMINISTRATOR');
  BEGIN 
    lProcessor.Process2(lItem); 
    dbms_output.put_line('Process2 completed successfully.'); 
  EXCEPTION WHEN OTHERS THEN 
    dbms_output.put_line('Exception when calling Process2.'); 
    dbms_output.put_line(SQLERRM); 
    dbms_output.put_line(DBMS_UTILITY.FORMAT_ERROR_BACKTRACE); 
  END; 
END; 
T_Base_Processor.SpecificValidation
Process completed successfully.
T_Another_Processor.SpecificValidation
Process2 completed successfully.
Gerard