Problem while hide a block on selection screen on button press

Question

Hi,
I have added two buttons on the application toolbar of the selection screen. I have input fields under two blocks on the selection-screen. Initially the second block is hidden. If I press the button 1 the second block should be made visible.
For this to happen, I captured the button 1 click event using the following statement.
IF sscrfields-ucomm = 'FC01'.
Inside the if ... endif, I looped at the screen and made the second block visible. It was working fine.
loop at screen.
  if screen-group4 = '013'.
     screen-invisible = 1.
     screen-active    = 0.
  endif.
endloop.
Later the second button was added. Now when i run the report for the first time, if button 2 is clicked the hidden block appears on the selection screen even though i have not added any code for it.
Just to check, i commented the logic to display the hidden block on button 1 click event. Even without any code the first time i press any of the two buttons added on the application toolbar the hidden block is displayed.
I saved a variant for the report.
During execution of the report, if i select any variant then the hidden block is displayed.
Can anyone please tell me how to fix this problem.
Regards,
T2.

Answer 1

Hi All,
The problem is solved.
Everyone was confusing between the pushbutton on the selectio-screen and on apllication toolbar
(where you have the execute icon).
Please find the code below. Thanks for you time and help. I appreciate it.
REPORT ztest.
INCLUDE <icon>.
*  TABLES                                                              *
TABLES: t001,              " Company Codes
        lfa1,              " Vendor Master (General Section)
        sscrfields.        " Fields on selection screens
* To capture button press event.
DATA: gv_button_press       TYPE c.
* Menu Painter: Program interface for dynamic texts
DATA: gs_dyntxt             TYPE smp_dyntxt.
*  SELECTION SCREEN                                                    *
SELECTION-SCREEN FUNCTION KEY 1.
SELECTION-SCREEN BEGIN OF BLOCK blk1 WITH FRAME TITLE text-s01.
* Company Code.
SELECTION-SCREEN BEGIN OF BLOCK ccode WITH FRAME TITLE text-s02.
SELECT-OPTIONS: s_bukrs FOR t001-bukrs OBLIGATORY MEMORY ID buk.
SELECTION-SCREEN END OF BLOCK ccode.
SELECTION-SCREEN END OF BLOCK blk1.
SELECTION-SCREEN BEGIN OF BLOCK dsel WITH FRAME TITLE text-s04.
* Vendor Master.
SELECTION-SCREEN BEGIN OF BLOCK vend WITH FRAME TITLE text-s07.
SELECT-OPTIONS: s_konzs FOR lfa1-konzs MODIF ID aw1.
SELECT-OPTIONS: s_txcd1 FOR lfa1-stcd1 MODIF ID aw1.
SELECT-OPTIONS: s_txcd2 FOR lfa1-stcd2 MODIF ID aw1.
SELECTION-SCREEN END OF BLOCK vend.
SELECTION-SCREEN END OF BLOCK dsel.
* INITIALIZATION                                                       *
INITIALIZATION.
* Populate the Application toolbar button attributes.
  PERFORM populate_app_toolbar_buttons.
* Hide the dynamic screen intially.
  PERFORM hide_screenfields.
* AT SELECTION SCREEN                                                  *
AT SELECTION-SCREEN.
* Capture the button press event.
  PERFORM capture_button_press.
* AT SELECTION-SCREEN OUTPUT.                                          *
AT SELECTION-SCREEN OUTPUT.
* Show/Hide the dynamic selection screen based on button press.
  PERFORM adapt_screen.
*&  Form  populate_app_toolbar_buttons                                 *
*   Display Icon on the application toolbar buttons. Also set the      *
*   function codes for these buttons.                                  *
FORM populate_app_toolbar_buttons.
  CLEAR gs_dyntxt.
  WRITE icon_fencing     TO gs_dyntxt-icon_id AS ICON.
  MOVE  text-b01         TO gs_dyntxt-quickinfo.   " Dynamic Selections
  MOVE gs_dyntxt         TO sscrfields-functxt_01.
ENDFORM.                    " populate_app_toolbar_buttons
*&  Form  hide_screenfields                                            *
*   Initially hide the Dynamic selection screen.                       *
FORM hide_screenfields.
  LOOP AT SCREEN.
    IF screen-group1 = 'AW1'.
      screen-invisible = '1'.
      screen-active    = '0'.
    ENDIF.
    MODIFY SCREEN.
  ENDLOOP.
ENDFORM.                    " hide_screenfields
*&  Form  capture_button_press                                         *
*   Set the flag based on button press event. Appication bar button    *
*   tcode is available only at 'At Selection-screen' event.            *
*   Use the captured data at 'At Selection-screen Output' event.       *
*   Screen adjustments is possible only under this event.              *
FORM capture_button_press.
  IF sscrfields-ucomm = 'FC01'.
    IF gv_button_press IS INITIAL.
      gv_button_press = 'X'.
    ELSEIF gv_button_press EQ 'X'.
      CLEAR gv_button_press.
    ENDIF.
  ENDIF.
ENDFORM.                    " capture_button_press
*&  Form  adapt_screen                                                 *
*   Show/Hide the dynamic selection screen based on button press       *
*   captured at 'At selection-screen' event.                           *
FORM adapt_screen.
* If button press flag is initial hide the dynamic selection screen.
  IF gv_button_press IS INITIAL.
    LOOP AT SCREEN.
      IF screen-group1 = 'AW1'.
        screen-invisible = '1'.
        screen-active    = '0'.
      ENDIF.
      MODIFY SCREEN.
    ENDLOOP.
* Elseif button press flag is 'X' show the dynamic selection screen.
  ELSEIF gv_button_press EQ 'X'.
    LOOP AT SCREEN.
      IF screen-group1 = 'AW1'.
        screen-invisible = '0'.
        screen-active    = '1'.
      ENDIF.
      MODIFY SCREEN.
    ENDLOOP.
  ENDIF.
ENDFORM.                    " adapt_screen
Regards,
T2
Message was edited by: Titu Joseph