Use the currval whenever I need it

Question

Hello,
I defined a sequence : MySequence_seq
I defined 2 Procedures :
1/ Initproc encloses a MySequence_seq.nextval
2/ GetProc encloses a MySequence_seq.currval
But when I call GetProc I get a "ORA-08002 :sequence SEQ1.CURRVAL is not yet defined in this session".
I thought one nextval was enough and then I could invoke a currval whenever I want.
The same issue with SQL*PLUS : if I connect call a nextval and then a currval it works. If I close then re-connect and call currval it doesn't work.
My need : having an absolute unique ID I can get whenever I want without performing a nextval (which will increments the ID) anytime I want the last value generated. Perhaps it's not possible with a sequence...so should I manage on my own (PL/SQL + a given field of my table storing this last value) ?
Any help greatly appreciated.
Jerome.

Answer 1

The manual says From: http://download-west.oracle.com/docs/cd/B10501_01/server.920/a96536/ch2123.htm#1300856
"Table: USER_SEQUENCES/ALL_SEQUENCES
LAST_NUMBER : Last sequence number written to disk. If a sequence uses caching, the number written to disk is the last number placed in the sequence cache. This number is likely to be greater than the last sequence number that was used."
This mean that the numbers X obtained by the proposed method, even if apparently persistent through sessions, are NOT a replacement for the number Y obtained from sequence.CURRVAL, and therefore cannot fulfill the function requested in the thread, because:
1. they are not unique: you can get same X for different Y
2. they are not stable: you can get different X for same Y (when X is read more than one time)
You can see this from the following test:
CREATE OR REPLACE PROCEDURE test_seq(p_iters      NUMBER,
                                     p_sleep_time NUMBER := 0) AS
    v_seq1   NUMBER;
    v_seq10  NUMBER;
    v_seq2   NUMBER;
    v_seq20  NUMBER;
    v_seqnos NUMBER := 0;
    v_diffs1 NUMBER := 0;
    v_diffs2 NUMBER := 0;
BEGIN
    FOR i IN 1 .. p_iters LOOP
        IF MOD(i, 10) = 1 THEN
            SELECT mysequence_seq.NEXTVAL
              INTO v_seq1
              FROM dual;
            v_seqnos := v_seqnos + 1;
        END IF;
        SELECT mysequence_seq.CURRVAL,
               last_number - 1
          INTO v_seq1,
               v_seq2
          FROM user_sequences
         WHERE sequence_name = 'MYSEQUENCE_SEQ';
        IF v_seq1 <> v_seq10 AND v_seq2 = v_seq20 THEN
            v_diffs1 := v_diffs1 + 1;
        END IF;
        IF v_seq1 = v_seq10 AND v_seq2 <> v_seq20 THEN
            v_diffs2 := v_diffs2 + 1;
        END IF;
        v_seq10 := v_seq1;
        v_seq20 := v_seq2;
        dbms_lock.sleep(p_sleep_time);
    END LOOP;
    dbms_output.put_line('Sequence.CURRVAL calls: ' || p_iters);
    dbms_output.put_line('Generated sequence numbers: ' || v_seqnos);
    dbms_output.put_line('Not unique numbers: ' || v_diffs1);
    dbms_output.put_line('Not stable numbers: ' || v_diffs2);
END;
Running from session #1:
SET SERVEROUT ON
EXEC test_seq(200, 0.1);
you get:
Sequence.CURRVAL calls: 200
Generated sequence numbers: 20
Not unique numbers: 17   <<******
Not stable numbers: 15   <<******
While running in parallel from session #2 of the same user:
SET SERVEROUT OFF
EXEC test_seq(10000);
EXEC test_seq(10000);