Raise statement in a package.

Question

I am just curious about the raise statement used in plsql.
exception
when others then
dbms_application_info.set_module('', '');
dbms_application_info.set_client_info('');
x_err_code := sqlcode;
x_err_message := sqlerrm;
log_message(p_message => x_err_message,
p_proc_name => lc_proc_name,
p_event_status => constants_pkg.event_error);
log_message('excpt5', lc_proc_name);
raise; ------------------------------------------------------------------------------------------------------------what does it do?it is not associated with any exception.
end apply_payment_by_vtxn;

Answer 1

Whatever caused the code to enter the exception block will be re-raised, it does not matter what it was that caused it, or where in the code it came from. Consider:
SQL> create procedure p (p_num in number, p_str in varchar2) as
  2     l_v varchar2 (2);
  3  begin
  4     if p_num is not null then
  5        select dummy into l_v
  6        from dual
  7        where 1 = p_num;
  8     else
  9        select p_str into l_v
10        from dual;
11     end if;
12  exception
13     when others then
14        raise;
15  end;
16  /
Procedure created.
SQL> exec p(2, null);
BEGIN p(2, null); END;
ERROR at line 1:
ORA-01403: no data found
ORA-06512: at "OPS$ORACLE.P", line 14
ORA-06512: at line 1
SQL> exec p(null, 'Hello');
BEGIN p(null, 'Hello'); END;
ERROR at line 1:
ORA-06502: PL/SQL: numeric or value error: character string buffer too small
ORA-06512: at "OPS$ORACLE.P", line 14
ORA-06512: at line 1Note that the line number for the error is at the raise, not where the original error occurred.
John