THE PROGRAM IS RUNNING VERY SLOW?

Question

HI:
THERE IS APROGRAM DEVELOPED BY USER ,CAN SOMEONE HELP TO  ANALYIZE HOW TO TUNE IT ?
THANKS
THE FILES:
FORM frm_get_data.
  DATA: BEGIN OF it_ablad OCCURS 0,
          ablad LIKE rkpf-umlgo,
        END OF it_ablad.
  IF NOT s_kunnr[] IS INITIAL.
    SELECT ablad
    INTO TABLE it_ablad
    FROM  knva
    WHERE knva~kunnr IN s_kunnr.
  ENDIF.
  IF it_ablad[] IS NOT INITIAL.
    SELECT rsdat
           usnam
           rspos
           rkpf~bwart
           xwaok
           kzear
           xloek
           sgtxt
           rkpf~rsnum
           werks
           rkpf~umwrk
           resb~matnr
           rkpf~umlgo
           bdmng
           enmng
           resb~wempf
           ablad
           extwg
    INTO CORRESPONDING FIELDS OF TABLE et_resb
    FROM rkpf INNER JOIN resb ON rkpfrsnum = resbrsnum
              INNER JOIN mara ON resbmatnr = maramatnr
    UP TO p_hinum ROWS
    FOR ALL ENTRIES IN it_ablad
    WHERE rkpf~bwart IN s_bwart
    AND   rsdat IN s_rsdat
    AND   rkpf~umwrk = '2020'
    AND   werks = '2020'
    AND   rkpf~umlgo = it_ablad-ablad
    AND   mara~extwg IN s_extwg
    AND   resb~matnr IN s_matnr
    AND   rkpf~rsnum IN s_rsnum
    AND   kzear = ''
    AND   xloek = ''
    AND   ( xwaok = ''
          OR ( xwaok = 'X'
          AND lgort = '') ).
  ELSE.
    SELECT rsdat
       usnam
       rspos
       rkpf~bwart
       xwaok
       kzear
       xloek
       sgtxt
       rkpf~rsnum
       werks
       rkpf~umwrk
       resb~matnr
       rkpf~umlgo
       bdmng
       enmng
       resb~wempf
       ablad
       extwg
INTO CORRESPONDING FIELDS OF TABLE et_resb
FROM rkpf INNER JOIN resb ON rkpfrsnum = resbrsnum
          INNER JOIN mara ON resbmatnr = maramatnr
