Where is a good place to post a small Applescript job/project?

Question

I need a script involving image manipulation and server upload as a folder action. Where should I look for someone to write it for me?
The script should enable any person without knowledge about image-manipulation and/or FTP-clients to exchange magazine covers in a shop with the latest issue.
How I picture it would work for the user:
- There is a folder with subfolders named after magazines.
- Drag'n'drop a JPG or PNG on one of the subfolders.
- The script activates in the background and resizes the images to a width of 150px and renames it to "subfoldername".jpg (Maybe pictures can be made to JPG if any other format ...?) The old picture can be overwritten.
- The image is uploaded to a certain directory on a webserver (via FTP or ...?). There is only one directory for all images.
What would be a fair compensation for something like this?

Answer 1

Well, here =)
A fair compensation for this... if it saves you a lot of time, maybe 50$ if you just use it from time to time maybe just $20... don't know...
Here is the source-code for a drop-let. Just drag&drop an image file onto that App and it will be resized and uploaded via ftp. This should be a better way to trigger that event, since with your plan you would have to link a folderaction to each magazin folder.
So using this script you just update a text-file with all the magazin-names, and drag&drop the images onto the app (you can place it in your Dock, too)
You will have to change the properties in the source-code to make it fit your ftp-url, username&password.
A copy of the script (already saved as an applescript-droplet) can be downloaded here :
http://dl.dropbox.com/u/154308/AppleScriptForum/3039124/magazin_upload_folder.zi p
I have a nice paypal button @ my website $-)
--05.05.2011 hubionmac.com
-- script to resize and upload images files to an ftp server (renamed my a list of  names in a txt file)
property myuploadpath : "ftp://yoursite.com"
property myftpusername : "ftp_username"
property myftppassword : "ftp_password"
property web_width : 150
property jpeg_quality : 75
on open these
repeat with thefile in these
--get the paths to work with
set thefile to quoted form of (POSIX path of (thefile as alias))
if thefile ends with ".jpg'" or thefile ends with ".png" then
tell application "Finder" to set myfolder to POSIX path of (container of ((path to me) as alias) as alias) as text
set magazin_list to myfolder & "magazin_list.txt"
--get a list of all magazine Names in text file
set names to every paragraph of (do shell script "cat " & quoted form of magazin_list)
--ask the user for a name
set themagazin to (choose from list names) as text
--if the selection was not empty
if themagazin ≠ "false" then
--just create the output path
set theoutput_file to quoted form of (myfolder & "uploaded/" & themagazin & ".jpg")
--resize the image and save it to the destination-folder
do shell script "sips -s format jpeg --resampleWidth " & web_width & " -s formatOptions " & jpeg_quality & " " & thefile & " --out " & theoutput_file
my display_message("Image resized (" & themagazin & ".jpg)", 1)
--upload the image via ftp
try
do shell script "curl -T " & theoutput_file & " " & myuploadpath & " --user " & myftpusername & ":" & myftppassword
my display_message("Image uploaded (" & themagazin & ".jpg)", 1)
on error msg
my display_message("ERROR:" & return & msg & "(" & themagazin & ".jpg)", 1)
end try
end if
else
my display_message("ERROR:" & return & "this is not an image file...", 1)
end if
end repeat
end open
on display_message(msgTXT, msgTimeout)
tell application "System Events"
set isRunning to ¬
(count of (every process whose name is "GrowlHelperApp")) > 0
end tell
if isRunning = true then
tell application "GrowlHelperApp"
-- Make a list of all the notification types
-- that this script will ever send:
set the allNotificationsList to ¬
{"Status"}
-- Make a list of the notifications
-- that will be enabled by default.     
-- Those not enabled by default can be enabled later
-- in the 'Applications' tab of the growl prefpane.
set the enabledNotificationsList to ¬
{"Status"}
-- Register our script with growl.
-- You can optionally (as here) set a default icon
-- for this script's notifications.
register as application ¬
"Finder" all notifications allNotificationsList ¬
default notifications enabledNotificationsList ¬
icon of application "Finder"
-- Send a Notification...
notify with name ¬
"Status" title ¬
"Status" description ¬
msgTXT application name ¬
"Finder"
return true
end tell
else
activate
display dialog msgTXT giving up after msgTimeout
end if
end display_message