Validate_layer_with_context -- differences between version 10g and 11g

Question

I have a spatial table that validates without issues under v10.2.0.4.0. This table was replicated to a new database running v11.2.0.2.0. Under this environment, the validation reports an "ORA-13366: invalid combination of interior exterior rings" issue. Has anyone else experienced this situation and does anyone have an explanation?
Thanks,
David

Answer 1

Hi David,
Not sure if I actually solved your issue. Any incorrect ring rotation has always thrown ORA-13367 as long as I have been around, 10g or 11g. In 10g you should never have seen true if any of your rings were originally backwards. And indeed its a big polygon but for example I have been doing some testing with "uber" polygons and just the other night was running SIMPLIFY on a polygon with 1.2 million vertices and it took a while (I went to bed) but in the morning it was done.
How are you testing ring rotation? I put a quickie function below. Are you doing things similarly? TO_CURRENT will actually reallocate rings from inner to outer if one is inside the other. But as part of the rearranging will always correct the ring orientation. In your case that seems not to have happened which is very odd. But perhaps this has something to do with the sheer number of polygons in the collection and how they interact (raw speculation). I would first try removing that particular polygon with SDO_UTIL.EXTRACT and see if there is anything squirrelly about it by itself.
Cheers,
Paul
CREATE OR REPLACE FUNCTION inspect_ordinate_rotation(
   p_input       IN  MDSYS.SDO_GEOMETRY,
   p_lower_bound IN  NUMBER DEFAULT 1,
   p_upper_bound IN  NUMBER DEFAULT NULL
) RETURN VARCHAR2
AS
   int_dims      PLS_INTEGER := p_input.get_dims();
   int_lb        PLS_INTEGER := p_lower_bound;
   int_ub        PLS_INTEGER := p_upper_bound;
   p_area        NUMBER;
   num_x         NUMBER;
   num_y         NUMBER;
   num_lastx     NUMBER;
   num_lasty     NUMBER;
BEGIN
   IF int_dims IS NULL
   THEN
     int_dims := 2;
   END IF;
   IF int_ub IS NULL
   THEN
      int_ub  := p_input.SDO_ORDINATES.COUNT;
   END IF;
   IF int_lb IS NULL
   THEN
      int_lb  := 1;
   END IF;
   p_area  := 0;
   num_lastx := 0;
   num_lasty := 0;
   WHILE int_lb <= int_ub
   LOOP
      num_x := p_input.SDO_ORDINATES(int_lb);
      num_y := p_input.SDO_ORDINATES(int_lb + 1);
      p_area := p_area + ( (num_lasty * num_x ) - ( num_lastx * num_y) );
      num_lastx := num_x;
      num_lasty := num_y;
      int_lb := int_lb + int_dims; 
   END LOOP;
   IF p_area > 0
   THEN
      RETURN 'CW';
   ELSE
      RETURN 'CCW';
   END IF;
END inspect_ordinate_rotation;