UP TO p_hinum ROWS
WHERE rkpf~bwart IN s_bwart
AND   rsdat IN s_rsdat
AND   rkpf~umwrk = '2020'
AND   werks = '2020'
AND   rkpf~umlgo IN s_umlgo
AND   mara~extwg IN s_extwg
AND   resb~matnr IN s_matnr
AND   rkpf~rsnum IN s_rsnum
AND   kzear = ''
AND   xloek = ''
AND   ( xwaok = ''
      OR ( xwaok = 'X'
      AND lgort = '') ).
  ENDIF.
  IF p_sd = 'X'.
    DELETE et_resb WHERE wempf <> 'SD'.
  ELSEIF p_plfw = 'X'.
    DELETE et_resb WHERE wempf+0(2) <> '13'.
  ELSEIF p_fw = 'X'.
    DELETE et_resb WHERE wempf+0(2) = '13' OR wempf = 'SD'.
  ENDIF.
  LOOP AT et_resb.
    DATA : tmp_labst   TYPE mard-labst.
    DATA : tmp_wdmeng  TYPE mard-labst.
    DATA : tmp_calab   TYPE mard-labst.
    CLEAR wa_output.
    wa_output-rsdat = et_resb-rsdat.
    wa_output-usnam = et_resb-usnam.
    wa_output-bwart = et_resb-bwart.
    wa_output-rsnum = et_resb-rsnum.
    wa_output-rspos = et_resb-rspos.
    wa_output-umwrk = et_resb-umwrk.
    wa_output-umlgo = et_resb-umlgo.
    wa_output-matnr = et_resb-matnr.
    wa_output-matnr1 = et_resb-matnr.
    wa_output-extwg = et_resb-extwg.
    wa_output-xwaok = et_resb-xwaok.
    wa_output-kzear = et_resb-kzear.
    wa_output-xloek = et_resb-xloek.
    wa_output-wempf = et_resb-wempf.
    wa_output-ablad = et_resb-ablad.
    wa_output-sgtxt = et_resb-sgtxt.
    wa_output-wbdmng = et_resb-bdmng - et_resb-enmng.
    IF pp_lgort <> ''.
      SELECT SINGLE labst
      FROM   mard
      INTO   tmp_labst
      WHERE  werks = '2020'
      AND    lgort = pp_lgort.
      PERFORM resb_lesen USING '2020'
                               pp_lgort
                               et_resb-matnr
                      CHANGING tmp_wdmeng.
      wa_output-calab = tmp_labst - tmp_wdmeng.
      wa_output-werks = '2020'.
      wa_output-lgort = pp_lgort.
    ELSE.
      SELECT  *
      FROM zmt_fckw_new
      INTO CORRESPONDING FIELDS OF TABLE et_fckw
      WHERE umwrk = et_resb-umwrk
        AND umlgo = et_resb-umlgo.
      LOOP AT et_fckw.
        CLEAR tmp_labst.
        SELECT SINGLE labst
        FROM   mard
        INTO   tmp_labst
        WHERE  werks = et_fckw-werks
        AND    lgort = et_fckw-lgort
        AND    matnr = et_resb-matnr.
        PERFORM resb_lesen USING et_fckw-werks
                                 et_fckw-lgort
                                 et_resb-matnr
                        CHANGING tmp_wdmeng.
        tmp_calab = tmp_labst - tmp_wdmeng.
        IF  tmp_calab >= wa_output-wbdmng.
          wa_output-werks = et_fckw-werks.
          wa_output-lgort = et_fckw-lgort.
          wa_output-lg_typ = et_fckw-lg_typ.
          wa_output-calab = tmp_calab.
          wa_output-xwaok = 'X'.
          EXIT.
        ELSE.
          SELECT  *
          FROM zmt_thwl
          INTO CORRESPONDING FIELDS OF TABLE et_thwl
          WHERE matnr = et_resb-matnr
          AND   zgroup <> 'X'.
          SORT et_thwl BY matnr
                          priority DESCENDING
                          sub_matnr.
          LOOP AT et_thwl.
            CLEAR tmp_labst.
            SELECT SINGLE labst
            FROM   mard
            INTO   tmp_labst
            WHERE  werks = et_fckw-werks
            AND    lgort = et_fckw-lgort
            AND    matnr = et_thwl-sub_matnr.
            PERFORM resb_lesen USING et_fckw-werks
                                     et_fckw-lgort
                                     et_thwl-sub_matnr
                             CHANGING tmp_wdmeng.
            tmp_calab = tmp_labst - tmp_wdmeng.
            IF  tmp_calab >= wa_output-wbdmng.
              wa_output-matnr1 = et_thwl-sub_matnr.
              wa_output-werks = et_fckw-werks.
              wa_output-lgort = et_fckw-lgort.
              wa_output-lg_typ = et_fckw-lg_typ.
              wa_output-calab = tmp_calab.
              wa_output-xwaok = 'X'.
              wa_output-subst = 'X'.
              EXIT.
            ENDIF.
          ENDLOOP.
        ENDIF.
        IF wa_output-lgort <> ''.
          EXIT.
        ENDIF.
      ENDLOOP.
      IF wa_output-lgort = ''.
        READ TABLE et_fckw WITH KEY umwrk = et_resb-umwrk
                                    umlgo = et_resb-umlgo
                                 zdefault = 'X'.
        wa_output-werks = et_fckw-werks.
        wa_output-lgort = et_fckw-lgort.
        wa_output-lg_typ = et_fckw-lg_typ.
        wa_output-xwaok = ''.
        CLEAR tmp_labst.
        PERFORM resb_lesen USING et_fckw-werks
                                 et_fckw-lgort
                                 et_resb-matnr
                        CHANGING tmp_wdmeng.
        tmp_calab = tmp_labst - tmp_wdmeng.
      ENDIF.
      CLEAR ET_FCKW[].
      CLEAR tmp_labst.
    ENDIF.
    SELECT  SINGLE lgobe
    INTO wa_output-lgobe
    FROM t001l
    WHERE werks = et_resb-umwrk
      AND lgort = et_resb-umlgo.
    SELECT SINGLE lgobe
    INTO wa_output-lgobe1
    FROM t001l
    WHERE werks = wa_output-werks
    AND   lgort = wa_output-lgort.
    SELECT SINGLE maktx
    INTO   wa_output-maktx
    FROM   makt
    WHERE  matnr = wa_output-matnr.
    APPEND wa_output.
  ENDLOOP.
ENDFORM.                    "frm_get_data

Answer 1

