Simple Transformation XML to ABAP Content of tag with subtrees to string field

Question

Hi,
I have an  requirement in which I have to do a transformation from an XML file to an structure.
I need get the value of a tag that have subtrees and move that to a field in my structure.
Example:
<TAG1>value1</TAG1>
<TAG2>value2</TAG2>
<TAG3>
     <TAG4>value4</TAG4>
     <TAG5>value5</TAG5>
</TAG3>
Result expected in ABAP Structure:
field1 -> tag1
field2 -> tag2
field3 -> <TAG4>value4</TAG4><TAG5>value5</TAG5>
The contents of the tag TAG3 is variable, so I want to store it as a string.
Can I make this with Simple Transformation?
In my tests I can move only the value of each child tag for the given field structure.
This syntax dont work:
<TAG3 tt:value-ref="STRUCTURE.FIELD3"/>
Thanks and Regards,
Miguel Motta

Answer 1

Hi Miguel
Have a look at below snippets. Here I have tried to escape the text inside TAG3 so that it gets treated as single node during transformation.
ABAP code
DATA: BEGIN OF result,
        col1 TYPE string,
        col2 TYPE string,
        col3 TYPE string,
      END OF result.
DATA: xml_string TYPE string VALUE
'<ROOT> <TAG1>value1</TAG1> <TAG2>value2</TAG2> <TAG3> <TAG4>value4</TAG4> <TAG5>value5</TAG5> </TAG3> </ROOT>',
      part1 TYPE string,
      part2 TYPE string,
      part3 TYPE string.
*   Escape the text inside TAG3 tag
FIND REGEX '(.*<TAG3>)(.*)(</TAG3>.*)' IN xml_string SUBMATCHES part1 part2 part3.
IF sy-subrc EQ 0.
  part2 = escape( val = part2 format = cl_abap_format=>e_xml_text ).
*      REPLACE ALL OCCURRENCES OF '<' IN part2 WITH '&lt;'.
*      REPLACE ALL OCCURRENCES OF '>' IN part2 WITH '&gt;'.
  xml_string = part1 && part2 && part3.
ENDIF.
TRY.
* Display xml
    cl_abap_browser=>show_xml( EXPORTING xml_string = xml_string ).
* Deserialization
    CALL TRANSFORMATION zmtest
      SOURCE XML xml_string
      RESULT para = result.
* Check result
    WRITE:/ 'COL1=', result-col1,
          / 'COL2=', result-col2,
          / 'COL3=', result-col3.
  CATCH cx_st_error.
* Error handling
    MESSAGE 'Error in Simple Transformation'
            TYPE 'I' DISPLAY LIKE 'E'.
ENDTRY.
Transformation code
<?sap.transform simple?>
<tt:transform xmlns:tt="http://www.sap.com/transformation-templates" template="temp" version="0.1">
   <tt:root name="PARA"/>
   <tt:template name="temp">
     <ROOT>
       <TAG1>
         <tt:value ref="PARA.COL1"/>
       </TAG1>
       <TAG2>
         <tt:value ref="PARA.COL2"/>
       </TAG2>
       <TAG3>
         <tt:value ref="PARA.COL3"/>
       </TAG3>
     </ROOT>
   </tt:template>
</tt:transform>