Repetitive call of event handler method

hi,
i ve some 8 screens with alv grid controls on each...i'm using
same subroutine for event handling for all the controls...the problem
is whenever i navigate from 1 to the other and return back to the same,
after data change, the event handler method is getting called as many times
i ve navigated....for toolbar actions i used befor user command event and
overcame but for data changed i got struck... Plz tel me the reason and how can we avoid.....
Thanks
Swaminathan.

Hello Swami
The following sample report shows how to handle the same event for different control instances. The crucial point is to check for the sending control.
*       CLASS lcl_eventhandler DEFINITION
CLASS lcl_eventhandler DEFINITION.
PUBLIC SECTION.
    CLASS-METHODS:
      handle_hotspot_click FOR EVENT hotspot_click OF cl_gui_alv_grid
        IMPORTING
          e_row_id
          e_column_id
          es_row_no
          sender.       " sending control !!!
ENDCLASS.                    "lcl_eventhandler DEFINITION
*       CLASS lcl_eventhandler IMPLEMENTATION
CLASS lcl_eventhandler IMPLEMENTATION.
METHOD handle_hotspot_click.
*   define local data
    DATA:
      ls_knb1     TYPE knb1,
      ls_col_id   TYPE lvc_s_col.
    CASE sender. " check for the sending control (this is known!!!)
      WHEN go_grid1.
        READ TABLE gt_customer1 INTO ls_knb1 INDEX e_row_id-index.
        MESSAGE 'Do event handling for 1st ALV grid!' TYPE 'I'.
      WHEN go_grid2.
        READ TABLE gt_customer2 INTO ls_knb1 INDEX e_row_id-index.
        MESSAGE 'Do event handling for 2nd ALV grid!' TYPE 'I'.
      WHEN OTHERS.
        RETURN.
    ENDCASE.
ENDMETHOD.                    "handle_hotspot_click
ENDCLASS.                    "lcl_eventhandler IMPLEMENTATION
The sample report contains two screens showing two parts of the selected data (just for demonstration). Please do note that it does not matter at all whether the ALV lists are on the same screen or on different screens or whether they are displayed in subscreens of the same dynpro.
*& Report ZUS_SDN_ALVGRID_EVENTS_4
* Both screens have the same flow logic and do not contain any elements:
*PROCESS BEFORE OUTPUT.
* MODULE STATUS_0100.
*PROCESS AFTER INPUT.
* MODULE USER_COMMAND_0100.
REPORT ZUS_SDN_ALVGRID_EVENTS_4.
DATA:
gd_okcode        TYPE ui_func,
gt_fcat          TYPE lvc_t_fcat,
go_docking1      TYPE REF TO cl_gui_docking_container,
go_docking2      TYPE REF TO cl_gui_docking_container,
go_grid1         TYPE REF TO cl_gui_alv_grid,
go_grid2         TYPE REF TO cl_gui_alv_grid.
DATA:
gt_customer1     TYPE STANDARD TABLE OF knb1,
gt_customer2     TYPE STANDARD TABLE OF knb1.
PARAMETERS:
p_bukrs      TYPE bukrs DEFAULT '2000' OBLIGATORY.
*       CLASS lcl_eventhandler DEFINITION
CLASS lcl_eventhandler DEFINITION.
PUBLIC SECTION.
    CLASS-METHODS:
      handle_hotspot_click FOR EVENT hotspot_click OF cl_gui_alv_grid
        IMPORTING
          e_row_id
          e_column_id
          es_row_no
          sender.
