Transpose columns and rows in numbers

Question

I need to transpose columns and rows in Numbers and I do not want to write script to do it.  Is there an easier way?

Answer 1

Give me a proper transpose and I will uninstall Excel and never look back.
Ok, here's a proper transpose, that can be placed in an Automator Service so it becomes a simple menu pick as below (and can also be assigned a keyboard shortcut).
To use it (this is slightly different from Excel) you select the range you want to transpose, choose Copy Transpose, click a destination cell in an existing table in the current document or another document, and command-v (Edit > Paste) or option-shift-command-v (Edit > Paste and Match Style).
The one-time setup is as follows.  In Automator choose File > New > Service,  drag a Run AppleScript action from the left into the right pane, choose 'No Input' for 'Services receives selected' and 'Numbers' for 'in'. Then paste the following into the Run AppleScript action, replacing all text already there by default:
--Transpose - select range, run, paste transposed values where wanted
try
          tell application "Numbers" to tell front document to tell active sheet
                    set selected_table to first table whose class of selection range is range
                    tell selected_table
                              set my_selection to the selection range
                              set first_col to address of first column of my_selection
                              set last_col to address of last column of my_selection
                              set first_row to address of first row of my_selection
                              set last_row to address of last row of my_selection
                              set str to ""
                              repeat with i from first_col to last_col
                                        repeat with j from first_row to last_row
                                                  set str to str & (value of cell j of column i of selected_table) & tab
                                        end repeat
                                        set str to str & return -- add line return after row
                              end repeat
                    end tell
          end tell
  set the clipboard to str
          display notification "Ready to paste transposed values" with title "Numbers"
on error
          display dialog "Select a range first and then try again"
end try
--end script
Hit the compile "hammer" and the script should indent properly. Then save the service with the name you want to appear in your menu, and it will thereafter be available via the Services menu (and keyboard shortcut, if you set one up in System Preferences > Keyboard > Shortcuts > Services).
That's it. Less then five minutes' one-time set-up work and you've got a menu pick for a transpose functionality that is as convenient as Excel's.
SG