Substitution Syntax in PL/SQL Process

Question

Hey all, I've got a good one for you. I used to be able to do the following in a pl/sql page process.
declare
l_vc_arr2 HTMLDB_APPLICATION_GLOBAL.VC_ARR2;
begin
SELECT ca.account_number BULK COLLECT INTO l_vc_arr2
FROM hz_cust_accounts ca,
hphc_enrollment_detail ed
WHERE ca.cust_account_id = ed.cust_account_id
and ed.enrollment_detail_id in (&P8005_ED_ID_STRING.) -- <= ***************
AND ROWNUM < 1000;
:P8005_ACCOUNT_NUMBER_STRING := HTMLDB_UTIL.TABLE_TO_STRING(l_vc_arr2,',');
exception when others then
:P8005_ACCOUNT_NUMBER_STRING := 0;
end;
It upgraded fine and continues to run fine, but I can' make changes to it and I can't do this again. This is an easy way to create an in clause. Any suggestions on what I should do?
Thanks,
Anton

Answer 1

I wouldn't call Tom's str2tbl technique a "cumbersome workaround". It is a very elegant technique that does the job wonderfully and comes in handy in many situations.
Here is a quick working example
http://htmldb.oracle.com/pls/otn/f?p=24317:210
The SQL query for the report is
select * from emp
where (:P210_EMPNOS is null
       or empno in (select *
                from table(str2tbl(cast(:P210_EMPNOS as varchar2(1000))))))The source for the SQL types and function is
CREATE OR REPLACE TYPE  "MYTABLETYPE" as table of number
create or replace function str2tbl( p_str in varchar2 )
return myTableType
as
  l_str   long default p_str || ',';
  l_n        number;
  l_data    myTableType := myTabletype();
begin
      loop
         l_n := instr( l_str, ',' );
         exit when (nvl(l_n,0) = 0);
         l_data.extend;
         l_data( l_data.count ) := ltrim(rtrim(substr(l_str,1,l_n-1)));
         l_str := substr( l_str, l_n+1 );
      end loop;
      return l_data;
end;
/Thanks