ENDCLASS.                    "lcl_eventhandler DEFINITION
*       CLASS lcl_eventhandler IMPLEMENTATION
CLASS lcl_eventhandler IMPLEMENTATION.
METHOD handle_hotspot_click.
*   define local data
    DATA:
      ls_knb1     TYPE knb1,
      ls_col_id   TYPE lvc_s_col.
    CASE sender.
      WHEN go_grid1.
        READ TABLE gt_customer1 INTO ls_knb1 INDEX e_row_id-index.
        MESSAGE 'Do event handling for 1st ALV grid!' TYPE 'I'.
      WHEN go_grid2.
        READ TABLE gt_customer2 INTO ls_knb1 INDEX e_row_id-index.
        MESSAGE 'Do event handling for 2nd ALV grid!' TYPE 'I'.
      WHEN OTHERS.
        RETURN.
    ENDCASE.
    CHECK ( ls_knb1-kunnr IS NOT INITIAL ).
    CASE e_column_id-fieldname.
      WHEN 'KUNNR'.
        SET PARAMETER ID 'KUN' FIELD ls_knb1-kunnr.
        SET PARAMETER ID 'BUK' FIELD ls_knb1-bukrs.
        CALL TRANSACTION 'XD03' AND SKIP FIRST SCREEN.
      WHEN 'ERNAM'.
*        SET PARAMETER ID 'USR' FIELD ls_knb1-ernam.
*        NOTE: no parameter id available, yet simply show the priciple
        CALL TRANSACTION 'SU01' AND SKIP FIRST SCREEN.
      WHEN OTHERS.
*       do nothing
    ENDCASE.
*   Set active cell to field BUKRS otherwise the focus is still on
*   field KUNNR which will always raise event HOTSPOT_CLICK
    ls_col_id-fieldname = 'BUKRS'.
    CALL METHOD go_grid1->set_current_cell_via_id
      EXPORTING
        is_row_id    = e_row_id
        is_column_id = ls_col_id.
ENDMETHOD.                    "handle_hotspot_click
ENDCLASS.                    "lcl_eventhandler IMPLEMENTATION
START-OF-SELECTION.
SELECT * FROM knb1 INTO TABLE gt_customer1
         WHERE bukrs = p_bukrs
         AND    kunnr <= '0000300000'.
SELECT * FROM knb1 INTO TABLE gt_customer2
         WHERE bukrs = p_bukrs
         AND    kunnr > '0000300000'.
* Create docking container
CREATE OBJECT go_docking1
    EXPORTING
      parent                      = cl_gui_container=>screen0
      ratio                       = 90
    EXCEPTIONS
      OTHERS                      = 6.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
CREATE OBJECT go_docking2
    EXPORTING
      parent                      = cl_gui_container=>screen0
      ratio                       = 90
    EXCEPTIONS
      OTHERS                      = 6.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Create ALV grid
CREATE OBJECT go_grid1
    EXPORTING
      i_parent          = go_docking1
    EXCEPTIONS
      OTHERS            = 5.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
CREATE OBJECT go_grid2
    EXPORTING
      i_parent          = go_docking2
    EXCEPTIONS
      OTHERS            = 5.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Set event handler
SET HANDLER:
    lcl_eventhandler=>handle_hotspot_click FOR ALL INSTANCES.
* Build fieldcatalog and set hotspot for field KUNNR
PERFORM build_fieldcatalog_knb1.
* Display data
CALL METHOD go_grid1->set_table_for_first_display
    CHANGING
      it_outtab       = gt_customer1
      it_fieldcatalog = gt_fcat
    EXCEPTIONS
      OTHERS          = 4.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
CALL METHOD go_grid2->set_table_for_first_display
    CHANGING
      it_outtab       = gt_customer2
      it_fieldcatalog = gt_fcat
    EXCEPTIONS
      OTHERS          = 4.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Link the docking container to the target dynpro
CALL METHOD go_docking1->link
    EXPORTING
      repid                       = syst-repid
      dynnr                       = '0100'
*      CONTAINER                   =
    EXCEPTIONS
      OTHERS                      = 4.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
CALL METHOD go_docking2->link
    EXPORTING
      repid                       = syst-repid
      dynnr                       = '0200'
*      CONTAINER                   =
    EXCEPTIONS
      OTHERS                      = 4.
IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* ok-code field = GD_OKCODE
CALL SCREEN '0100'.
END-OF-SELECTION.
*&      Module STATUS_0100 OUTPUT
*       text
MODULE status_0100 OUTPUT.
SET PF-STATUS 'STATUS_0100'.
* SET TITLEBAR 'xxx'.
ENDMODULE.                 " STATUS_0100 OUTPUT
*&      Module USER_COMMAND_0100 INPUT
*       text
MODULE user_command_0100 INPUT.
CASE gd_okcode.
    WHEN 'BACK' OR
         'END' OR
         'CANC'.
      CASE syst-dynnr.
        WHEN '0100'.
          SET SCREEN 0. LEAVE SCREEN.
        WHEN '0200'.
          SET SCREEN 100. LEAVE SCREEN.
      ENDCASE.
    WHEN 'NEXT'.
      SET SCREEN 200. LEAVE SCREEN.
    WHEN OTHERS.
ENDCASE.
CLEAR: gd_okcode.
ENDMODULE.                 " USER_COMMAND_0100 INPUT
*&      Form BUILD_FIELDCATALOG_KNB1
*       text
* --> p1        text
* <-- p2        text
FORM build_fieldcatalog_knb1 .
* define local data
DATA:
    ls_fcat        TYPE lvc_s_fcat.
CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
*     I_BUFFER_ACTIVE              =
      i_structure_name             = 'KNB1'
*     I_CLIENT_NEVER_DISPLAY       = 'X'
*     I_BYPASSING_BUFFER           =
*     I_INTERNAL_TABNAME           =
    CHANGING
      ct_fieldcat                  = gt_fcat
    EXCEPTIONS
      inconsistent_interface       = 1
      program_error                = 2
      OTHERS                       = 3.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
LOOP AT gt_fcat INTO ls_fcat
          WHERE ( fieldname = 'KUNNR' OR
                  fieldname = 'ERNAM' ).
    ls_fcat-hotspot = abap_true.
    MODIFY gt_fcat FROM ls_fcat.
ENDLOOP.
ENDFORM.                    " BUILD_FIELDCATALOG_KNB1
Regards
Uwe

Similar Messages

Explicitly call the Event Handler method