I agree with what one of the other people has said.  Joins are not nesasarily bad, but badly designed joins are.  So from the perspective of the Join vs. the For All Entries I don't belive that just moving to a For All Entries will solve your problem.  A well desinged Join can actaully perform very well and often would actaully be my choosen way of accessing data.  So it's not black and white on this subject, it depends on the relationships between the tables and the distribution of data accross those tables.
Taking a look at the large join statements that you have I'm not going to attempt to do a tuning on it since I'm not really familiar with your specific data distribution in your system, so I'm going to concentrate on some other areas instead.  I do suggest that you do an SE30 trace on it so that you can do some profiling of understanding which components of your program are taking up the highest net runtime.
I belive that there is a significant amount of processing time that is taken up inside your looping due to the selects and reads inside the loops.  Selects inside loops have certain overhead to them as opposed to doing an arracy select (For All Entries) and also it appears that there are many spots where you are most likely going back to the data base for the same data multiple times.  Rudundant DB calls for the same records is one of the leading causes of waste in ABAP programs.  My rule of thumb is that during a batch program written in ABAP there should never be a record in a table that is retrieved more then once accross all of your various selects.  Pigion hole principal can be applied here, if there are 100 records in a table and you end up executing 1,000 selects against that table then there have been 900 rudundant calls and account for waste in the processing time of the program.  Something I often remind my developers of is that if it is inside a loop don't forget that it is happening multiple times!  I know that it seems like an obvious statement, but often developers overlook the cost of what they are doing.
Here are some of the pieces of code that should be examined:
1) Switch to a single loop with three checks inside it.  Each time you do a delete statement it is actually doing a full sequential pass through the internal table.  So in this case you are making 2 redundant full sequential reads of the table.
IF p_sd = 'X'.
    DELETE et_resb WHERE wempf 'SD'.
  ELSEIF p_plfw = 'X'.
    DELETE et_resb WHERE wempf+0(2) '13'.
  ELSEIF p_fw = 'X'.
    DELETE et_resb WHERE wempf+0(2) = '13' OR wempf = 'SD'.
  ENDIF.
2) Remove from loop at et_resb, it doesn't make sense to do this select inside a loop when it could be done as a For All Entries outside of the loop, you're going to most likely be getting the same records selected multiple times which is a waste.  Additionally, even if the same records aren't being rudundently called, an array select is still faster for something like this then individual selects due to DB overhead per call.  Also note that there seems to be something wrong with this select since you are note including the MATNR field in the where clause, it is going to each time just get the first material it happens to find for the storage location at that plant.
SELECT SINGLE labst
      FROM mard
      INTO tmp_labst
      WHERE werks = '2020'
      AND lgort = pp_lgort.
3) What is happening inside the PERFORM resb_lesen?  This is inside a loop so it should be examined further to understand the cost of the processing that it is doing.
4) Refer to point#2, this is a select inside a loop and could become expensive depending on the nature of the tables and their data.
SELECT *
      FROM zmt_fckw_new
      INTO CORRESPONDING FIELDS OF TABLE et_fckw
      WHERE umwrk = et_resb-umwrk
      AND umlgo = et_resb-umlgo.
5) Refer to point#2, this is another select inside a loop and most likely will be making rudundant calls where it goes back to the DB for the same records multiple times.  In addition to this it is actually inside multiple loops nested.
SELECT SINGLE labst
        FROM mard
        INTO tmp_labst
        WHERE werks = et_fckw-werks
        AND lgort = et_fckw-lgort
        AND matnr = et_resb-matnr.
6) Refer to point#2.  Note also that this will be causing redundant DB calls if you're looking at the same materials  on multiple passes of the loop.
SELECT *
          FROM zmt_thwl
          INTO CORRESPONDING FIELDS OF TABLE et_thwl
          WHERE matnr = et_resb-matnr
          AND zgroup 'X'.
7) Refer to point #6.
SELECT SINGLE labst
            FROM mard
            INTO tmp_labst
            WHERE werks = et_fckw-werks
            AND lgort = et_fckw-lgort
            AND matnr = et_thwl-sub_matnr.
8) Read statement should be optimized via a non-sequential access pattern such as a binary search or the use of a hash table
READ TABLE et_fckw WITH KEY umwrk = et_resb-umwrk
        umlgo = et_resb-umlgo
        zdefault = 'X'.
9) Refer to point #6
SELECT SINGLE lgobe
    INTO wa_output-lgobe
    FROM t001l
    WHERE werks = et_resb-umwrk
    AND lgort = et_resb-umlgo.
    SELECT SINGLE lgobe
    INTO wa_output-lgobe1
    FROM t001l
    WHERE werks = wa_output-werks
    AND lgort = wa_output-lgort.
    SELECT SINGLE maktx
    INTO wa_output-maktx
    FROM makt
    WHERE matnr = wa_output-matnr.
~Ian