Problems while uploading text documents into Database

Question

I just upgraded our database from 9iR1 to 9iR2 (9.2.0.1.0). The server
character set is AL32UTF8. Now I'm facing a problem when
uploading text documents into the database via a web frontend.
I use the upload table defined for the PL/SQL Database Access Descriptor:
create table TB_UPLOAD (
NAME VARCHAR2(256) not null,
MIME_TYPE VARCHAR2(128),
DOC_SIZE NUMBER,
DAD_CHARSET VARCHAR2(128),
LAST_UPDATED DATE,
CONTENT_TYPE VARCHAR2(128),
BLOB_CONTENT BLOB);
After uploading a text document containing the two words "hallo welt",
the following statement returns not "hallo welt", but "68616C6C6F2077656C74":
declare
b_loc blob;
v_amount integer := 100;
v_buffer varchar2(100);
v_offset integer := 1;
begin
select blob_content into b_loc from tb_upload where name like 'mydoc.txt';
dbms_lob.read(b_loc, v_amount, v_offset, v_buffer);
htp.prn(v_buffer);
end;
What is this? I studied the documentation, but didn't found a solution.
When trying to use Oracle's built-in procedure wpg_docload.download_file,
the content is shown the way it should be. Unfortunately, I can't use
wpg_docload.download_file in order to copy the BLOB content to another table.
Any hints would be appreciated!
Thanks so much in advance!
Roman
E-Mail: [email protected]

Answer 1

Hi Roman,
the upload uses a BLOB (Binary Lob). Your Document is
stored as is in the binary representation. If you
use dbms_lob.read on a blob and your buffer is a varchar2 the binary representation is not translated!!!
use a raw for the buffer and utl_raw.cast_to_varchar2
to do the conversion to varchar.
try this
Procedure SHOW_DOC(p_name doc_test.name%TYPE)
IS
v_len number;
v_mime_type tb_upload.mime_type%TYPE;
v_offset integer := 1;
v_Buf_size integer := 32767;
v_buf raw(32767);
v_blob blob;
v_Doc_name varchar2(1000);
BEGIN
v_doc_name := url_Decode(p_name);
select mime_type,doc_size,blob_content
into v_mime_Type,v_len,v_blob
from tb_upload
where name = v_doc_name;
OWA_UTIL.MIME_HEADER(v_Mime_Type);
begin
LOOP
DBMS_LOB.READ(v_blob,v_buf_size,v_offset,v_buf);
HTP.PRN(UTL_RAW.CAST_TO_VARCHAR2(v_buf));
v_offset := v_offset + v_buf_size;
END LOOP;
exception
when no_data_found then
null;
end;
END;
HTH
detlev