Hello Friends,
Is it possible to explicitly call the eventhandler method `? or dynamically fire/invoke the event so that particular eventhandler method should be called ?
Regards,

You should call eventhandler as follows
DATA lr_event TYPE REF TO cl_wd_custom_event.
**Create event object
CREATE OBJECT lr_event
    EXPORTING
      name = 'ON_SELECT'. " give your event name which appears in wdevent in your handler method
* Call eventhandler
wd_this->onactionsel_rdb(
wdevent = lr_event                          " ref to cl_wd_custom_event

How to Call Event Handler Method in Another view

Hi Experts,
                   Can anybody tell me how to call Event handler Method which is declared in View A ,it Should be Called in
view B,Thanks in Advance.
Thanks & Regards
Santhosh

hi,
1)    You can make the method EH_ONSELECT as public and static and call this method in viewGS_CM/ADDDOC using syntax
    impl class name of view GS_CM/DOCTREE=>EH_ONSELECT "method name.
             or
2)The view GS_CM/ADDDOC which contains EH_ONSELECT method has been already enhanced, so I can't execute such kind of operation one more time.
                     or
3)If both views or viewarea containing that view are under same window , then you can get the instance ofGS_CM/DOCTREE from view GS_CM/ADDDOC through the main window controller.
lr_window = me->view_manager->get_window_controller( ).
    lv_viewname = 'GS_CM/DOCTREE '.
lr_viewctrl ?= lr_window ->get_subcontroller_by_viewname( lv_viewname ).
Now you can access the method of view GS_CM/DOCTREE .
Let me know in case you face any issues.
Message was edited by: Laure Cetin
Please do not ask for points, this is against the Rules of Engagement: http://scn.sap.com/docs/DOC-18590

Enhance standard class with event handler method

In trying to enhance a standard class with a new event handler class, I find that the ECC 6.0 EHP4 system does not appear to recognise the fact the method is an event handler method. The specific example is a new method to handle the event CL_GUI_ALV_GRID->USER_COMMAND.
I notice that the flag called Active has not been ticked - see image below. Perhaps this is the reason why the event handler is not being triggered.
Note that there is an event handler for the same event in the standard class which obviously is executed as expected. Any ideas on limitations in the system or I am missing a step?
Thanks
John

Thank you for your replies.
There is a bug in the ALV handler of a standard SAP class (when executed in ITS WebGUI) and I was hoping to create a custom event handler as an Enhancement to execute some custom code to sort of "handle the bug".
I agree - ideally it should be done in a Z class but that will not give me access to the object methods and attributes of the enhanced class.
Cheers,
John

View not copied or enhanced with wizard Error while creating Event Handler method in Z Component

Hello Friends,
In one Z Component (Custom Component), in one of the views, while creating event handler, it gave me error message that view not copied or enhanced with wizard.
I am aware that in Standard Component, if we want to create the event handler method then we need to first Enhance the Component and then we need to enhance the view.
But, in the Z Component (Custom Component), how to create event handler method in one of the views as while creating event handler method i am getting view not copied or enhanced with wizard error.

Hi,
Add a method in views impl class with naming convention eh_on__* with htmt and html_ex parameters. I dont have have the system right now. Please check any existing event import export parameters.
Check out do handle event method in the same class.
Redefine that method. Call that event method in this handle method. See existing code for reference.
Attach that event to the button on click event in .htm page.
Regards,
Bhushan

Event handler method

Hi all,
I want to know the significance of creating event handler method in Class builder.
and how it can be used at the time of event trigger.( Is it called automatically or programmer need to call it explicitly in the program.)
Thanks,
Sushant singh

Hi Sushant,
1. In ABAP Objects, triggering and handling an event means that certain methods act as triggers and trigger events, to which other methods - the handlers - react. This means that the handler methods are executed when the event occurs.
2.To trigger an event, a class must
Declare the event in its declaration part
Trigger the event in one of its methods
3.You declare events in the declaration part of a class or in an interface. To declare instance events, use the following statement:
EVENTS evt EXPORTING... VALUE(e1 e2 ...) TYPE type [OPTIONAL]..
4. An instance event in a class can be triggered by any instance method in the class. Static events can be triggered by any method. However, static methods can only trigger static events. To trigger an event in a method, use the following statement:
RAISE EVENT evt EXPORTING e1 = f1 e2 = f2 ...
5. Events are handled using special methods. To handle an event, a method must
be defined as an event handler method for that event
be registered at runtime for the event.
Declaring Event Handler Methods
Any class can contain event handler methods for events from other classes. You can, of course, also define event handler methods in the same class as the event itself. To declare an event handler method, use the following statement:
METHODS meth FOR EVENT evt OF cif IMPORTING e1 e2 ...
6. Registering Event Handler Methods
To allow an event handler method to react to an event, you must determine at runtime the trigger to which it is to react. You can do this with the following statement:
SET HANDLER h1 h2 ... [FOR]...
It links a list of handler methods with corresponding trigger methods. There are four different types of event.
7. Timing of Event Handling
After the RAISE EVENTstatement, all registered handler methods are executed before the next statement is processed (synchronous event handling). If a handler method itself triggers events, its handler methods are executed before the original handler method continues. To avoid the possibility of endless recursion, events may currently only be nested 64 deep.
Handler methods are executed in the order in which they were registered. Since event handlers are registered dynamically, you should not assume that they will be processed in a particular order. Instead, you should program as though all event handlers will be executed simultaneously.
Reward if useful.

Accessing exception information in an event handler method

Hi,
I am trying to handle an event thrown by a fatal exception. I am able to capture the event in this event handler method. However, I need to access the PREVIOUS of the exception in this event handler method and am not sure how to do it.
Can some one please help with this?
Thanks
Saravanan.

Hi,
Look at this code end check if your program works in the similar way.
Here, i'm changing an atribute from one class from other class.
If it doesn't works and you can't change an atribute directelly, i really don't know other way to do this.
      CLASS main DEFINITION
CLASS main DEFINITION.
PUBLIC SECTION.
    EVENTS evt EXPORTING value(e_data) TYPE char01.
    METHODS event_trigger.
    METHODS set_data IMPORTING i_data TYPE char01.
PRIVATE SECTION.
    DATA v_data TYPE char01 VALUE 'X'.
ENDCLASS.
      CLASS main IMPLEMENTATION
CLASS main IMPLEMENTATION.
METHOD event_trigger.
    RAISE EVENT evt EXPORTING e_data = v_data.
ENDMETHOD.
METHOD set_data.
    MOVE i_data TO v_data.
    WRITE: / 'New v_data value ->', v_data.
ENDMETHOD.
ENDCLASS.
      CLASS second DEFINITION
CLASS second DEFINITION.
PUBLIC SECTION.
    METHODS event_handler FOR EVENT evt OF main IMPORTING e_data sender.
ENDCLASS.
      CLASS second IMPLEMENTATION
CLASS second IMPLEMENTATION.
METHOD event_handler.
    WRITE: 'v_data value ->', e_data.
    CALL METHOD sender->set_data( i_data = 'Y' ).
ENDMETHOD.
ENDCLASS.
START-OF-SELECTION.
DATA: obj_main   TYPE REF TO main.
DATA: obj_second TYPE REF TO second.
CREATE OBJECT: obj_main, obj_second.
SET HANDLER obj_second->event_handler FOR obj_main.
call method obj_main->event_trigger( ).
Regards.
Marcelo Ramos

Handling exceptions for a event handler method.

Hi Mates,
I have two custom container in which i am displaying an alv grid usind objects. when a double click event is performed in one of the alv the other alv should be displayed. I now have to handle exceptions of the class CX_SY_DYN_CALL_ILLEGAL_TYPE. This is raised for an invalid parameter type when calling a method dynamically. I cannot use the keyword "RAISING" in the definition of the event handler method. i checked with the syntax of the method definition in abap dictionary, there were no addition "RAISING" for an event handler method. please provide me with the solution (a sample code would do.)

Hello,
May be you should read about the TRY ... CATCH block which is used for handling exceptions.
Basic construct of your code should look like this:
TRY.
" Your Dynamic Method call
CATCH CX_SY_DYN_CALL_ILLEGAL_TYPE.
ENDTRY.
If you want to get the error message text:
DATA:
lcx_excp TYPE REF TO CX_SY_DYN_CALL_ILLEGAL_TYPE,
v_err_msg TYPE string.
TRY.
" Your Dynamic Method call
CATCH CX_SY_DYN_CALL_ILLEGAL_TYPE INTO lcx_excp.
v_err_msg = lcx_excp->get_text( ).
ENDTRY.

Is there any way to send value to my attribute through event handler method

While I give value to the img array it does not print while I call object for this class. Is there any way that I could give value for img attribute
// Attribute
public var img:Array;
// Constructor
public function ReadXML(myfile:String) {
            img=new Array();
            xmlFile=myfile;
            var loader:URLLoader=new URLLoader;
            var url:URLRequest=new URLRequest(xmlFile);
          loader.addEventListener(Event.COMPLETE,onXMLLoad);
            loader.load(url);
// Event handling Method
        function onXMLLoad(event:Event):Array {
            var xml:XML=new XML(event.target.data);
            //trace(xml);
            //trace("Number of Contacts : " + xml..person.length());
            //trace("First contact’s favorite food : " + xml.contacts.person[0].@favoriteFood);
            img["height"]=100;
            img["width"]=200;
            return img;

what are you trying to do?
if img has anything to do with an image, explain.
if img is supposed to be an associate array, use:
var img:Object;
img=new Object();
etc

Getting error in event handler method onPlugFromStartView

Hi,
I am getting error in event handler method onPlugFromStartView java coding. The error message is u201CThe method wdGetwelcome componentcontroller() is undefined for the IPrivatevieew.
Plese explain how to resolve this error to deploy the webdynpro application successfully.
Thanks,
Kundan.

Hi
1.It seems some thing corrupt or some problem .
2. Do one exercise Create one new Dc --component -View ,In component write one method.
a) Open the view and then try to add that component.
Let us know the result
Best Regards
Satish Kumar

Button's Event Handler Method not getting triggered

To add a button I have written the following code:
clear ls_button.
    l_import = 'Mass Upload'.
    l_enabled = 'X'.
    clear ls_button.
    ls_button-on_click = 'UPLOAD'. "IMPORT FILE
    ls_button-text     = l_import.
    ls_button-enabled = l_enabled.
    INSERT ls_button INTO rt_buttons INDEX 5.
Created a new Event Handler method for it and wrote the following code:
gr_file_popup = comp_controller->window_manager->create_popup(
    iv_interface_view_name = 'ZSRQM_INCID_H/FileUploadwindow'
    iv_usage_name = 'ZCufileupload'
    iv_title = l_title ).
gr_file_popup->set_on_close_event( iv_view = me iv_event_name = 'upload' ).
gr_file_popup->open( ).
When i run in th component in debug mode,my event is not getting triggered.
Please suggest.
Regards
Najam

Try the following code in first part...
clear ls_button.
    l_import = 'Mass Upload'.
    clear ls_button.
    ls_button-on_click = 'UPLOAD'. "IMPORT FILE
    ls_button-text     = l_import.
    ls_button-page_id = me->component_id.
    ls_button-enabled = abap_true.
    INSERT ls_button INTO rt_buttons INDEX 5.

Using page attribute in event handler method of controller

Hi all,
I have created a page attribute GT_TABLE. I need to use this table in one of the event handler methods of the controller of the same page. I tried to use the GET_ATTRIBUTE method but it always returns an empty table.
Can someone please guide me in this respect.
Thanking you in advance,
Regards,
Sumit.

Hi Sumit,
The page attribute you mention (GT_TABLE) it's an internal table, isn't it? So far I know, the value of internal table will gone when BSP finish to load in server. If you want to keep the data in internal table, you need to load the internal table into Session (in one of page event in BSP).
Regards
David

Populating database tables in event handler method - error

Friends,
I am trying to insert values into ztable in an event handler method in a WDA application.
This is the code. ZDATA1 is a ztable with two fields: MANDT and ZKTOKD of data element char01.
types: begin of zs,
zktokd type char01,
end of zs.
data: zitab type table of zs,
zstruct like line of zitab.
zstruct-zktokd = 's'.
append zstruct to zitab.
INSERT zdata1 FROM TABLE zitab.
I am getting the error: "The Work area "ZITAB" is not long enough...
Please let me know what is missing.
Thanks and Regards.

Hi,
The error is here
types: begin of zs,
zktokd type char01,
end of zs.
data: zitab type table of zs ,
zstruct like line of zitab.
"passed the Internal table name which is wrong
Correct one
data:
zitab type table of zs,
zstruct like line of ZS. " Here we have to give the type you have declared above.
" Zstruct acts like a workarea.
Regards
Lekha

Error in event handler method in window

Hi,
I have created configuration in SEFVISU, to receive the workitem i have created a parameter in event handler method in window
but it is throwing dump The ASSERT condition was violated, if i remove that parameter means application executing properly but i am not able to pass the unique, values please guide me.
Regards,
Srini.

Hello Srini,
are you talking about the default event handler method of the window? if so then you need to ensure that the parameter name defined in the event and passed in name are same. And also its better to go for the parameter type as STRING.
other option would be instead of defining the static parameters in the event handler method, you can get the parameters from the WDEVENT itself by accessing WDEVENT->PARAMETERS table.
hope this helps.
BR, Saravanan

How to call the event handler of other application....?

Hi,
I am working on two applications.
Now i need to call a Event handler from my first application to my second application.
I need a same process in this aaplication also. So i need to call the event handler of that application.
So, Kindly tell me about the process to call the even handler of another application.
Thanks in Advance.
Regards,
Prithivi

hi,Prithivi..
Unfortunately, as far as i know, i should tell you that : you cann't call the event-hanlder in another Application if the 2 applicaions are run in different IE browser...
If your 2 component are used in the same IE browser, maybe you can make one interface event, and trigger it in one component, then handle the event in the second component(by reimplemented the former)...
However, from your description, i think, you want to trigger the event handler in another application in different IE Browser...
So, very upset..We cann't communicate between the 2 applications, as far as i know...
Best wishes.

Repetitive call of event handler method

Similar Messages

Maybe you are looking for