Simple Apple Script Required

Question

Hey
Im looking for a simple AppleScript i can run on client workstations , The Script ideally needs to do the following ..
- Find any files in the User's Home folder with a Creation date older than 3 years ago.
- Display the files and allow user to delete.
Im sure this is quite simple for someone who knows what there doing with AppleScript ! , anyone have any simple scripts they could suggest ?
Cheers

Answer 1

Well, getting a list of files is one thing (there are several shell utilities), getting them in a Finder window so you can do various things with them is another. There isn't much AppleScript support for the Finder's Find…, and saved searches don't appear to be portable. GUI scripting is more akin to voodoo, but I figured I would give it a shot to see if I could get close.
The following script pastes the appropriate search term in the Search item in a Finder window's toolbar. Getting the search to start in a specific place is a bit goofy, but if you have navigated to the desired folder, running the script should start the search from there:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- enter a search term in the Finder's search toolbar item
-- set the search date
tell ((current date) as «class isot» as string)
(get text 1 thru 4) - 3 -- the current year - 3
set SearchDate to text 6 thru 7 & "/" & text 9 thru 10 & "/" & result
end tell
-- make sure there is a Finder window and the toolbar is showing
tell application "Finder"
activate
if (get windows) is {} then set target of (make new Finder window) to path to home folder
if not toolbar visible of front window then set toolbar visible of front window to true
end tell
-- enter the search term into the search text field, if present
tell application "System Events"
if UI elements enabled then
get value of attribute "AXRoleDescription" of text field 1 of group 1 of tool bar of front window of application process "Finder"
if (result as text) is "search text field" then -- toolbar search item exists
set value of text field 1 of group 1 of tool bar of front window of application process "Finder" to "created:<=" & SearchDate
else -- oops
activate
display dialog "This script needs to use the Search item on the toolbar - please customize the Finder toolbar to include Search." with title "Find by creation date" buttons {"OK"} default button 1
end if
else
tell application "System Preferences"
activate
set current pane to pane "com.apple.preference.universalaccess"
display dialog "This script needs UI element scripting enabled. Check \"Enable access for assistive devices\" and try again." with title "Find by creation date" buttons {"OK"} default button 1
end tell
end if
end tell
</pre>
HTH