Why there is no output after running the procedure

Question

Hello everyone,
SQL> set serveroutput on size 1000000
SQL> set echo on
SQL> set feedback on
SQL> declare
  2     n number(19);
  3     v_startday varchar2(100) := '7/1/2013';
  4     v_owner varchar2(100) := 'SLIMSINTDM';
  5     v_audit_tab audit_var := audit_var();
  6     v_table_name varchar2(40);
  7     type cur_type is ref cursor;
  8     v_cur cur_type;
  9     v_first_name varchar2(100);
10     v_last_name varchar2(100);
11     v_out_tab varchar2(100);
12     v_lab_code varchar2(10);
13     v_sql varchar2(20000);
14     v_sql_1 varchar2(10000) := q'[
15     select distinct au.first_name, au.last_name,
16     :v_table_name table_name, lab_code
17     from laboratory l
18     join app_user_security aus on AUS.owning_lab_id = l.lab_id
19     join app_user au on AU.APP_USER_ID = AUS.APP_USER join ]';
20     v_sql_2 varchar2(10000) := q'[ t on (t.ADDED_BY = AU.APP_USER_ID
21     or t.last_modified_by = au.app_user_id)
22     where lab_locale = 'en_AU'
23     and (t.added_date > to_date(:v_startday, 'MM/DD/YYYY')
24     or t.last_modified_date > to_date(:v_startday, 'MM/DD/YYYY'))
25     order by last_name, first_name
26     ]';
27  begin
28     n := 0;
29     for i in (select table_name from all_tables where owner = v_owner order by table_name)
30     loop
31         v_table_name := substr(i.table_name, 1, instr(i.table_name, '_JN') - 1 );
32  --  dbms_output.put_line('v_table_name: ' || v_table_name ||' ; i.table_name: ' ||i.table_name);
33         v_sql := v_sql_1 || i.table_name || v_sql_2;
34  --  dbms_output.put_line(v_sql);
35         begin
36            open v_cur for v_sql using v_table_name, v_startday, v_startday;
37            loop
38               fetch v_cur into v_first_name, v_last_name, v_out_tab, v_lab_code;
39               exit when  v_cur%NOTFOUND;
40               n := n + 1;
41               v_audit_tab.extend;
42               v_audit_tab(n) := audit_type(v_first_name, v_last_name, v_out_tab, v_lab_code);
43            end loop;
44            close v_cur;
45         exception
46           when others then
47              if sqlcode = -1030 then -- insufficient privs
48                 dbms_output.put_line('No privs for ' || USER || ' on ' || i.table_name);
49  --                  exit;
50              end if;
51         end;
52     end loop;
53      for x in (select * from table(v_audit_tab))
54      loop
55        dbms_output.put_line (x.first_name ||','||x.last_name||','||x.table_name||','||x.lab_code);
56      end loop;
57  end;
58  /
PL/SQL procedure successfully completed.
Question here ,  developer can't find any output (results) as expected after running this procedure, so is ther anything wrong?
Thank you very much.

Answer 1

There is a good chance that there is another error other than -1030 but it is  going into the bit bucket never to be seen.  Check out Oracle Magazine articles on PL/SQL (http://www.oracle.com/technetwork/issue-archive/index-087690.html) for some good coding practices. Part 6, PLSQL: Error Management is relevant to exception handling. 
You could use a PRAGMA EXCEPTION INIT(InsufficientPriv,-1030); in the declaration section and then do the following:
EXCEPTION
  WHEN InsufficientPrivs THEN
     dbms_output.put_line('No privs for ' || USER || ' on ' || i.table_name);
  WHEN OTHERS THEN
    dbms_output.put_line('Other Error: '||SQLERRM);
END;
or following your example
exception
   when others then
       if sqlcode = -1030 then -- insufficient privs
           dbms_output.put_line('No privs for ' || USER || ' on ' || i.table_name);
           -- raise;if you want to exit this block and not continue.
        else
           dbms_output.put_line('Other Error: '||SQLERRM);
           -- raise;if you want to exit this block and not continue.
       end if;
end;