The columns are missed in Backgroup job in report program

Question

Hi experts,
    I have a report program and I  display it by WRITE statement. The total length of the report is about 550, and I set the line-size to 600. When I run it by backgroup job, it can not display the row completedly, the last  10 columns are missed. Do any one know what happpen and how I fixed it? Thanks in advance.
Best Regards
Joe

Answer 1

Hi Kiran,
I had completed the program and now I am showing you my solution in brief.
I hvae two programs to meet the solution. First is ZSDR0087 and next is ZSDR0087_RAW_PROGRAM. The former program is just for the purpose of calliing latter program, and latter program is for handling the program logic. The transaction code link to ZSDR0087 They are using a same selection screen.
Below is the cods of selection screen
SELECTION-SCREEN BEGIN OF BLOCK sel1 WITH FRAME TITLE text-001.
PARAMETERS: p_hbad TYPE /bluesky/cshbad-hbad OBLIGATORY MEMORY ID hba."#EC EXISTS
SELECT-OPTIONS: s_airli FOR /bluesky/mdairlz-airline MODIF ID m4,
                s_altp FOR /bluesky/mdairlz-altp MODIF ID m4,
                s_kunnr FOR knvv-kunnr MODIF ID m4,
                s_prsdt FOR /bluesky/fecpost-prsdt MODIF ID m4,
*                s_atdat FOR /bluesky/fearde-atdat OBLIGATORY,
                s_actyp FOR /bluesky/mdacrt-actyp MODIF ID m4,
                s_mtmcat FOR /bluesky/mdacrt-mtomcat MODIF ID m4,
                s_regid FOR /bluesky/mdreg-regid MODIF ID m4,
                s_fenum FOR /bluesky/fehdr-fenum MODIF ID m4.
PARAMETERS: p_en_ex TYPE c AS LISTBOX VISIBLE LENGTH 10 MODIF ID m4.
SELECTION-SCREEN END OF BLOCK sel1.
SELECTION-SCREEN BEGIN OF BLOCK run WITH FRAME TITLE text-003.
PARAMETERS: p_imm RADIOBUTTON GROUP grp1 DEFAULT 'X' USER-COMMAND comm."Run the program immdiately and show report at frontend
PARAMETERS: p_batch RADIOBUTTON GROUP grp1, "Run in backgroup job, the result will be saved at application server as .txt file
            p_file  TYPE g_type_file LOWER CASE MODIF ID m1. ".txt File name which will be saved in application server
PARAMETERS: p_ser RADIOBUTTON GROUP grp1. "Read the data from .txt file in application server
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(14) text-004 FOR FIELD p_txt MODIF ID m2.
PARAMETERS: p_txt  TYPE g_type_file LOWER CASE MODIF ID m2."Source .txt file in application server
SELECTION-SCREEN COMMENT 50(14) text-005 FOR FIELD p_del MODIF ID m2.
PARAMETERS: p_del AS CHECKBOX MODIF ID m2. "The .txt file will be deleted once the report is generated
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK run.
SELECTION-SCREEN BEGIN OF BLOCK sel2 WITH FRAME TITLE text-002.
PARAMETERS: p_xls AS CHECKBOX DEFAULT '' MODIF ID m3."Generate the excel file in frontend
SELECTION-SCREEN END OF BLOCK sel2.
Main Code in ZSDR0083
REPORT  zsdr0087 MESSAGE-ID zbluesky_program LINE-SIZE 530 NO STANDARD PAGE HEADING."#EC *
INCLUDE zsdr0087_top.
INCLUDE zsdr0087_common_blk.
INCLUDE zsdr0087_frm.
START-OF-SELECTION.
  PERFORM handle_report.
FORM handle_report .
  IF p_imm = 'X' OR p_ser = 'X'.
    PERFORM run_program_without_batch.
  ELSEIF p_batch = 'X'.
    PERFORM submit_to_batch.
  ENDIF.
ENDFORM.                    " handle_report
FORM run_program_without_batch .
  DATA: lv_answer TYPE c.
  IF p_ser = 'X' AND p_txt IS INITIAL.
    MESSAGE s029.
    EXIT.
  ENDIF.
  IF p_ser = 'X' AND p_del = 'X' AND p_xls = ''.
    PERFORM popup_to_confirm USING 'Delete file in server' "titlebar
                                   'The file in server will be deleted, are you going to save the data in Excel file？' "question
                                   'SAVE IN EXCEL'"the text in first button
                                   'ICON_XLS' "the icon for first button
                                   'Not Save'
                                   'ICON_WARNING'"the icon for second button
                                   '1'"default button
                                   'X'"display cancel button
                            CHANGING lv_answer.
    CASE lv_answer.
      WHEN '1'.
        p_xls = 'X'.
      WHEN '2'.
        p_xls = ''.
      WHEN 'A'.
        MESSAGE s032.
        EXIT.
    ENDCASE.
  ENDIF.
  SUBMIT zsdr0087_raw_program WITH p_hbad = p_hbad
                              WITH s_airli IN s_airli
                              WITH s_altp IN s_altp
                              WITH s_kunnr IN s_kunnr
                              WITH s_prsdt IN s_prsdt
                              WITH s_actyp IN s_actyp
                              WITH s_mtmcat IN s_mtmcat
                              WITH s_regid IN s_regid
                              WITH p_en_ex = p_en_ex
                              WITH p_imm = p_imm
                              WITH p_batch = p_batch
                              WITH p_file = p_file
                              WITH p_ser = p_ser
                              WITH p_txt = p_txt
                              WITH p_del = p_del
                              WITH p_xls = p_xls
                              AND RETURN.
