Removing Zeros from Packed with decimals value

Question

Declaration is as follows:  var1(3) type p decimals 1
i am passing value from database var1 value is 10.0
In the above case i want to remove decimal value 0 in 10.0 if var1 value is 10.50 then my required value is 10.5 only.
var1 is not used in clasical reports.
I would like to export the variable var1 into smartforms and print.

Answer 1

try this code and adopt it according to your needs:
DATA:
  gv_p_init         TYPE p DECIMALS 2 VALUE '10.1',
  gv_dec_separator  TYPE char1,
  gv_tmp1           TYPE char1024,
  gv_len_dec        TYPE i,
  gv_tmp2           TYPE char1024,
  gr_dref           TYPE REF TO data,
  gr_datadescr      TYPE REF TO cl_abap_datadescr.
FIELD-SYMBOLS:
  <gv_new_p>        TYPE p.
* determine user specific decimal separator
PERFORM get_dec_separator
  CHANGING gv_dec_separator.
WRITE gv_p_init TO gv_tmp1.
SEARCH gv_tmp1 FOR gv_dec_separator.
* create new anonymous data object -> GR_DREF of type P with same length
* as GV_P_INIT and decimals depending on relevant decimals of GV_P_INIT
IF sy-subrc EQ 0.
  MOVE gv_tmp1+sy-fdpos TO gv_tmp2.
  SHIFT gv_tmp2 LEFT DELETING LEADING gv_dec_separator.
  SHIFT gv_tmp2 RIGHT DELETING TRAILING space.
  SHIFT gv_tmp2 RIGHT DELETING TRAILING '0'.
  SHIFT gv_tmp2 LEFT DELETING LEADING space.
  gv_len_dec = STRLEN( gv_tmp2 ).
  gr_datadescr ?= cl_abap_datadescr=>describe_by_data( gv_p_init ).
  gr_datadescr ?= cl_abap_elemdescr=>get_p(
                                    p_decimals = gv_len_dec
                                    p_length   = gr_datadescr->length ).
  CREATE DATA gr_dref TYPE HANDLE gr_datadescr.
  ASSIGN gr_dref->* TO <gv_new_p>.
  MOVE gv_p_init TO <gv_new_p>.
  WRITE: / gv_p_init,
         / <gv_new_p>.
ENDIF.
FORM get_dec_separator
  CHANGING cv_sep TYPE char1.
  DATA:
    lv_one_thousand TYPE i VALUE 1000,
    lv_tmp          TYPE char20.
  WRITE lv_one_thousand TO lv_tmp.
  IF lv_tmp CA '.'.
    MOVE ',' TO cv_sep.
  ELSE. "IF lv_tmp CA '.'
    MOVE '.' TO cv_sep.
  ENDIF. "IF lv_tmp CA '.'
ENDFORM. "FORM get_dec_separator
reward points if helpful