Web Services using UTL_DBWS

Question

Hiiiii Guys,
Can you pls give a simple working example of procedure through which we can call a web services. I have tried example given on oracle's site, but it seems its not working.
I have just installed oracle in my PC, so guys pls give me the names of extra JARs which are required
Thanks in advance
Cheers!!!
Vikas

Answer 1

Your question makes no sense in this forum.
This is the XML DB forum.
XML DB Native web services allows SQL statements and PL/SQL procedures packages and functions to be invoked from any client that understands how to process a WSDL withot requring any additional code or jars to be installed. It is a feature of database 11.1.x
If you are wanting to invoke a Web Service from PL/SQL code then you can do this with UTL_HTTP, again with no jars required..
DECLARE
  V_SOAP_REQUEST      XMLTYPE := XMLTYPE(
'<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:SOAP-ENC="http://schemas.xmlsoap.org/soap/encoding/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
     <SOAP-ENV:Body>
          <m:CXMLTYPE-POSTInput xmlns:m="http://xmlns.oracle.com/orawsv/SOAPTEST/POST">
               <m:P_REQUEST-XMLTYPE-IN><Request>4</Request></m:P_REQUEST-XMLTYPE-IN>
          </m:CXMLTYPE-POSTInput>
     </SOAP-ENV:Body>
</SOAP-ENV:Envelope>');
  V_SOAP_REQUEST_TEXT CLOB := V_SOAP_REQUEST.getClobVal();
  V_REQUEST           UTL_HTTP.REQ;
  V_RESPONSE          UTL_HTTP.RESP;
  V_BUFFER            VARCHAR2(32000);
  V_RESPONSE_TEXT     CLOB;
  V_RESPONSE_XML      XMLTYPE;
  V_WSDL              XMLTYPE;
BEGIN
     DBMS_LOB.CREATETEMPORARY(V_RESPONSE_TEXT, TRUE);
  begin
    V_REQUEST := UTL_HTTP.BEGIN_REQUEST(URL => :URL, METHOD => 'POST');
    UTL_HTTP.SET_HEADER(V_REQUEST, 'User-Agent', 'Mozilla/4.0');
    V_REQUEST.METHOD := 'POST';
    UTL_HTTP.SET_HEADER (R => V_REQUEST, NAME => 'Content-Length', VALUE => DBMS_LOB.GETLENGTH(V_SOAP_REQUEST_TEXT));
    UTL_HTTP.WRITE_TEXT (R => V_REQUEST, DATA => V_SOAP_REQUEST_TEXT);
    V_RESPONSE := UTL_HTTP.GET_RESPONSE(V_REQUEST);     
     LOOP
      UTL_HTTP.READ_LINE(V_RESPONSE, V_BUFFER, TRUE);
      if (LENGTH(V_BUFFER) > 0) then
        DBMS_LOB.WRITEAPPEND(V_RESPONSE_TEXT,LENGTH(V_BUFFER),V_BUFFER);  
      end if;
     END LOOP;
     UTL_HTTP.END_RESPONSE(V_RESPONSE);
  EXCEPTION
    WHEN UTL_HTTP.END_OF_BODY THEN
      UTL_HTTP.END_RESPONSE(V_RESPONSE);
  END;
  V_RESPONSE_XML := XMLTYPE(V_RESPONSE_TEXT);
  select XMLQUERY
           'declare namespace SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/"; (::)
            declare namespace SOAP-ENC="http://schemas.xmlsoap.org/soap/encoding/"; (::)
            declare namespace xsi="http://www.w3.org/2001/XMLSchema-instance"; (::)
            declare namespace xsd="http://www.w3.org/2001/XMLSchema"; (::)
            declare namespace m="http://xmlns.oracle.com/orawsv/WSDLTEST/TEST_CLOB"; (::)
            $resp/SOAP-ENV:Envelope/SOAP-ENV:Body/*'
            passing V_RESPONSE_XML as "resp" returning content
    into V_WSDL
    from DUAL;
  select V_WSDL.getClobVal()
    into :RESULT
    from dual;
     DBMS_LOB.FREETEMPORARY(V_RESPONSE_TEXT);
END;
/I've no idea about UTL_DBWS or why you would need it