Problem with Nested tell blocks in Applescript

Question

Hello everyone,
I've been trying to do a little Applescript, whose purpose is to open a file selector to let the user choose a bunch of images, then prompt him to ask a resizing ratio, and then resize the chosen pictures accordingly (after duplicating the originals in a folder on the desktop, the copied files being the ones resized).
I'm having problems with the resizing part... Here is the code I've come up with so far... "Image traitées" is the name of the new folder created on the desktop, and "compression" is the factor in %.
     -- Resizing 
     tell application "Finder"
          repeat with photo in folder "Images traitées" of desktop
               tell application "Image Events"
                    launch
                    scale photo by factor compression * 0.01
               end tell
          end repeat 
     end tell
I'm encountering an error number -1708, saying that the 'photo' item doesn't understand the scale message...
As I'm new to Applescript, I have some difficulties solving this... Could it be due to the nested tell blocks ?
Thanks a lot for your help !
Thomas

Answer 1

Your tell statements are OK, although when nesting them you do need to keep track of what application is getting targeted in any given statement (to avoid terminology conflicts).
Each application refers to its objects in its own way - unfortunately, not everything knows about Finder references.  Your photo variable contains a Finder reference (e.g. "file x of folder y of disk z"), but Image Events doesn't know what that is.  The solution is to convert the Finder reference to something more standard, such as text or an alias.
Your script won't work with just that change, however.  Image Events works with the image contained in a file, so you also need to actually get that image, for example:
set compression to 80 -- used in the following snippet
tell application "Image Events" to launch -- just need to do this once
tell application "Finder"
     repeat with photo in folder "Images traitées" of desktop
          tell application "Image Events"
               set theImage to open (photo as alias) -- get the image from the Finder reference
               scale theImage by factor compression * 0.01
               save theImage -- save the changed image
          end tell
     end repeat
end tell