Read "last changed" data from AL11 into BSP page

Question

Hi all,
I'm looking for a way to read the following information from the application server
Last change             Creator     Name
17.07.2006 09:19:58     cbdadm      file1.csv
27.05.2003 10:53:11     cbdadm      file2.csv
13.07.2006 17:01:30     cbdadm      file3.csv
I want to see for a number of filenames, when it was last changed, but I don't know where to get this data? Is it stored in a table? And how should I read this data?
I see that a program named RSWATCH0 is generating the required output for transaction AL11...maybe this is helpful?
The following code works in ABAP, but I need to use this in BSP... is this possible somehow?
REPORT ZUPLOAD_TIME .
TABLES epsf.
PARAMETERS dir  LIKE epsf-epsdirnam.
PARAMETERS file LIKE epsf-epsfilnam.
DATA mtime TYPE p DECIMALS 0.
DATA time(10).
DATA date LIKE sy-datum.
CALL FUNCTION 'EPS_GET_FILE_ATTRIBUTES'
     EXPORTING
          file_name              = 'TESTFILE.CSV'
          dir_name               = '/usr/sap/data/'
     IMPORTING
          file_size              = epsf-epsfilsiz
          file_owner             = epsf-epsfilown
          file_mode              = epsf-epsfilmod
          file_type              = epsf-epsfiltyp
          file_mtime             = mtime
     EXCEPTIONS
          read_directory_failed  = 1
          read_attributes_failed = 2
          OTHERS                 = 3.
PERFORM p6_to_date_time_tz(rstr0400) USING mtime
                                           time
                                           date.
WRITE: / mtime,
       / date, time.
thanks in advance! points will be rewarded for usefull answers
Message was edited by: Joris Hens
Message was edited by: Joris Hens

Answer 1

In the TYPES Definition tab :
types: BEGIN OF t_file,
        date     TYPE d,
        time(10) TYPE c.
        INCLUDE  TYPE epsf.
TYPES: END OF t_file.
types: tt_files type table of t_file.
In the Page attributes tab :
ta_files TYPE tt_files
In the OnInitialization Event Handler :
* event handler for data retrieval
DATA: epsf      TYPE epsf.
DATA: mtime     TYPE p DECIMALS 0.
DATA: time(10)  TYPE c.
DATA: date      TYPE sy-datum.
CALL FUNCTION 'EPS_GET_FILE_ATTRIBUTES'
  EXPORTING
    file_name              = 'myfile.csv'
    dir_name               = '/usr/sap/data'
  IMPORTING
    file_size              = epsf-epsfilsiz
    file_owner             = epsf-epsfilown
    file_mode              = epsf-epsfilmod
    file_type              = epsf-epsfiltyp
    file_mtime             = mtime
  EXCEPTIONS
    read_directory_failed  = 1
    read_attributes_failed = 2
    OTHERS                 = 3.
PERFORM p6_to_date_time_tz IN PROGRAM rstr0400 USING mtime
                                                     time
                                                     date.
FIELD-SYMBOLS: <fs_file>  LIKE LINE OF ta_files.
APPEND INITIAL LINE TO ta_files ASSIGNING <fs_file>.
MOVE-CORRESPONDING epsf TO <fs_file>.
<fs_file>-time = time.
<fs_file>-date = date.
In the Layout :
<%@page language="abap"%>
<%@extension name="htmlb" prefix="htmlb"%>
<htmlb:content design="design2003">
  <htmlb:page title = "List files on application server ">
    <htmlb:form>
    <htmlb:tableView id = "tvx"
                     table = "<%= ta_files %>" />
    </htmlb:form>
  </htmlb:page>
</htmlb:content>
Then, you still have some minor modificaions to perform on the tableView thanks to an Iterator, for instance.
Best regards,
Guillaume
Message was edited by: Guillaume Garcia