ENDFORM.                    " run_program_without_batch
FORM submit_to_batch .
  DATA: lv_job_name TYPE tbtcjob-jobname,
        lv_job_number TYPE tbtcjob-jobcount.
  lv_job_name = p_file.
  TRANSLATE lv_job_name TO UPPER CASE.
  CALL FUNCTION 'JOB_OPEN'
    EXPORTING
      jobname          = lv_job_name
    IMPORTING
      jobcount         = lv_job_number
    EXCEPTIONS
      cant_create_job  = 1
      invalid_job_data = 2
      jobname_missing  = 3
      OTHERS           = 4.
  IF sy-subrc <> 0.
    MESSAGE e022.
  ENDIF.
  SUBMIT zsdr0087_raw_program WITH p_hbad = p_hbad
                              WITH s_airli IN s_airli
                              WITH s_altp IN s_altp
                              WITH s_kunnr IN s_kunnr
                              WITH s_prsdt IN s_prsdt
                              WITH s_actyp IN s_actyp
                              WITH s_mtmcat IN s_mtmcat
                              WITH s_regid IN s_regid
                              WITH p_en_ex = p_en_ex
                              WITH p_imm = p_imm
                              WITH p_batch = p_batch
                              WITH p_file = p_file
                              WITH p_ser = p_ser
                              WITH p_txt = p_txt
                              WITH p_xls = p_xls
                              VIA JOB lv_job_name NUMBER lv_job_number
                              AND RETURN.
  IF sy-subrc NE 0.
    MESSAGE e023 WITH 'zsdr0087_raw_program'..
  ENDIF.
  CALL FUNCTION 'JOB_CLOSE'
    EXPORTING
      jobcount             = lv_job_number
      jobname              = lv_job_name
      strtimmed            = 'X'
    EXCEPTIONS
      cant_start_immediate = 1
      invalid_startdate    = 2
      jobname_missing      = 3
      job_close_failed     = 4
      job_nosteps          = 5
      job_notex            = 6
      lock_failed          = 7
      OTHERS               = 8.
  IF sy-subrc NE 0.
    MESSAGE e025.
  ELSE.
    MESSAGE s026.
  ENDIF.
ENDFORM.                    " submit_to_batch
:OK, Below is main code in program ZSDR0087_RAW_PROGRAM
REPORT  zsdr0087 MESSAGE-ID zbluesky_program LINE-SIZE 530 NO STANDARD PAGE HEADING."#EC *
INCLUDE zsdr0087_top.
INCLUDE zsdr0087_common_blk.
INCLUDE zsdr0087_frm.
START-OF-SELECTION.
  IF sy-tcode EQ 'SE38' OR sy-tcode EQ 'SA38'.
    MESSAGE s035.
    EXIT.
  ENDIF.
  CREATE OBJECT go_bluesky_program
    EXPORTING
      i_home_base = p_hbad.
  IF p_imm = 'X' OR p_batch = 'X'.
********  Get data from database
    PERFORM get_data_from_db.
    IF p_batch = 'X'.
*******Save the data the server as .txt file, it will run at backgroup Job
      PERFORM save_data_to_server USING <gt_output>
                                        p_hbad
                                        gv_run_time
                                        gv_run_date
                                        sy-uname
                                        gv_top_folder
                                        p_file
                                        go_bluesky_program->gt_fieldcat_lvc.
      EXIT.
    ENDIF.
  ELSE.
******** Get data from server
    PERFORM get_data_from_server.
  ENDIF.
  IF <gt_output> IS ASSIGNED AND <gt_output> IS NOT INITIAL.
    IF p_xls = 'X' AND p_batch = ''.
      PERFORM output_excel.
    ENDIF.
    PERFORM display_report.
  ELSE.
    MESSAGE s004(zbluesky_program).
  ENDIF.
