Problem in the BDC program to upload the data from a flat file.

Question

Hi,
I am required to write a BDC program to upload the data from a flat file. The conditions are as mentioned below:-
1) Selection Screen will be prompted to user and user needs to provide:- File Path on presentation server (with F4 help for this obligatory parameter) and File Separator e.g. @,#,$,%,... etc(fields in the file will be separated by using this special character) or fields may be separated by tab(tab delimited).
2) Finally after the data is uploaded, following messages need to be displayed:-
a) Total Number of records successfully uploaded.
b) Session Name
c) Number of Sessions created.
Problem is when each record is fetched from flat file, the record needs to be split into individual fields separated by delimiter or in case tab separated, then proceeding in usual manner.
It would be great if you provide me either the logic, pseudocode, or sample code for this BDC program.
Thanks,

Answer 1

Here is an example program,  if you require the delimitor to be a TAB, then enter TAB on the selection screen, if you require the delimitor to be a comma, slash, pipe, whatever, then simply enter that value.  This example is simply the uploading of the file, not the BDC, I assume that you know what to do once you have the data into the internal table.
REPORT zrich_0001.
TYPES: BEGIN OF ttab,
        rec TYPE string,
       END OF ttab.
TYPES: BEGIN OF tdat,
       fld1(10) TYPE c,
       fld2(10) TYPE c,
       fld3(10) TYPE c,
       fld4(10) TYPE c,
       END OF tdat.
DATA: itab TYPE TABLE OF ttab.
data: xtab like line of itab.
DATA: idat TYPE TABLE OF tdat.
data: xdat like line of idat.
DATA: file_str TYPE string.
DATA: delimitor TYPE string.
PARAMETERS: p_file TYPE localfile.
PARAMETERS: p_del(5) TYPE c.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  DATA: ifiletab TYPE filetable.
  DATA: xfiletab LIKE LINE OF ifiletab.
  DATA: rc TYPE i.
  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    CHANGING
      file_table = ifiletab
      rc         = rc.
  READ TABLE ifiletab INTO xfiletab INDEX 1.
  IF sy-subrc = 0.
    p_file = xfiletab-filename.
  ENDIF.
START-OF-SELECTION.
  TRANSLATE p_del TO UPPER CASE.
  CASE p_del.
    WHEN 'TAB'.
      delimitor = cl_abap_char_utilities=>horizontal_tab.
    WHEN others.
      delimitor = p_del.
  ENDCASE.
  file_str = p_file.
  CALL METHOD cl_gui_frontend_services=>gui_upload
    EXPORTING
      filename = file_str
    CHANGING
      data_tab = itab.
  LOOP AT itab into xtab.
    CLEAR xdat.
    SPLIT xtab-rec AT delimitor INTO xdat-fld1
                                     xdat-fld2
                                     xdat-fld3
                                     xdat-fld4.
    APPEND xdat to idat.
  ENDLOOP.
  LOOP AT idat into xdat.
    WRITE:/ xdat-fld1, xdat-fld2, xdat-fld3, xdat-fld4.
  ENDLOOP.
Regards,
Rich Heilman