Special characters being read from the unicode file for greek language

Question

Hi All,
I have a report which would upload a unicode file and then update the vendor master data accordingly.
The file contains greek characters too.
when the file is being read in the code, some special characters are being added up to the vendor number which is the first entry. The special characters are not included in the file , but are added up only to the first vendor number and not any other vendor numbers.
The logic that is being used is as follows :
TRY.
      IF unicode IS INITIAL.
        IF codepage IS INITIAL.
*-->      For backward compatibility where this FM might be called from
*         other dependent objects (FMs/dynamic subroutines)
*         which donot have access to  user's input w.r.t Unicode parameters
          OPEN DATASET filename FOR INPUT
               IN LEGACY TEXT MODE
               MESSAGE msg
               REPLACEMENT CHARACTER repl_char
               IGNORING CONVERSION ERRORS
               FILTER filter.                         
        ELSE.
*--> System in non-unicode and Unicode Environment (Phases I and II)
          OPEN DATASET filename FOR INPUT
               IN LEGACY TEXT MODE CODE PAGE codepage MESSAGE msg
               REPLACEMENT CHARACTER repl_char
               IGNORING CONVERSION ERRORS
               FILTER filter.                          
        ENDIF.
      ELSE.
*-->  Extract File in Unicode format - Phase III
        OPEN DATASET filename FOR INPUT IN TEXT MODE ENCODING UTF-8
        MESSAGE msg
        FILTER filter.                                 
      ENDIF.
      IF sy-subrc NE 0.
        MESSAGE e001(zuni) WITH filename sy-subrc
         RAISING file_open_error.
      ENDIF.
the unicode parameters used are : codepage = 8000.
An early reply is most appreciated.
Regards,
Manu.

Answer 1

Please check SAP notes for Eastern European Characters in Unicode system. and may be below code helps you
DATA:
    ltp_bom                  TYPE sychar01,
    ltp_encoding             TYPE sychar01,
    ltp_codepage             TYPE cpcodepage.
Processing --------------------------------------------------------- *
  TRY.
      CALL METHOD cl_abap_file_utilities=>check_utf8
        EXPORTING
          file_name         = itp_filename
          max_kb            = -1
          all_if_7bit_ascii = abap_true
        IMPORTING
          bom               = ltp_bom
          encoding          = ltp_encoding.
    CATCH cx_sy_file_open .
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
              RAISING file_open_error.
    CATCH cx_sy_file_authority .
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
              RAISING file_authority_error.
    CATCH cx_sy_file_io .
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
              RAISING file_io_error.
  ENDTRY.
  CASE ltp_encoding.
    WHEN cl_abap_file_utilities=>encoding_utf8
      OR cl_abap_file_utilities=>encoding_7bit_ascii.
      CASE ltp_bom.
        WHEN cl_abap_file_utilities=>no_bom.
          OPEN DATASET itp_filename FOR INPUT IN TEXT MODE
            ENCODING UTF-8.
        WHEN cl_abap_file_utilities=>bom_utf8.
          OPEN DATASET itp_filename FOR INPUT IN TEXT MODE
            ENCODING UTF-8
              SKIPPING BYTE-ORDER MARK.
        WHEN cl_abap_file_utilities=>bom_utf16_be.
          ltp_codepage = '4102'.
          OPEN DATASET itp_filename FOR INPUT IN LEGACY BINARY MODE
            BIG ENDIAN CODE PAGE ltp_codepage.
        WHEN cl_abap_file_utilities=>bom_utf16_le.
          ltp_codepage = '4103'.
          OPEN DATASET itp_filename FOR INPUT IN LEGACY BINARY MODE
            LITTLE ENDIAN CODE PAGE ltp_codepage.
        WHEN OTHERS.
          OPEN DATASET itp_filename FOR INPUT IN TEXT MODE
            ENCODING UTF-8.
      ENDCASE.
    WHEN OTHERS.
      OPEN DATASET itp_filename FOR INPUT IN LEGACY TEXT MODE.
  ENDCASE.
Edited by: Nilesh Shete on May 7, 2010 5:29 PM