If parameter p_batch is check, The subroutine save_data_to_server will save the internal table data as .txt file at server.This is run in backgroup.Please set your focus on the function module C13Z_TEXT_WRITE
FORM save_data_to_server USING ut_internal_table TYPE STANDARD TABLE
                               u_home_base
                               u_run_time TYPE syuzeit
                               u_run_date TYPE sydatum
                               u_user TYPE syuname
                               u_top_folder TYPE rsmrgstr-path
                               u_filename   TYPE g_type_file
                               ut_fieldcat_lvc   TYPE lvc_t_fcat.
  FIELD-SYMBOLS: <lt_table_dataset> TYPE STANDARD TABLE.
  DATA: lv_table_ref TYPE REF TO data.
  DATA: lv_filename TYPE rcgiedial-iefile.
  DATA: lv_file_pattern TYPE rsmrgstr-name.
  CALL METHOD go_bluesky_program->convert_data_to_dataset_format
    EXPORTING
      it_internal_table = ut_internal_table
      it_fieldcat_lvc   = ut_fieldcat_lvc
    IMPORTING
      et_table_ref      = lv_table_ref.
  ASSIGN lv_table_ref->* TO <lt_table_dataset>.
*******Create file name
  PERFORM get_filename USING
             u_home_base
              u_user
              u_run_date
              u_run_time
              u_filename
    CHANGING lv_filename
             lv_file_pattern.
******Check filename again
  PERFORM check_filename_if_duplicate
              USING
                 lv_filename
                 u_top_folder
                 lv_file_pattern.
******Create dataset path
  CONCATENATE u_top_folder lv_filename INTO lv_filename.
  CALL FUNCTION 'C13Z_TEXT_WRITE'
    EXPORTING
      i_file         = lv_filename
    TABLES
      i_textdata_tab = <lt_table_dataset>
    EXCEPTIONS
      no_permission  = 1
      open_failed    = 2
      ap_file_exists = 3
      OTHERS         = 4.
  IF sy-subrc <> 0.
    MESSAGE e021.
  ENDIF.
ENDFORM.                    " save_data_to_server
If parameter p_ser is check, The subroutine get_data_from_server will read the data from .txt file in server and put it into internal table. Please focus on the DO looping in the subroutine.It is the codes for reading data from .txt file into internal table.
FORM get_data_from_server .
  FIELD-SYMBOLS: <lt_table_dataset> TYPE STANDARD TABLE,
                 <ls_line_dataset> TYPE ANY,
                 <field_runtime> TYPE ANY,
                 <field_dataset> TYPE ANY.
  DATA: lv_table_ref TYPE REF TO data,
        lv_line_ref TYPE REF TO data.
  DATA: lv_file TYPE string.
  DATA: ls_file_record TYPE rsfillst.
  DATA: ls_fieldcat_lvc TYPE lvc_s_fcat.
  PERFORM build_output_table.
******Get the dataset format(all the fiels are CHAR type)
  CALL METHOD go_bluesky_program->convert_data_to_dataset_format
    EXPORTING
      it_internal_table = <gt_output>
      it_fieldcat_lvc   = go_bluesky_program->gt_fieldcat_lvc
    IMPORTING
      et_table_ref      = lv_table_ref.
  ASSIGN lv_table_ref->* TO <lt_table_dataset>.
  CREATE DATA lv_line_ref LIKE LINE OF <lt_table_dataset>.
  ASSIGN lv_line_ref->* TO <ls_line_dataset>.
  PERFORM get_file_record
              USING
                 sy-mandt
                 sy-uname
                 p_hbad
                 gv_top_folder
              CHANGING
                 ls_file_record.
  CONCATENATE ls_file_record-dirname ls_file_record-name INTO lv_file.
  OPEN DATASET lv_file FOR INPUT IN TEXT MODE ENCODING DEFAULT.
  IF sy-subrc NE 0.
    MESSAGE e030 WITH p_txt.
  ENDIF.
  DO.
    READ DATASET lv_file INTO <ls_line_dataset>.
    IF sy-subrc EQ 0.
      IF <ls_line_dataset> IS NOT INITIAL.
        APPEND <ls_line_dataset> TO <lt_table_dataset>.
        CLEAR <ls_line_dataset>.
      ENDIF.
    ELSE.
      EXIT.
    ENDIF.
  ENDDO.
  CLOSE DATASET lv_file.
  IF p_del = 'X'.
    DELETE DATASET lv_file.
  ENDIF.
*  break chengr.
  LOOP AT <lt_table_dataset> ASSIGNING <ls_line_dataset>.
    LOOP AT go_bluesky_program->gt_fieldcat_lvc INTO ls_fieldcat_lvc.
      ASSIGN COMPONENT ls_fieldcat_lvc-fieldname
                         OF STRUCTURE <ls_line_dataset> TO <field_dataset>.
      ASSIGN COMPONENT ls_fieldcat_lvc-fieldname
                         OF STRUCTURE <gs_output> TO <field_runtime>.
      <field_runtime> = <field_dataset>.
    ENDLOOP.
    APPEND <gs_output> TO <gt_output>.
  ENDLOOP.
At last, I think you understand how to display it in ALV .