Script for forward mail as attachment

Question

Hi,
I think there is no direct call for creating forward mail as attachment. I tried "forward" reply and other things.Its working fine.
Please let me know if any one have idea for creating script for apple mail "forward as attachment".

Answer 1

hm... perhaps these two functions do what you wanna do :-/
on createmail_emlx_files_attachment_ofselection()
tell application "Mail"
-- get the mail selection
set myMessages to selection
--do it to every selected mail
repeat with m in myMessages
--get the folder where the emlx file is stored in
set mypath to quoted form of POSIX path of ((account directory of account of mailbox of m) as alias)
--get the id of that message (should be unique within each account)
set myid to id of m
--find the folder where this unique email (by id) is stored in
set myfolder to quoted form of (paragraph 1 of (do shell script "find " & mypath & " -name '" & myid & ".emlx' -exec dirname {} \\;"))
--create a compressed tar archive of this message and open this gzipped files with Apple Mail (-> attach it to a new message).
do shell script "cd " & myfolder & ";tar -rf " & myid & ".tar " & myid & ".emlx;gzip " & myid & ".tar;mv " & myid & ".tar.gz /tmp/;open -a /Applications/Mail.app /tmp/" & myid & ".tar.gz"
end repeat
end tell
end createmail_emlx_files_attachment_ofselection
on createmail_source_attachment_ofselection()
tell application "Mail"
-- get the mail selection
set myMessages to selection
--do it to every selected mail
repeat with m in myMessages
set myid to id of m
set mysource to quoted form of ((source of m) as text)
do shell script "cd /tmp/;echo " & mysource & "|cat>/tmp/" & myid & ".txt;gzip " & myid & ".txt;open -a /Applications/Mail.app " & myid & ".txt.gz"
end repeat
end tell
end createmail_source_attachment_ofselection