Printing a range of pages of report

Question

I have a main  form "classes" and two subforms ( students and grades). The classes form is linked to the students subform as one-to-many (by the class ID), whereas students is linked to grades as one-to-many(by the Students ID). I have created
a report that prints the grades for each single student in one page and it works well.  However, i want make another report to print or preview the all students of each class. For example if the Class A has 30 students, then I should have 30 pages, where
each page refer to single student grades. Any help please ??  

Answer 1

However, i want make another report to print or preview the all students of each class.
You only need one report, which by default will return all students, with each on a separate page by setting the ForceNewPage property of the StudentID group footer section to 'After Section'.
To print the report for a single student you can filter it to a selected StudentID by means of the WhereCondition argument of the OpenReport method.  Similarly you can filter it to a selected ClassID to print all students in a selected class.
To select a student or class I'd suggest you create an unbound dialogue form with two combo boxes, cboStudent and cboClass, set up as follows in the case of cboStudent:
RowSource:     SELECT StudentID, FirstName & " " & LastName FROM Students ORDER BY LastName, FirstName;
BoundColumn:   1
ColumnCount:    2
ColumnWidths:  0cm
If your units of measurement are imperial rather than metric Access will automatically convert the unit of the last one to inches.  The important thing is that the dimension is zero to hide the first column.
And for Classes:
RowSource:     SELECT ClassID, Class FROM Classes ORDER BY Class;
BoundColumn:   1
ColumnCount:    2
ColumnWidths:  0cm
In the AfterUpdate event procedure of cboClass clear any selection in cboStudent with:
    Me.cboStudent = Null
Similarly, in the AfterUpdate event procedure of cboStudent clear any selection in cboClass with:
    cboClass = Null
Add a command button to the form and in its Click event procedure put the following code:
Const REPORT_NAME = "YourReportNameGoesHere"
Const MESSAGE_TEXT = "No class or student selected"
Dim strCriteria As String
If Not IsNull(Me.cboClass) Then
    strCriteria = "ClassID = " & Me.cboClass
ElseIf Not IsNull(Me.cboStudent) Then
    strCriteria = "StudentID = " & Me.cboStudent
End If
If Len(strCriteria) > 0 Then
    DoCmd.OpenReport REPORT_NAME, WhereCondition:=strCriteria
Else
    MsgBox MESSAGE_TEXT, vbExclamation, "Invalid Operation"
End If
To print a report you open the dialogue form, select a class or student, and click the button.  You might like to have two buttons on the form, with identical code apart from the following amendment:
    DoCmd.OpenReport REPORT_NAME, View:=acViewPreview, WhereCondition:=strCriteria
so that you can preview the report as well as sending it to a printer.
Ken Sheridan, Stafford, England
Done, Marked as answer.
Many thanks