Switch between transient and persistent objects?

Question

Hi Folks,
I'm Re: transient object to persistent to ask this type of question, but couldn't find an answer.
Using persistent classes, does anyone know an elegant way to convert a transient object to a persistent one and vice versa? There is no standard functionality provided that I can see, and cloning the object results in clashing keys.
What am I trying to accomplish?
I need an object instance which <i>may</i> exist in the DB and if not, it <i>may</i> need to be saved for future use. I'm using a table with key fields K1 and K2 and the app will ask for an object instance using the full key K1+K2.
If the object doesn't find a DB record for K1K2 then it should instantiate itself with values for K1blank. Here is where I'm considering transient in order to provide the app with default functionality defined in record K1+blank.
If a write access occurs to a transient object then is should become persistent and the K1+K2 record be created.
Any ideas appreciated.
Cheers,
Mike

Answer 1

Hi Mike,
I written something similar working on Persistent Objects.
The only point of attention is that you cannot create a new persistent while a transient is resident in memory.
This is checked by the OS system during the creation of a new persistent:
in method CREATE_PERSISTENT of Basis Class, there is a check on the existing object:
* Precondition   : No object exists with the given business key, neither
*                  in memory nor on database.
So, you can create a new transient, fill it with the values you need and then pass this values to the agent to create a new persistent, but only after releasing the existing transient (because they will have the same key).
I've solved the problem like this:
METHOD flush.
"IMPORTING value(im_transient) TYPE REF TO zcl_liquidate_daily_bo
"IMPORTING value(im_commit) TYPE xfeld
"IMPORTING value(im_agent) TYPE REF TO zca_liquidate_daily_bo
"RETURNING value(re_persistent) TYPE REF TO zcl_liquidate_daily_bo
"--> raised by event PERNR_PROCESSED
  DATA: s_dip_liq TYPE zhr_tm_dip_liq.
  s_dip_liq-zpernr    = im_transient->get_employee_no( ).
  s_dip_liq-zsocmat   = im_transient->get_matricola_legale( ).
  s_dip_liq-zdataev   = im_transient->get_event_date( ).
  s_dip_liq-zcodev    = im_transient->get_event_type( ).
  s_dip_liq-zdescev   = im_transient->get_event_descr( ).
  s_dip_liq-zmotev    = im_transient->get_event_reasn( ).
  s_dip_liq-zmeseall  = im_transient->get_mese_allineamento( ).
  s_dip_liq-zannoall  = im_transient->get_anno_allineamento( ).
* // Invalidate the transient before create the persistent!
  im_agent->if_os_factory~release( im_transient ).
  CLEAR im_transient.
  IF im_commit EQ abap_true.
    TRY.
re_persistent =
im_agent->create_persistent( EXPORTING i_anno_allineamento = s_dip_liq-zannoall
                                               i_mese_allineamento = s_dip_liq-zmeseall
                                               i_employee_no       = s_dip_liq-zpernr
                                               i_event_date        = s_dip_liq-zdataev
                                               i_event_type        = s_dip_liq-zcodev
                                               i_event_descr       = s_dip_liq-zdescev
                                               i_event_reasn       = s_dip_liq-zmotev
                                               i_matricola_legale  = s_dip_liq-zsocmat ).
      CATCH cx_os_object_existing.
    ENDTRY.
    COMMIT WORK AND WAIT.
  ENDIF.
ENDMETHOD.
This method is called inside a loop on a table that containes references to transient objects.
For each object I perform some tasks, and if all it's ok I raise the event PERNR_PROCESSED, which automatically calls this method FLUSH, transferring the transient to the persistent.
Return Object is the new persistent, which will be passed back to the internal table, changing the content from the transient to the new persistent.
Hope this helps,
Roby.