Problem with local class, static private attribute and public method

Question

Hello SDN,
Consider the following situation:
1) I have defined a LOCAL class airplane.
2) This class has a private static attribute "type table of ref to" airplane (array of airplanes)
3) A public method should return the private static table attribute
Problems:
a) The table cannot be given as an EXPORTING parameter in the method because TYPE TABLE OF... is not supported and I get syntax errors. I also cannot define a dictionary table type because it is a local class.
b) The table cannot be given as a TABLES parameter in the method because TABLES is not supported in the OO context.
c) The table cannot be given as an EXPORTING parameter in the method defined as LIKE myStaticAttribute because my method is PUBLIC and my attribute is PRIVATE. ABAP syntax requires that all PUBLIC statements are defined before PRIVATE ones, therefore it cannot find the attribute to reference to with LIKE.
I see only 2 solutions:
a) Never ever use local classes and always use global classes so that I might define a dictionary table type of my class which I can then use in my class.
b) Make the attribute public, but this goes against OO principles, and isn't really an option.
Am I missing anything here, or is this simply overlooked so far?

Answer 1

Hello Niels
Since your class is local and, thus, only know to the "surrounding" application is does not really make sense to make it public to any other application.
However, if you require to store instances of your local classes in internal tables simply use the most generic reference type possible, i.e. <b>OBJECT</b>.
The following sample report shows how to do that. Furthermore, I believe it also shows that there are <u><b>no </b></u>serious inconsistency in the ABAP language.
*& Report  ZUS_SDN_LOCAL_CLASS
REPORT  zus_sdn_local_class.
" NOTE: SWF_UTL_OBJECT_TAB is a table type having reference type OBJECT
*       CLASS lcl_airplane DEFINITION
CLASS lcl_airplane DEFINITION.
  PUBLIC SECTION.
    DATA:    md_counter(3)             TYPE n.
    METHODS: constructor,
             get_instances
               RETURNING
                 value(rt_instances)   TYPE swf_utl_object_tab.
  PRIVATE SECTION.
    CLASS-DATA: mt_instances    TYPE swf_utl_object_tab.
ENDCLASS.                    "lcl_airplane DEFINITION
*       CLASS lcl_airplane IMPLEMENTATION
CLASS lcl_airplane IMPLEMENTATION.
  METHOD constructor.
    APPEND me TO mt_instances.
    DESCRIBE TABLE mt_instances.
    md_counter = syst-tfill.
  ENDMETHOD.                    "constructor
  METHOD get_instances.
    rt_instances = mt_instances.
  ENDMETHOD.                    "get_instance
ENDCLASS.                    "lcl_airplane IMPLEMENTATION
DATA:
  gt_instances      TYPE swf_utl_object_tab,
  go_object         TYPE REF TO object,
  go_airplane       TYPE REF TO lcl_airplane.
START-OF-SELECTION.
  " Create a few airplane instance
  DO 5 TIMES.
    CREATE OBJECT go_airplane.
  ENDDO.
  gt_instances = go_airplane->get_instances( ).
  CLEAR: go_airplane.
  LOOP AT gt_instances INTO go_object.
    go_airplane ?= go_object.
    WRITE: / 'Airplane =', go_airplane->md_counter.
  ENDLOOP.
END-OF-SELECTION.
Regards
  Uwe<u></u>