VBA & Word: Which Sections will be printed?

Question

I have implemented the event DocumentBeforePrint with Word 2013.
I've modified the backstage print view where the user can select a text (stamp) which will be inserted as a watermark and removed after the print has been done.
In the event DocumentBeforePrint I would like to get the information what the user wants to print (All of the document, or only certain sections of it.) Because setting the watermark in the Footer of each Section takes up some time and I would like to narrow
it down and insert the watermark only in the Section which will be printed.
Thanks for any help! Martin

Answer 1

In that case, you'd probably need to use a DocumentBeforePrint macro, coded along the lines of:
Private Sub wdApp_DocumentBeforePrint(ByVal Doc As Document, Cancel As Boolean)
Dim StrPrn As String, StrRng As String
'Retrieve the print parameters from the FilePrint Dialog
With Application.Dialogs(wdDialogFilePrint)
    'If Print =
    'All, StrPrn = 0
    'Current Page, StrPrn = 2
    'Pages, StrPrn = 4
    StrPrn = .Range
    'If StrPrn = 4, then StrRng holds the range to be printed
    StrRng = .Pages
End With
Select Case StrPrn
  Case 0: StrRng = "1" & "-" & ActiveDocument.Sections.Count
  Case 2: StrRng = Selection.Sections.First.Index
  Case 4
    If InStr(StrRng, "p") > 0 Then
      MsgBox "Please specify only Section #s", vbExclamation
      Cancel = True
      Exit Sub
    End If
    StrRng = Replace(StrRng, "s", "")
End Select
StrRng = ParseNumberString(StrRng, ",", "-")
'StrRng now holds an itemised list of Section #s for further processing
MsgBox StrRng
End Sub
Function ParseNumberString(StrIn As String, strSS, strGS)
Dim i As Long, j As Long, StrTmp As String, Arr As Variant
Arr = Filter(Split(StrIn, strSS), strGS)
For i = 0 To UBound(Arr)
  StrTmp = ""
  For j = Val(Arr(i)) To Split(Arr(i), strGS)(1)
    StrTmp = StrTmp & strSS & j
  Next
  StrIn = Replace(StrIn, Arr(i), Mid(StrTmp, 2))
Next
ParseNumberString = StrIn
End Function
To use code like this, see:
http://word.mvps.org/FAQs/MacrosVBA/InterceptSavePrint.htm
and:
http://word.mvps.org/FAQs/MacrosVBA/AppClassEvents.htm
Note that I haven't included the code that actually adds the watermarks - all it now outputs is a message box showing the sections to be processed. I'll leave that part to you. I also haven't tested whether you can actually reliably retrieve the required
data this way - you can indeed retrieve it from the Print Dialogue, but doing that directly ordinarily doesn't return the values you're interested in until after the print job has been submitted.
Cheers
Paul Edstein
[MS MVP - Word]