Using AppleScript to create folders and place files in them

Question

Hi guys,
I've been reading through the forum for the better part of the last 6 hours wracking my brain trying to figure out how to accomplish what I'm trying to do. I've been playing around with Automator and also trying to decipher some Apple Script samples that were posted on here, but I'm really having no luck at all. I'm sure you've all been there where you feel like you're on an endless search to solve a problem and it feels like there's no hope. I've tried every single possible thing I can and I'm getting close, but it's never quite right.
Here's what I'm trying to do, and hopefully some kind soul will help me out. I'm deseperately trying to figure this out, and any help at all would be GREATLY appreciated!
I have a bunch of PDF files that I scan, in the hundreds. After I've scanned them I'm left with something like this:
1234567_Elephant.pdf
1234567_Duck.pdf
1234567_Cat.pdf
1234567_Cat_01.pdf
1234567_Dog.pdf
3431233_Elephant.pdf
3431233_Dog.pdf
3431233_Dog_01.pdf
3431233_Duck.pdf
etc...
So they have a 7 digit ID, then the file name which is always one of the 4 options (I'm just using the animals as examples, but they would be other words).
What I'd want the script to do is categorize these into folders based on the ID number, and then based on the "animal" and then the files within them. Note, some files have an _01 or _02 etc... appended to them. I don't know if this makes a difference.
So after running the script I'd love to see
1234567 (Folder)
     Elephant (Subfolder)
          1234567_Elephant.pdf (File)
     Duck (Subfolder)
          1234567_Duck.pdf (File)
     Cat (Subfolder)
          1234567_Cat.pdf (File)
          1234567_Cat_01.pdf (File)
     Dog (Subfolder)
          1234567_Dog.pdf (File)
3431233
     Elephant
          3431233_Elephant.pdf
     Dog
          3431233_Dog.pdf
          3431233_Dog_01.pdf
     Duck
          3431233_Duck.pdf

Answer 1

well, using a couple of stock handlers I had lying around, and making the following assumptions:
that an underscore is always the delimiter used
that the file name is always a single word like 'dog' or 'cat' (if you have multiple word file names, the script needs to be modified some)
this should do what you ask:
set mainFolder to (choose folder) as text
tell application "System Events"
  -- get all the unsorted files, and loop through
          set unsortedFiles to every file of folder mainFolder whose visible is true
          repeat with thisFile in unsortedFiles
  -- split the file name on underscores and periods
                    set fileNameBits to my tid(name of thisFile, {"_", "."})
  -- first item of list is id, make/get correct folder
                    set IDFolder to my checkForFolder(mainFolder, item 1 of fileNameBits)
  -- second item of list is file name, make/get correct folder in id folder
                    set groupFolder to my checkForFolder(IDFolder, item 2 of fileNameBits)
  -- move file
  move thisFile to groupFolder
          end repeat
end tell
to checkForFolder(fParent, fName)
  -- subroutine checks for folder, creating it if it doesn't exist
          tell application "System Events"
                    if not (exists folder fName of folder fParent) then
                              set output to path of (make new folder at end of folder fParent with properties {name:fName})
                    else
                              set output to (path of (folder fName of folder fParent))
                    end if
          end tell
          return output
end checkForFolder
on tid(input, delim)
  -- subroutine for handling text item delimiters
          set {oldTID, my text item delimiters} to {my text item delimiters, delim}
          if class of input is list then
                    set output to input as text
          else
                    set output to text items of input
          end if
          set my text item delimiters to oldTID
          return output
end tid