Reverting an alias based Library to an iPhoto organized one.

Question

Hi,
When I installed iPhoto 6, I opted to keep my photo directory separate (Read: unchecked "Copy Files to iPhoto Library folder" option). I soon realized that I couldn't manage the files from within iPhoto anymore (e.g. can't completely remove pictures).
Now I want to revert my library and start letting iPhoto organize the files. I wasn't able to see such an option in iPhoto (the preference I mentioned above only applies to new files, not existing ones). I have around 10,000 pictures with several layers of hierarchy, so a manual solution isn't an option. I don't want to lose other information in my library (ratings, albums and other metadata) so I can't start a new library either.
I know that modifying files from Finder is a "no-no", but I cannot see any other options. So, I wanted to write a script that will go through the iPhoto Library/Originals folder and replace each alias with the original file (after a full back-up of course).
I tried this with a single file, but wasn't able to move the file (see below script). If this works, I can do the same for all files under the Originals folder.
try
set this_file to choose file
set this_folder to the folder of this_item
tell application "Finder"
set orig_item to the original item of this_item
move orig_item to this_folder with replacing
end tell
end try
Unfortunately, this did not replace the file as I intended.
Any ideas/suggestions?

Answer 1

Hi eatalay,
Here's an example of a recursive subroutine that replaces all alias files, in a passed folder path, with their originals.
set f to choose folder
ProcessAlias(f as string)
-- replacess all alias files in the passed folder path (string)
on ProcessAlias(this_folder)
-- get list of folders in this_folder
set utid to AppleScript's text item delimiters -- store old delimiters
set AppleScript's text item delimiters to {return}
tell application "Finder"
set folder_listing to every folder of folder this_folder as string
end tell
set AppleScript's text item delimiters to utid -- restore old delimiters
if folder_listing is "" then
set folder_list to {}
else
set folder_list to paragraphs of folder_listing
end if
-- process folder_list
repeat with sub_folder in folder_list
ProcessAlias(sub_folder) -- send each folder back to this subroutine
end repeat
-- get list of alias files and process them
tell application "Finder"
set alias_files to every file of folder this_folder whose kind is "Alias"
repeat with this_alias in alias_files
try -- error if broken alias
set orig_item to original item of this_alias
set item_dest to container of this_alias
move orig_item to item_dest with replacing
end try
end repeat
end tell
return -- you can return a listing of moved originals if you want
end ProcessAlias
I didn't test for broken aliai yet, but it looks ok. I just thought of something. You might want to keep a list of broken alias files and return it from the subroutine. You can then delete the broken alias or fix them.
gl,