Production order scheduled start/finish dates

Question

Hello experts!
I have a problem with prod. order scheduling. I set the date '07.05.2007' as order start/finish date. If I run <i>Functions -> Schedule -> Order</i> (or save the order) SAP set these dates to '02.01.2008', and scheduling also to '02.01.2008'. The scheduling type is <b>Forwards in time</b>. Scheduling margin: everything is 0.
I have checked the <b>work center capacity</b>:
from 20.04.2007 to 31.12.2007
Lenght of cycle: 1 Start: 06:00:00 End: 23:00:00 Break: 00:00:00 Cap. util.: 100
from 01.01.2008 to 31.12.9999
Standard avail. capacity
(01.01.2008 is non-working day)
Routing exists for this material (valid from 02.03.2007).
Based on what does SAP calculates these dates?
(SAP 46B)

Answer 1

Hello guys!
I have found the reason and also the solution. It's a bug in SAP (46B). When it happens?
1) Open work center
2) Create interval with minimum 2 shifts and save
3) Delete first shift of the interval
4) Check table kapa -> field SCHNR (shift sequence number) for the 1st shift in this interval will contain number 2.
If SAP calculates the scheduled date for order it excludes this interval from calculation. We had an interval 20.04.2007 to 31.12.2007 with deleted first shift, so the next workday for SAP was 02.01.2008.
I have created a function, which can solve this problem:
FUNCTION z_pp_fix_capacity_data.
*"*"Local interface:
*"  IMPORTING
*"     VALUE(I_WERKS) TYPE  WERKS_D
*"     VALUE(I_ARBPL) TYPE  ARBPL
*"  EXPORTING
*"     VALUE(E_CHANG) TYPE  INT4
*"  EXCEPTIONS
*"      FOREIGN_LOCK
*"      SYSTEM_FAILURE
*"      NOT_VALID_WORK_CENTER
*"      DATABASE_UPDATE_FAILED
  DATA: l_kapid LIKE crhd-kapid,
        l_schnr LIKE kapa-schnr,
        l_error TYPE c.
  DATA: ikap LIKE kapa OCCURS 200 WITH HEADER LINE.
  CLEAR: e_chang.
  COMMIT WORK.
*- Get the Capacity ID of the work center
  SELECT SINGLE kapid
           INTO l_kapid
           FROM crhd
          WHERE werks = i_werks
            AND arbpl = i_arbpl.
  IF sy-subrc <> 0.
    RAISE not_valid_work_center.
  ENDIF.
*- Lock the work center
  CALL FUNCTION 'ENQUEUE_ECARPL'
       EXPORTING
            arbpl          = i_arbpl
            werks          = i_werks
       EXCEPTIONS
            foreign_lock   = 1
            system_failure = 2
            OTHERS         = 3.
  IF sy-subrc <> 0.
    CASE sy-subrc.
      WHEN 1.
        RAISE foreign_lock.
      WHEN 2.
        RAISE system_failure.
    ENDCASE.
  ENDIF.
*- Select the whole capacity into internal table
  SELECT *
    FROM kapa
    INTO TABLE ikap
   WHERE kapid = l_kapid.
*- Sort
  SORT ikap BY versn datub tagnr schnr.
*- Set the correct sequence number
  LOOP AT ikap.
    ON CHANGE OF ikap-versn
              OR ikap-datub
              OR ikap-tagnr.
      l_schnr = 1.
    ENDON.
    IF ikap-schnr NE l_schnr.
      ikap-schnr = l_schnr.
      e_chang = e_chang + 1.
      MODIFY ikap.
    ENDIF.
    l_schnr = l_schnr + 1.
  ENDLOOP.
  IF e_chang NE 0.  " If change found, recreate data
*- Clear error indicator
    CLEAR l_error.
*- Delete old data
    DELETE FROM kapa WHERE kapid = l_kapid.
*- Insert data
    IF sy-subrc EQ 0.              " Delete OK, insert
      INSERT kapa FROM TABLE ikap.
      IF sy-subrc EQ 0.            " Insert OK, commit
        COMMIT WORK AND WAIT.
        clear: l_error.
      ELSE.                        " Insert failed, rollback
        ROLLBACK WORK.
        l_error = 'X'.
      ENDIF.
    ELSE.                          " Delete failed, rollback
      ROLLBACK WORK.
      l_error = 'X'.
    ENDIF.
  ENDIF.
*- Unlock the work center
  CALL FUNCTION 'DEQUEUE_ECARPL'
       EXPORTING
            arbpl = i_arbpl
            werks = i_werks.
  IF l_error NE space.
*- Raise exception
    RAISE database_update_failed.
  ENDIF.
ENDFUNCTION.
I hope this helps someone! Anyway! Thank you for your answers!