Question: How do I retrieve values after creating an autofilter.

Question

So the question is sort of simple but my code is below, this is my first time really running in VBA but it isn't so far all to dissimilar to LotusScript which I am a bit more knowledgeable in. What I am trying to do is retrieve values from the filtered information,
or more simply, I am trying to retrieve values from two cells in the spreadsheet that I want move together.
As noted below one of them is a countries field which simply concatenates the country string with the duplicates with the same first column (A#) fields. 
Example 123 .. UK
              123 .. US
              123 .. CA
The output stored in countries would be UK,US,CA and posted to sheet3.
Sub proFirst()
Dim wSheet As Worksheet
Dim columnCount As Integer
Dim rowCount As Long
Dim testVar As Long
Dim coll As New Collection, a
Dim Assignee() As String
Dim tmpList() As String
Dim newVar As Variant
Dim dict As Object
Const rowDataBegin = 2
Dim count As Long
rowCount = Sheets("Sheet1").UsedRange.Rows.count
columnCount = Sheets("Sheet1").UsedRange.Columns.count
'** This Cleans up the filtering to ensure all data is viewable before we begin **
Sheets("Sheet1").Activate
If (ActiveSheet.AutoFilterMode And ActiveSheet.FilterMode) Or ActiveSheet.FilterMode Then
  ActiveSheet.ShowAllData
End If
Sheets("Sheet3").Activate
If (ActiveSheet.AutoFilterMode And ActiveSheet.FilterMode) Or ActiveSheet.FilterMode Then
  ActiveSheet.ShowAllData
End If
'** This sets a filter to filter by column O which is designated as Submitted Date  **
Sheets("Sheet1").Columns("A:S").AutoFilter Field:=15, Criteria1:="<>"
'** This block copuies and pastes the values we need for the final report however   **
'** this is not a permenent viewable format for the report, a recut may be required **
Application.CutCopyMode = False
rowCount = Sheets("Sheet1").UsedRange.Rows.count
Sheets("Sheet1").Range("A1:D" & rowCount).Copy Sheets("Sheet3").Range("A1:D" & rowCount)
Application.CutCopyMode = False
Sheets("Sheet1").Range("J1:J" & rowCount).Copy Sheets("Sheet3").Range("H1:H" & rowCount)
Application.CutCopyMode = False
Sheets("Sheet1").Range("O1:O" & rowCount).Copy Sheets("Sheet3").Range("I1:I" & rowCount)
Application.CutCopyMode = False
'loops through the first column and acquires all of the data and generates as string array
rowCount = Sheets("Sheet3").UsedRange.Rows.count
columnCount = Sheets("Sheet3").UsedRange.Columns.count
ReDim Assignee(rowCount)
ReDim tmpList(rowCount) 'helper variant to make it smoother for recall of lines
For i = rowDataBegin To rowCount
    Assignee(i - rowDataBegin) = CStr(Sheets("Sheet3").Cells(i, 1).Value)
    tmpList(i - rowDataBegin) = rowCount
Next i
Set dict = CreateObject("Scripting.Dictionary")
For i = LBound(Assignee) To UBound(Assignee)
   If dict.exists(Assignee(i)) Then
        dict.Item(Assignee(i)) = dict.Item(Assignee(i)) + 1
         Else
        dict.Add Assignee(i), 1
    End If
   Next i
Sheets("Sheet3").Range("$A$1:$I$" + CStr(rowCount)).RemoveDuplicates Columns:=1, Header:=xlYes
rowCount = 2
Application.Workbooks(1).Worksheets("Sheet3").Activate
'** Header values Change as needed                                                             
Sheets("Sheet3").Cells(1, 5).Value = "Completed Global Questionnaire? (Yes or No)"
Sheets("Sheet3").Cells(1, 6).Value = "Number of Countries"
Sheets("Sheet3").Cells(1, 7).Value = "Name of Countries Submitted"
For Each v In dict.keys
If dict.Item(v) > 0 And v <> "" Then
Sheets("Sheet3").Cells(rowCount, 6).Value = dict.Item(v)
rowCount = rowCount + 1
End If
Next v
Sheets("Sheet3").Columns("A:I").AutoFilter Field:=6, Criteria1:=">1", _
        Operator:=xlAnd
'** BEGIN TESTING AREA
'** Stage 2 Test Complete - able to retrieve a list of how many rows are in use
'** Stage 3 test - retrieve countries
Sheets("Sheet1").Activate
count = 2
For Each v In dict.keys
countries = ""
rowCount = 0
If dict.Item(v) > 1 Then
    With ActiveSheet
       Set rnData = .UsedRange
        With rnData
            .AutoFilter Field:=1, Criteria1:=v
           .Select
            'xlCellTypeVisible = 12
             For Each rngArea In .SpecialCells(xlCellTypeVisible).Areas
             tmp = .SpecialCells(xlCellTypeVisible).Rows
            Next
            For Z = 2 To rowCount
                If countries = "" Then
                    countries = .Range("I" & Z).Value
                Else
                    countries = countries & ", " & .Range("I" & Z).Value
                End If
            Next Z
        End With
    End With
     Sheets("Sheet3").Cells(count, 7).Value = countries
End If
count = count + 1
Next v
'**  Testing block              **
Sheets("Sheet3").Columns("A:I").AutoFit
MsgBox "End loop"
                                            

Answer 1

The code below is only semi-tested but it should give you the idea of how to loop through the visible data of an AutoFiltered Range. You can't use code like "For r = 2 to Rows.Count" because the code stops after the first non contiguous row. However,
you can use For Each loop to loop through the rows and get the row number from there.
An explanation of the code to set rngVisible. (Note that a space and underscore at the end of a line is a line break in an otherwise single line of code.)
With .AutoFilter.Range   This is the entire AutoFilter Range (Includes column headers, visible and non visible rows)
 .Offset(1, 0)     Moves down one row off the column headers but now includes an additional row at the bottom below the data. (Still includes visible and non visible rows)
 .Resize(.Rows.Count - 1, .Columns.Count)     Removes the additional row due to Offset (Still includes visible and non visible rows)
.SpecialCells(xlCellTypeVisible)      Only include the visible rows.
    Sheets("Sheet1").Activate
    For Each v In dict.keys
        countries = ""
        If dict.Item(v) > 1 Then
            With ActiveSheet
                Set rnData = .UsedRange
                With rnData
                    .AutoFilter Field:=1, Criteria1:=v
                End With
                'Note that AutoFilter.Range is an inbuilt object variable _
                for the entire range covered by the AutoFilter
                With .AutoFilter.Range
                    'Following tests if any rows (other than column header) are visible _
                    in the AutoFilter.Range.  If > 1 then more than just column headers. _
                    Attempting to set the rngVisible will error if not at least one row _
                    of visible data.
                    If .Columns(1).SpecialCells(xlCellTypeVisible).Cells.Count > 1 Then
                        'Assign the visible data to a range variable
                        Set rngVisible = .Offset(1, 0) _
                                   .Resize(.Rows.Count - 1, .Columns.Count) _
                                   .SpecialCells(xlCellTypeVisible)
                    Else
                        MsgBox "No visible data. Procesing terminated."
                        'Left for you to handle what you want to do if the _
                         filter does not exist in the data and no visible rows present
                        Exit Sub
                    End If
                End With
                'Loop through the rows of rngVisible
                'and get the row numbers
                For Each rngRow In rngVisible.Rows
                    Z = rngRow.Row
                    If countries = "" Then
                       countries = .Range("I" & Z).Value
                    Else
                       countries = countries & ", " & .Range("I" & Z).Value
                    End If
                Next rngRow
            End With
        End If
    Next v
Regards, OssieMac