Automator/applescript to forward junk mail as attachment...how?

Question

I finally came up with a real use for Automator and Applescript -- I was delighted.
I want to modify my junk mail rule to run an Applescript that forwards a mail message as an attachment (not just a regular forward) to Spamcop.
It has to be forwarded as an attachment. First shot, I simply went to modify my junk mail rule but, alas, found that "forward as attachment" is not an option for Mail's rules. Fortunately, there is a "run Applescript" option so...
I fired up Automator, hoping to see how to tell Mail to forward a message as an attachment. Again, alas, no "as attachment" option there. So then I started exploring how to invoke the Mail menu item Message > Forward as Attachment but, haven't been able to figure it out.
Any help would be appreciated. Especially since this will be the first time I've actually found a use for Automator, which is great... I just know it's not merely eye candy...

Answer 1

Here is some starter code, to be saved into the current users' '~/Library/Scripts/Applications/Mail/' folder - as a script file ...
using terms from application "Mail"
on perform mail action with messages tMessages
repeat with i in tMessages -- Cycle throught the list of incoming 'Rule' filtered e-Mail messages.
-- File path file Name of temporary attachement file.
set file_Name to (((path to home folder from user domain) as string) & (do shell script "date +%Y%m%d%H%M%StempFile.txt"))
try -- Capture any unexpected AppleScript error.
set FREF to open for access file file_Name with write permission -- Create temporary attachement file.
write ((source of i) as string) to FREF starting at 0 -- Write to temporary attachement file.
close access FREF -- Close temporary attachement file.
-- Make new outgoing e-Mail message, and attach respective attachment file.
set tMessage to make new outgoing message with properties {visible:true, subject:"My Subject", content:("My Body" & return & return)}
tell content of tMessage
make new attachment with properties {file name:(file_Name as alias)} at after last paragraph
end tell
end try
try -- Capture any unexpected AppleScript error.
tell application "Finder" to delete file file_Name -- Trash temporary attachement file.
end try
end repeat
end perform mail action with messages
try -- Capture any unexpected AppleScript error.
tell application "Finder" to empty trash -- Delete all temporary attachement files (plus all other items) in the trash can.
end try
end using terms from