PR First release by initiator

Question

PR First release by initiator
Using standard <u><b>PR overall release</b></u>
Who ever having authorization for PR creation that person will create PR as well as will release it first. If initiator is not released it within 3 days then initiator's superior will release this. For this scenario there may be many no. of Persons to create PR.So, how to initiate one release code for many users?
Thanks and Regards,
Prabhakar Dharmala

Answer 1

You need to use the user-exit (implement enhancement M06B0001) to find the person who changed the requisition, except those users who release it. Neither do you want to identify the users who just change long texts.
I just did that little excercise myself, and basically this code snippet (placed in ZXM06U12) does it, and then you of course have to use that information in your code to set up the correct agent specification. Note, the code selects fields that are not really required, but I found them nice to have during debugging.
CONSTANTS: c_changeclass TYPE cdhdr-objectclas VALUE 'BANF'.
* Find user who changed it last - but exclude transaction codes used for release
DATA: l_latest_change_header TYPE cdhdr,
      l_latest_change        TYPE cdpos,
      l_table_key_item       TYPE cdpos-tabkey.
CONCATENATE syst-mandt i_eban-banfn i_eban-bnfpo '%'
            INTO l_table_key_item.
SELECT objectclas
       objectid
       changenr
       username
       udate
       utime
       INTO CORRESPONDING FIELDS OF l_latest_change_header
       FROM cdhdr
       WHERE objectclas =      c_changeclass AND
             objectid   =      i_eban-banfn  AND
             tcode      NOT IN ('ME54N','ME55')
       ORDER BY udate DESCENDING
                utime DESCENDING.
  SELECT changenr
         tabname
         tabkey
         fname
         chngind
         text_case
         unit_new
         cuky_new
         value_new
         INTO CORRESPONDING FIELDS OF l_latest_change
         FROM cdpos
         UP TO 1 ROWS
         WHERE objectclas =    l_latest_change_header-objectclas AND
               objectid   =    l_latest_change_header-objectid   AND
               changenr   =    l_latest_change_header-changenr   AND
               tabkey     LIKE l_table_key_item.
  ENDSELECT.
  IF syst-subrc <> 0.
    CLEAR l_latest_change_header.
  ELSE.
    EXIT.
  ENDIF.
ENDSELECT.
IF l_latest_change_header IS INITIAL.
  l_latest_change_header-username = i_eban-ernam.
  l_latest_change_header-udate    = i_eban-erdat.
ENDIF.