Replace movie icon

Question

Hello,
I'm newbie on this forum so I apologize if I'm not posting at the right place.
I have a external HD with a hundreds of folders. Each folder contains two files having same name but different format: a pic file (AAAAA.jpg) and a movie file (AAAAA.avi or AAAAAA.wmv). For each movie, I would like to replace the icon (available in the GET INFO menu) with the picture of the corresponding .jpg file.
Is there any possibility to do it automatically using automator ?
The only solution I found so far is to do it manually by opening the pic file, copy the pic, open the "get info" menu of the movie file and then paste the pic as icon.
Thank you in advance for your suggestion,
Banpo

Answer 1

This is more of an AppleScript situation, although you can put a script into an Automator workflow. There are some utilities in the *Developer Tools* (an optional install on your OS installation disk) that can be used to create and set icons. If you have these tools installed (specifically, Rez, DeRez, and SetFile), give the following a try:
1) *Get Specified Finder Items* (or however you want to get the input items)
2) *Filter Finder Items* { Find files where kind is folder } -- limit input to folders
3) *Run AppleScript* (paste the following script):
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into an Automator 'Run AppleScript' action">
on run {input, parameters} -- set a file icon
gets an image from the first jpg file of a folder, and sets it as the icon for the first non-jpg file of a folder
input [Finder Items]: folders to process
output [Finder Items]: folders successfully processed
set output to {}
set skippedItems to {} -- this will be a list of skipped items (errors)
try -- check for required tools
get POSIX file "/Developer/Tools/" as text as alias
on error
error "required Developer Tools not installed"
end try
repeat with aFolder in the input
set aFolder to contents of aFolder
try
tell application "Finder"
set theName to name of aFolder
set iconFile to (first file of aFolder whose name extension is "jpg") as alias -- find the icon image file
(duplicate iconFile to (path to temporary items) with replacing) as alias -- make a temporary copy
set tempImage to quoted form of POSIX path of the result
set destination to (first file of aFolder whose name extension is not "jpg") as alias -- get the other file
set destination to POSIX path of destination
end tell
set tempResource to quoted form of (POSIX path of (((path to temporary items) as text) & "SetIconTempResource"))
do shell script "/usr/bin/sips -i " & tempImage -- add a Finder icon to the image
do shell script "/Developer/Tools/DeRez -only icns " & tempImage & " > " & tempResource -- get the icon resource
do shell script "/Developer/Tools/Rez -a " & tempResource & " -o " & quoted form of destination -- add resource to the file
do shell script "/Developer/Tools/SetFile -a C " & quoted form of destination -- set custom icon attribute
set the end of the output to aFolder -- success
tell application "Finder" to update (destination as POSIX file)
on error errorMessage number errorNumber -- oops
log errorMessage
set errorNumber to "  (" & (errorNumber as text) & ")"
-- set the end of skippedItems to (aFolder as text) & errorNumber -- full path
set the end of skippedItems to quoted form of theName & errorNumber -- just the name
end try
try -- remove temporary files
do shell script "rm " & tempImage & space & tempResource
end try
end repeat
showSkippedAlert for skippedItems
return the output -- pass the result(s) to the next action
end run
to showSkippedAlert for skippedItems
show an alert dialog for any items skipped, with the option to cancel the rest of the workflow
parameters - skippedItems [list]: the items skipped
returns nothing
if skippedItems is not {} then
set {alertText, theCount} to {"Error with AppleScript action", count skippedItems}
if theCount is greater than 1 then
set theMessage to (theCount as text) & space & " items were skipped:"
else
set theMessage to "1 item was skipped:"
end if
set {tempTID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, return}
set {skippedItems, AppleScript's text item delimiters} to {skippedItems as text, tempTID}
if button returned of (display alert alertText message (theMessage & return & skippedItems) alternate button "Cancel" default button "OK") is "Cancel" then error number -128
end if
return
end showSkippedAlert
</pre>
4) other actions as desired