Rule based classification errors in creating CLASSIFIER.THIS

Question

package body "STARDOC".classifier as
procedure this
is
v_document     blob;
v_item          number;
v_doc           number;
begin
for doc in (select document_id, content from documents)
     loop
          v_document :=doc.content;
          v_item:=0;
          v_doc:=doc.document_id;
     for c in (select category_id, category_name from doc_cats_rule_based_class
               where MATCHES (doc_cats_rule_based_class.QUERY, v_document)>0)
          loop
               v_item:=v_item +1;
               insert into doc_cat_rule_based_class values (c.document_id, c.category_id);
          end loop;
     end loop;
end this;
end;
Errors:
Error     1     PLS-00306: wrong number or types of arguments in call to 'MATCHES'     ORACLE://stardoc.(Local Database)/Package Body/STARDOC/CLASSIFIER*     17     10     
Error     2     PL/SQL: ORA-00904: "MATCHES": invalid identifier     ORACLE://stardoc.(Local Database)/Package Body/STARDOC/CLASSIFIER*     17     10     
Error     3     PL/SQL: SQL Statement ignored     ORACLE://stardoc.(Local Database)/Package Body/STARDOC/CLASSIFIER*     16     11     
Error     4     PLS-00364: loop index variable 'C' use is invalid     ORACLE://stardoc.(Local Database)/Package Body/STARDOC/CLASSIFIER*     20     64     
Error     5     PL/SQL: ORA-00984: column not allowed here     ORACLE://stardoc.(Local Database)/Package Body/STARDOC/CLASSIFIER*     20     66     
Error     6     PL/SQL: SQL Statement ignored     ORACLE://stardoc.(Local Database)/Package Body/STARDOC/CLASSIFIER*     20     4     
i store the documents in Documents(document_id,content) table, rules in
doc_cats_rule_based_class(CATEGORY_ID,CATEGORY_NAME,QUERY)
and store the assigned document-category in doc_cat_rule_based_class(DOCUMENT_ID,CATEGORY_ID).
Please Help

Answer 1

I believe the problem is with trying to pass a value of blob datatype as a parameter to matches. Try using utl_cast_to_varchar2 as demonstrated below.
SCOTT@10gXE> CREATE TABLE Documents
  2    (document_id    NUMBER,
  3       content        BLOB)
  4  /
Table created.
SCOTT@10gXE> INSERT INTO documents VALUES (1, UTL_RAW.CAST_TO_RAW ('contents of document'))
  2  /
1 row created.
SCOTT@10gXE> CREATE TABLE doc_cats_rule_based_class
  2    (CATEGORY_ID    NUMBER,
  3       CATEGORY_NAME  VARCHAR2 (15),
  4       QUERY            VARCHAR2 (30))
  5  /
Table created.
SCOTT@10gXE> INSERT INTO doc_cats_rule_based_class VALUES (1, 'test_cat', 'contents OR document')
  2  /
1 row created.
SCOTT@10gXE> CREATE INDEX your_index ON doc_cats_rule_based_class (query)
  2  INDEXTYPE IS CTXSYS.CTXRULE
  3  /
Index created.
SCOTT@10gXE> CREATE TABLE doc_cat_rule_based_class
  2    (DOCUMENT_ID    NUMBER,
  3       CATEGORY_ID    NUMBER)
  4  /
Table created.
SCOTT@10gXE> CREATE OR REPLACE package classifier as
  2    procedure this;
  3  end classifier;
  4  /
Package created.
SCOTT@10gXE> SHOW ERRORS
No errors.
SCOTT@10gXE> CREATE OR REPLACE package body classifier as
  2    procedure this
  3    is
  4    v_document blob;
  5    v_item number;
  6    v_doc number;
  7    begin
  8        for doc in (select document_id, content from documents)
  9        loop
10          v_document :=doc.content;
11          v_item:=0;
12          v_doc:=doc.document_id;
13          for c in (select category_id, category_name from doc_cats_rule_based_class
14                 where MATCHES (doc_cats_rule_based_class.QUERY, UTL_RAW.CAST_TO_VARCHAR2 (v_document))>0)
15          loop
16            v_item:=v_item +1;
17            insert into doc_cat_rule_based_class values (doc.document_id, c.category_id);
18          end loop;
19        end loop;
20    end this;
21  end classifier;
22  /
Package body created.
SCOTT@10gXE> SHOW ERRORS
No errors.
SCOTT@10gXE> EXECUTE classifier.this
PL/SQL procedure successfully completed.
SCOTT@10gXE> SELECT * FROM doc_cat_rule_based_class
  2  /
DOCUMENT_ID CATEGORY_ID
          1           1
SCOTT@10gXE>