Update master data in BW with Visual Composer

Question

Hi guys.
I have an attribute of an info object that I need to give the users access to update.
I would like to do it with visual composer.
I would like the user to see all rows in a table kind of view and the user will update only the rows that need to be changed and than he/she will click on a button that will update the master data table in BW.
I believe that I'll need to use a BAPI or a RFC for that? Does anyone know any good predefined ones for that?
Thanks
Shlomi

Answer 1

That's not really true. In VC you have access to all remote enabled functions. We have created specific functions to update attributes.
We are using it to allow our users to update their own master data instead of bugging the BI team.
Here is an example of our code.
Before I paste this in, you need to know a couple things.
1. You can only update one record at a time (with my code)
2. You have to pass back in the entire record, even if you are only changing one attribute of many.
3. It automatically does the attribute change run, so you do not need to to it.
This is a simple infoobject with a few attributes.
First we created a Get function (which collects the data and shows it to the user.
Then we gave them a edit button on the table that goes to a pop up.
The user selects the record to change, then hits the edit button.
When the popup  comes up the data is shown in a form, with a save and cancel button, fields that you do not wish users to see or change, hide them, but they all most be present on the form.
The  when the user hits save, it send it to the below function. The name of the infoobject is ZCAT_SUB.
FUNCTION zcat_update_subparty2.
""Local Interface:
*"  IMPORTING
*"     VALUE(I_T_ZSUBPARTY) LIKE  /BIC/PZCAT_SUB
*"  STRUCTURE  /BIC/PZCAT_SUB
*"  EXPORTING
*"     VALUE(E_RESULT) TYPE  STRING
  TYPE-POOLS: rs, rsarc, rsarr, sbiwa, rssm.
  DATA:
        l_t_zsubparty LIKE /bic/pzcat_sub OCCURS 10,
        l_s_minfo      TYPE  rssm_s_minfo,
        l_t_idocstate  TYPE  rsarr_t_idocstate,
        l_subrc        LIKE  sy-subrc.
  APPEND i_t_zsubparty TO l_t_zsubparty.
  CALL METHOD cl_rsdmd_update_master_data=>update_attributes_static
    EXPORTING
      i_iobjnm      = 'ZCAT_SUB'
      i_t_data      = l_t_zsubparty
      i_s_minfo     = l_s_minfo
      i_monitoring  = rs_c_false
    IMPORTING
      e_subrc       = l_subrc
    CHANGING
      c_t_idocstate = l_t_idocstate.
  IF sy-subrc <> 0.
    e_result = 'Error happened'.
  ELSE.
    e_result = 'Process Completed'.
    DATA:
      l_t_msg                  TYPE rs_t_msg,
      l_r_activate_master_data TYPE REF TO cl_rsdmd_activate_master_data.
    CREATE OBJECT l_r_activate_master_data
      EXPORTING
        i_iobjnm               = 'ZCAT_SUB'
        i_p_q_have_to_exist    = rs_c_true
      EXCEPTIONS
        iobj_not_found         = 1
        iobj_not_active        = 2
        generate_program_error = 3
        p_q_do_not_exist       = 4
        p_q_txt_do_not_exist   = 5
        OTHERS                 = 6.
    IF sy-subrc = 0.
      l_r_activate_master_data->activate( IMPORTING e_subrc = l_subrc
                                        CHANGING  c_t_msg = l_t_msg ).
    ENDIF.
  ENDIF.
ENDFUNCTION.