Selection-screen .... How to lock the whole block ??? urgent

Question

i have created a selection with two blocks.
selection-screen begin of block d2 with frame title text-005 .
parameters r_create radiobutton group g3 USER-COMMAND u1.
parameters r_add radiobutton group g3.
selection-screen end of block d2.
selection-screen skip 1.
selection-screen begin of block b3 with frame title text-009.
parameters: pvenmap as checkbox default 'X'.
parameters: psermap no-display. "as checkbox default 'X' .
parameters: pmatlmap as checkbox. "default 'X'.
selection-screen end of block b3.
selection-screen begin of block b2 with frame title text-005 .
parameters r_valid no-display." radiobutton group g2 .
parameters r_master radiobutton group g2.
parameters p_sercat like asmd-astyp default 'SERV' no-display.
parameters p_serv  radiobutton group sm1 default 'X'.
parameters p_genc  radiobutton group sm1.
parameters p_act  radiobutton group sm1.
parameters r_agrmt  radiobutton group g2.
parameters p_extnum like ekko-ebeln no-display.
selection-screen end of block b2.
Now i want that when radio button r_create is 'X' then block 'B2' should be locked/disabled and when r_add is 'X' then block 'B3' should be locked/disabled.
One method is :-
AT SELECTION-SCREEN ON RADIOBUTTON GROUP g3.
  v_ucomm = sscrfields-ucomm .
IF r_create EQ c_x .
      LOOP AT SCREEN.
      IF screen-name = ........
        screen-input = c_0.
        MODIFY SCREEN.
      ENDIF.
      ENDLOOP.
  ENDIF.
but is there any other method such that i can disable/lock the whole block, instead of locking each field ???
regards
Rahul

Answer 1

Hi Rahul,
Please check the code below:
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
PARAMETERS: p_file  TYPE rlgrap-filename MODIF ID abc, " OBLIGATORY,
            p_lifnr TYPE lfa1-lifnr      MODIF ID abc,
            p_vkorg TYPE vbak-vkorg      MODIF ID abc.
SELECTION-SCREEN END OF BLOCK b1.
SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME TITLE text-002.
PARAMETERS: p_kunnr TYPE vbak-kunnr MODIF ID def.
SELECT-OPTIONS: s_lifnr FOR lfa1-lifnr MODIF ID def,
                s_date  FOR lfa1-erdat MODIF ID def,
                s_augru FOR vbak-augru MODIF ID def,
                s_vbeln FOR vbak-vbeln MODIF ID def.
SELECTION-SCREEN END OF BLOCK b2.
SELECTION-SCREEN BEGIN OF BLOCK b3 WITH FRAME TITLE text-003.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: upload RADIOBUTTON GROUP g1 USER-COMMAND uc01.
SELECTION-SCREEN COMMENT 3(60) text-025 FOR FIELD upload.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
PARAMETERS: reprss RADIOBUTTON GROUP g1 .                   "#EC *
SELECTION-SCREEN COMMENT 3(60) text-026 FOR FIELD reprss.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK b3.
AT SELECTION-SCREEN OUTPUT.
  IF reprss EQ 'X'.
    LOOP AT SCREEN.
      IF screen-group1 = 'ABC'.
        screen-input = '0'.
      ELSEIF screen-group1 = 'DEF'.
        screen-active = '1'.
      ENDIF.
      MODIFY SCREEN.
    ENDLOOP.
  ELSEIF upload EQ 'X'.
    LOOP AT SCREEN.
      IF screen-group1 = 'DEF'.
        screen-input = '0'.
      ELSEIF screen-group1 = 'ABC'.
        screen-active = '1'.
      ENDIF.
      MODIFY SCREEN.
      CLEAR upload.
    ENDLOOP.
Regards
kannaiah
please reward useful points