Replace an existing file with a new one

Question

This is probably a very simple problem. I have a script that is making an XML document. I am sucking information out of a database and exporting it as a XML file. The script runs just dandy except when I want to update the text file I receive an error along the lines of "the file already exists".
What code do I use to replace an existing file?
tell application "Finder"
set theFile to "donky.xml" as string
set theFullName to mySavePathAsText & theFile
set theNewFile to make new file at myPath with properties {name:theFile}
write myFinalText to file theFullName
set the extension hidden of theNewFile to false
end tell
I assume I would use the "replacing yes" command but that is not working or I am not doing it right.
Any help much appreciated.

Answer 1

Hello
Two things.
• 'open for access file _path with write permission' will create new file at the path given in _path if it's not present.
• 'set eof' command will clear the existing contents of the given file, which lets you replace the contents.
So you may try something like this. (Finder is only used to set 'extension hidden' property of the file)
Good luck
H
-- SNIPPET
set theFileName to "donky.xml"
set theFullPath to mySavePathAsText & theFileName
try
set fref to open for access file theFullPath with write permission
set eof fref to 0 -- clear the existing contents
write myFinalText to fref starting at eof
close access fref
on error errs number errn
try
close access file theFullPath
on error --
end try
error errs number errn
end try
tell application "Finder"
set extension hidden of item theFullPath to false
end tell
-- END OF SNIPPET