Writing generated XML into a file after comparing with other XML

Question

Hi,
  I have completed the comparison of two XML now I have a requirement to concat these two xml but also need to append the XML with a status node that if after comparing the two XML output is Y or N so if it is Y then a node with
<status>Y</status>
<from table>t1</from table>
then completing those task I need to write it in a file
declare
    p_emp_info   CLOB;
  l_emp_tab        xmlsequencetype := xmlsequencetype();
BEGIN
  FOR i IN (SELECT id from emp WHERE emp_name='ABC') LOOP
    l_emp_tab.extend;
    SELECT XMLELEMENT("ABCD",
           XMLELEMENT("id",i.id))
      INTO l_emp_tab(i)
      FROM dual;
END LOOP;
  SELECT XMLELEMENT("EMP"
                       ,XMLAGG(t.column_value))
    INTO p_emp_info  
    FROM TABLE(l_emp_tab) t;
    --Dbms_Output.put_line(getclobval(1,2));
EXCEPTION
    WHEN OTHERS THEN
   Dbms_Output.put_line(SQLCODE||sqlerrm);
END ;
I am using this query but it is giving me an error that expression is of wrong type  at this line {  INTO l_emp_tab(I) }
I am unable to find out the error that what I am missing here !!

Answer 1

You've changed the datatype of i from the example that Odie gave you in
repeating nodes using FOR loop but when concating XML string then concating only last iteration of FOr loop ??
In his example, i was a number.  In your above code, i is now the rowset for a cursor.
You could rewrite your version to look like
declare
  p_emp_info     XMLTYPE;
  l_emp_tab      xmlsequencetype := xmlsequencetype();
  l_pos          PLS_INTEGER;
  CURSOR c_info IS
    SELECT id
      from emp
     WHERE emp_name='ABC';
BEGIN
  FOR r_info IN c_info LOOP
    l_emp_tab.extend;
    l_pos := c_info%ROWCOUNT;
    SELECT XMLELEMENT("ABCD",
           XMLELEMENT("id",r_info.id))
      INTO l_emp_tab(l_pos)
      FROM dual;
  END LOOP;
  SELECT XMLELEMENT("EMP"
                       ,XMLAGG(t.column_value))
    INTO p_emp_info 
    FROM TABLE(l_emp_tab) t;
  --Dbms_Output.put_line(p_emp_info.getclobval());
END ;
You can't use the c_info%ROWCOUNT in the INTO clause, hence the need for l_pos.
Or you could rewrite it to be
declare
  p_emp_info   XMLTYPE;
  l_clob       CLOB;
BEGIN
  SELECT XMLElement("EMP",
           XMLAgg(XMLElement("ABCD",
                    XMLElement("id",e.id))))
    INTO p_emp_info
    FROM emp e
   WHERE emp_name = 'ABC';
  SELECT XMLSERIALIZE(DOCUMENT p_emp_info AS CLOB)
    INTO l_clob
    FROM DUAL;
  Dbms_Output.put_line(l_clob);
END;
Both produce the same XML.