Related to ALV

Question

Hi,
My requirement is to ..
disply output in an ALV list (List display).. Place cursor on a row and select particular data and  this must take U to the FB02 transaction( NOT initial screen but directly to long text screen) . Then user will do ener some text in this transaction..
When it is saved it must come back to the ALV list (from where U called the transaction FB02.)
How to call particular screen and save the text fo diffrent line items.
Please help me in resolving this issue.

Answer 1

Hi,
Check this example..This will satisfy your requirement..IF you double click on the line in the ALV..It will directly take you to the long text screen..
TYPE-POOLS: slis.
Data declaration.
DATA: bdcdata LIKE bdcdata OCCURS 0 WITH HEADER LINE.
DATA: BEGIN OF wa,
        belnr LIKE bkpf-belnr,
        gjahr LIKE bkpf-gjahr,
        bukrs LIKE bkpf-bukrs,
      END OF wa.
DATA: v_repid TYPE syrepid.
v_repid = sy-repid.
DATA: itab LIKE wa OCCURS 0 WITH HEADER LINE.
DATA: t_fieldcatalog TYPE slis_t_fieldcat_alv.
DATA: s_fieldcatalog TYPE slis_fieldcat_alv.
START-OF-SELECTION.
get the data.
  SELECT belnr gjahr bukrs UP TO 10 ROWS
         FROM bkpf
         INTO TABLE itab.
get the field catalog.
  CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
       EXPORTING
            i_program_name     = v_repid
            i_internal_tabname = 'WA'
            i_inclname         = v_repid
       CHANGING
            ct_fieldcat        = t_fieldcatalog.
display alv.
  CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
       EXPORTING
            i_callback_program      = v_repid
            i_callback_user_command = 'USER_COMMAND'
            it_fieldcat             = t_fieldcatalog
       TABLES
            t_outtab                = itab.
FORM user_command USING ucomm LIKE sy-ucomm
selfield TYPE slis_selfield.
  IF ucomm = '&IC1'.
    READ TABLE itab INDEX selfield-tabindex.
    IF sy-subrc = 0.
      PERFORM bdc USING itab-belnr itab-gjahr itab-bukrs.
    ENDIF.
  ENDIF.
ENDFORM.
FORM bdc USING belnr gjahr bukrs.
  REFRESH bdcdata.
  PERFORM bdc_dynpro USING 'SAPMF05L' '0100'.
  PERFORM bdc_field USING 'BDC_CURSOR'
  'RF05L-BELNR'.
  PERFORM bdc_field USING 'BDC_OKCODE'
  '=AZ'.
  PERFORM bdc_field USING 'RF05L-BELNR'
  belnr.
  PERFORM bdc_field USING 'RF05L-BUKRS'
  bukrs.
  PERFORM bdc_field USING 'RF05L-GJAHR'
  gjahr.
  PERFORM bdc_dynpro USING 'SAPMF05L' '0301'.
  PERFORM bdc_field USING 'BDC_CURSOR'
  'BSEG-ZUONR'.
  PERFORM bdc_field USING 'BDC_OKCODE'
  '=LTXT'.
  PERFORM bdc_field USING 'BDC_OKCODE'
  '=LTXT'.
  CALL TRANSACTION 'FB02' USING bdcdata
  MODE 'E'.
ENDFORM.
FORM bdc_dynpro USING program dynpro.
  CLEAR bdcdata.
  bdcdata-program = program.
  bdcdata-dynpro = dynpro.
  bdcdata-dynbegin = 'X'.
  APPEND bdcdata.
ENDFORM.
FORM bdc_field USING fnam fval.
  CLEAR bdcdata.
  bdcdata-fnam = fnam.
  bdcdata-fval = fval.
  APPEND bdcdata.
ENDFORM.
Thanks,
Naren