Smartform NODIALOG , OTF issue

Question

Hi Experts,
My requirement is to convert Smartform to PDF and download it in local drive. I wanted to suppress the Print option dialog, I have done the coding to suppress it but still the Print Option dialog opens and It asks for Print . If i give print Preview also, When i check the return parameter ( it_jobout1-otfdata[ ]) from Smartform function module , the OTF  data is Empty. I have attached my code below. Please suggest  me what i am missing to suppress the dialog and to get the OTF data in return ?
        v_control_parameters-getotf = 'X'.
        v_control_parameters-no_dialog = 'X'.
        v_control_parameters-device = 'PRINTER'.
  wa_compop-tddest = 'LOCL'.
*TO CALL THE  FUNCION MODULE TO PRINT THE SMART FORMS
        CALL FUNCTION v_fun_name
          EXPORTING
            control_param    = v_control_parameters
            output_options   = wa_compop
           user_settings      = ' '
            is_ekko          = is_ekko
            v_tot            = v_tot
            v_menge          = v_menge
            v_meins          = v_meins
          IMPORTING
            job_output_info  = it_jobout1
          TABLES
            it_tab1          = it_tab1
            it_tab2          = it_tab2
            it_tab3          = it_tab3
            it_hedr          = it_hedr
          EXCEPTIONS
            formatting_error = 1
            internal_error   = 2
            send_error       = 3
            user_canceled    = 4
            OTHERS           = 5.
        IF sy-subrc <> 0.
          MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                  WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
        ENDIF.
        wa_conv_file = it_jobout1-otfdata[].
*TO CONVERT THE OTF DATA TO PDF
        CALL FUNCTION 'CONVERT_OTF'
          EXPORTING
            format                = 'PDF'
            max_linewidth         = 132
          IMPORTING
            bin_filesize          = l_file_size
          TABLES
            otf                   = wa_conv_file
            lines                 = wa_dwld_file_format
          EXCEPTIONS
            err_max_linewidth     = 1
            err_format            = 2
            err_conv_not_possible = 3
            err_bad_otf           = 4
            OTHERS                = 5.
        IF sy-subrc <> 0.
          LOOP AT wa_dwld_file_format INTO wa_tline.
            ASSIGN wa_tline TO <p> CASTING TYPE x.
            CONCATENATE outputx <p> INTO outputx IN BYTE MODE.
          ENDLOOP.
          EXPORT outputx TO MEMORY ID id_itab.
        ENDIF.

Answer 1

Hi Murali,
Very strange. After passing the parameters, the pop up will only come if there are mandatory parameters which are not passed.
I am attaching my complete code below
DATA
       : l_control_parameters TYPE ssfctrlop,
         l_output_options     TYPE ssfcompop,
         l_bin_filesize       TYPE i,
         l_file_name          TYPE string,
         l_text               TYPE string.
  DATA
       : lit_job_output_info  TYPE ssfcrescl,
         lit_pdf              TYPE TABLE OF tline.
  l_control_parameters-no_dialog = c_x.
  l_control_parameters-preview   = c_x.
  l_output_options-tddest    = 'LP01'. "--> Make sure the printer name is correct (Check table TSP03)
  l_output_options-tdnoprint = c_x.
  IF x_pdf = c_x. "--> Based on selection screen input i decide to convert to PDF
    l_control_parameters-getotf = c_x.
  ENDIF.
CALL FUNCTION p_l_form
    EXPORTING
      control_parameters = l_control_parameters
      output_options     = l_output_options
      user_settings      = space
      i_bukrs            = p_l_final-bukrs
      i_gsber            = p_l_final-gsber
      i_butxt            = p_l_final-butxt
      i_gtext            = p_l_final-gtext
      i_budat_from       = g_budat_from
      i_budat_to         = g_budat_to
      it_final           = it_final
    IMPORTING
      job_output_info    = lit_job_output_info
    EXCEPTIONS
      formatting_error   = 1
      internal_error     = 2
      send_error         = 3
      user_canceled      = 4
      OTHERS             = 5.
  IF sy-subrc EQ 0.
    IF x_pdf = c_x.
      PERFORM convert_otf_pdf
              USING lit_job_output_info-otfdata
              CHANGING lit_pdf
                       l_bin_filesize.
    ENDIF.
ENDIF
FORM convert_otf_pdf
     USING p_it_otfdata TYPE tsfotf
     CHANGING p_it_pdf TYPE tline_t
              l_bin_filesize TYPE i.
  DATA
       : lit_docs TYPE TABLE OF docs.
  CALL FUNCTION 'CONVERT_OTF_2_PDF'
* EXPORTING
*   USE_OTF_MC_CMD               = 'X'
*   ARCHIVE_INDEX                =
IMPORTING
      bin_filesize                 = l_bin_filesize
    TABLES
      otf                          = p_it_otfdata
      doctab_archive               = lit_docs
      lines                        = p_it_pdf
   EXCEPTIONS
     err_conv_not_possible        = 1
     err_otf_mc_noendmarker       = 2
     OTHERS                       = 3
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    " CONVERT_OTF_PDF