Refresh SBO Order

Question

Dear Sir,
I am using the DI to add an order to the database using the oOrder.Lines.Add methods and VB6 SP6 as developpemt language but instead of
creating a new form I am using the standard SBO Order form.
the problem is that when I open the order form, it is in a create mode, I start to enter items and i should create one line per quantiy for
example if i enter Item1 with qty = 2, at the line validation, 2 lines should be added to the database before going to a new line I
automatically insert the order line into the database using the oOrder.lines.add method. and now i have a problem since the user cannot see
that his order is now containing 2 lines with the same item reference with qty=1 per line.
My question is what should i do to refresh my order and get the exact number of lines already inserted in the database.
Thanks in advance

Answer 1

Hello Mary,
What you try to do (blocking the regular Add, but still using the form to display the result) would require a workaround that handles 2 events in parallel since you would have to <b>switch</b> the Form.Mode to "Find". That will cause the system message asking you whether it is OK to clear the data on the form ("Changes will cause the data to be deleted")...
...and that message needs to be handled separately - and you will need a global or static flag to know that you should close that message in your code.
I.e. you will have a workaround that isn't too nice and could cause more trouble than convincing the users that a bit of flicker doesn't really do much harm... - if I am not totally mistaken!
Here's the code for the opening / closing (in the background):
Please note that it works for the Item EVent only - at least in my patch (18) I had trouble using it in the FormDataEvent (what would be the more natural choice in principle...)
Try
    If (pVal.FormTypeEx = "139") _
    And (pVal.ItemUID = "1") _
    And (pVal.EventType = SAPbouiCOM.BoEventTypes.et_ITEM_PRESSED) _
    And (pVal.BeforeAction = True) Then
        Dim oFormOrig As SAPbouiCOM.Form
        oFormOrig = SBO_Application.Forms.Item(FormUID)
        If Not (oFormOrig.Mode = SAPbouiCOM.BoFormMode.fm_ADD_MODE) Then
            Exit Sub
        End If
        BubbleEvent = False
        ' get the data from the form... (like you do now...;
        'we asked R&D to consider to supply an easier way to get the data...)
        '...(quite some work to do...)
        Dim oOrder As SAPbobsCOM.Documents = oCompany.GetBusinessObject(SAPbobsCOM.BoObjectTypes.oOrders)
        oOrder.CardCode = "C20000"
        oOrder.DocDueDate = Date.Now
        oOrder.Comments = "Order added in FormDataEvent..."
        oOrder.Lines.ItemCode = "A00001"
        oOrder.Lines.Add()
        oOrder.Lines.ItemCode = "A00002"
        oOrder.Lines.Add()
        oOrder.Lines.ItemCode = "A00003"
        ' Try to add the order object to the database
        iRetCode = oOrder.Add()
        If iRetCode <> 0 Then ' If the addition failed
            oCompany.GetLastError(iErrCode, sErrMsg)
            SBO_Application.MessageBox(iErrCode & " " & sErrMsg) ' Display error message
            Exit Sub
        End If
        SBO_Application.StatusBar.SetText("Order Added", _
          SAPbouiCOM.BoMessageTime.bmt_Short, _
          SAPbouiCOM.BoStatusBarMessageType.smt_Success)
        'Navigate to new document:
        Dim sDocEntry As String = oCompany.GetNewObjectKey()
        If oOrder.GetByKey(CInt(sDocEntry)) Then
            ' to "Find" the document we need the Document Number instead of the (internal) Doc Entry number...
            Dim sDocNum As String = CStr(oOrder.DocNum)
            ' Open a new SO Form... and set form to "Find" mode
            SBO_Application.ActivateMenuItem("2050")
            Dim oFormNew As SAPbouiCOM.Form
            oFormNew = SBO_Application.Forms.Item(SBO_Application.Forms.ActiveForm.UniqueID)
            oFormNew.Mode = SAPbouiCOM.BoFormMode.fm_FIND_MODE
            ' fill the document number (visible to the user) into the corresponding input field
            Dim oEdt As SAPbouiCOM.EditText = oFormNew.Items.Item("8").Specific
            oEdt.String = sDocNum
            ' "Find" the document...
            oFormNew.Items.Item("1").Click()
            ' "Cancel" the old one...
            oFormOrig.Items.Item("2").Click()
        Else
            SBO_Application.StatusBar.SetText("Internal error: Order not found; DocEntry = " & sDocEntry, _
                            SAPbouiCOM.BoMessageTime.bmt_Short, _
            SAPbouiCOM.BoStatusBarMessageType.smt_Error)
        End If
    End If
Catch ex As Exception
    SBO_Application.StatusBar.SetText(ex.Message, _
            SAPbouiCOM.BoMessageTime.bmt_Short, _
           SAPbouiCOM.BoStatusBarMessageType.smt_Error)
End Try
Message was edited by:
        Frank Moebius