Search in database in all the tables

Question

Hi friends,
I want to search following text in database in all the tables :
Paris-Murex BO for BNL- Panorama(Roma) / BNL-Panorama for Paris-Murex BO(Roma)
above text is thr in our client site which is getting retrieved from database, I know the database instance name but but dont know from which table this value (text) is comming from.
please help it's urgent!!!

Answer 1

This is a depressingly common request. Why are there so many shonky undocumented applications out there?
Anyway, the solution for a one-off exercise is this brute force approach. It's not pretty and the performance will be Teh Suck, but it will find the string. If you think that the string might be in more than one column you should remove the EXIT and let the thing grind on for as long as it takes.
set serveroutput on
declare
    n number;
begin
    for r in ( select owner, table_name, column_name
               from all_tab_columns
               where owner not in ('SYS', 'SYSTEM')
               and   data_type in ('CHAR', 'VARCHAR2')
               and   data_length >= 43 )
    loop
        dbms_output.put_line('checking!!'||r.owner||'.'||r.table_name||'.'||r.column_name);
        begin
            execute immediate 'select 1 from '||r.owner||'.'||r.table_name
                          ||' where '||r.column_name||' like ''%Paris-Murex BO for BNL- Panorama(Roma) / BNL-Panorama for Paris-Murex BO(Roma)%'''
                          ||' and rownum = 1'
            into n;
            dbms_output.put_line('found it!!'||r.owner||'.'||r.table_name||'.'||r.column_name);
            exit;
        exception
            when no_data_found
            then
                null;
        end;
    end loop;
end;
/If you have CLOBs and BLOBs you want to check as well then you'll need to run through a second query using CONTAINS(). Implementing that is left as an exercise for the reader.
Note that if you want to do this on a regular basis then you need a completely different, more architectural approach.
Cheers, APC
blog: http://radiofreetooting.blogspot.com