XDB creation of folders with PL/SQL problem

Question

Hi Forum,
I'm struggling with the problem of creating folders and resources automatically using PL/SQL. I'm working with Oracle 9.2
What I'd like to achieve is a proc like so:
create_folder(path in varchar2)
This proc should create the folder for me. Problem is:
1. If a subfolder is not existing, dbms_xdb.create_folder throws an error.
2. If a folder is existing, the same happens.
So my approach is:
split the path '/a/b/c/d/test.xml' into chunks like:
/a
/a/b
/a/b/c
/a/b/c/d
Now, check for each entry, whether folder exists. If not, create folder.
The way I implemented this is by a pipelined PL/SQL function split_path:
create type path_table as table of varchar2;
create or replace function split_path (path in varchar2)
return path_table pipelined
is
i number := 1;
begin
while instr(path, '/', 2, i) > 0 loop
pipe row (substr(path, 1, instr(path, '/', 2, i) - 1));
i := i + 1;
end loop;
return;
end split_path;
This function pumps out any sub-path.
Now, I create a create_folder function like so:
procedure create_folder (path in varchar2)
is
i number := 1;
-- cursor for all non-existing pathes (via pipelined function split_path)
cursor path_cur is
select column_value
from table(mds_tools.split_path(path))
where column_value not in (select any_path from resource_view);
begin
-- Create all non-existing folders
for entry in path_cur loop
result := dbms_xdb.createFolder(entry.column_value);
end loop;
-- exception handling goes here
end create_folder;
So, this way, I'm checking any sub folder against the existing cursors and try to create a folder if it's not existing.
Nice try, so far, but: It doesn't work.
Oracle gives me an "End of communication" error, when trying to run this.
It seems to bomb out as soon as the second pipe is pumped out of the function and I don't understand, why.
If this should be the wrong approach, how could I improve this?
Thanks for any help,
Jürgen

Answer 1

The createDirectoryTree procedure in the following package may help...
-- XDB_HELPER should be created under XDBPM
alter session set current_schema = XDBPM
create or replace package XDB_UTILITIES_10200
AUTHID CURRENT_USER
as
   function getBinaryContent(file bfile) return BLOB;
   function getBinaryContent(filename varchar2, directoryName varchar2 default USER) return BLOB;
   function getBinaryContent(file bfile, tempBLOB IN OUT BLOB) return BLOB;
   function getBinaryContent(filename varchar2, directoryName varchar2 default USER, tempBLOB IN OUT BLOB) return BLOB;
   function getFileContent(file bfile, charset varchar2 default 'WE8MSWIN1252') return CLOB;
   function getFileContent(filename varchar2, directoryName varchar2 default USER, charset varchar2 default 'WE8MSWIN1252') return CLOB;
   function getFileContent(file bfile, charset varchar2 default 'WE8MSWIN1252', tempCLOB IN OUT CLOB) return CLOB;
   function getFileContent(filename varchar2, directoryName varchar2 default USER, charset varchar2 default 'WE8MSWIN1252', tempCLOB IN OUT CLOB) return CLOB;
   procedure createHomeFolder(userName varchar2);
   procedure createPublicFolder;
   procedure createDirectoryTree(path varchar2);
   procedure uploadFiles(FILE_LIST varchar2 default 'ls.xml', UPLOAD_DIRECTORY_NAME varchar2 default USER, REPOSITORY_FOLDER_PATH varchar2 default '/home/' || USER , BATCH_SIZE number default 1);
   procedure put_xml(XML XMLTYPE);
   function printNestedTables(XML_TABLE varchar2) return XMLType;
   procedure printXMLToFile(xmlContent XMLType, targetDirectory varchar2, Filename VARCHAR2);
   function  getDefaultTableName(PATH VARCHAR2) return VARCHAR2;
   function  getXMLReference(PATH VARCHAR2) return REF XMLType;
   function  getXMLReferenceByResID(RESOID RAW) return REF XMLType;
   function getVersionsByPath(path VARCHAR2) return RESOURCE_ID_TABLE pipelined;
   function getVersionsByResid(RESID RAW) return RESOURCE_ID_TABLE pipelined;
   function isCheckedOut(PATH VARCHAR2) return number;
   function isCheckedOutByRESID(RESOID RAW) return number;
   procedure updateXMLContent(path VARCHAR2, content XMLType);
   procedure updateBinaryContent(path VARCHAR2,content BLOB);
   procedure updateCharacterContent(path VARCHAR2,content CLOB,db_charset VARCHAR2);
   procedure renameCollectionTable (XMLTABLE varchar2, XPATH varchar2, COLLECTION_TABLE_PREFIX varchar2);
end XDB_UTILITIES_10200;
show errors
create or replace package body XDB_UTILITIES_10200
as
-- When using getFileContent() the application must explicitly free the CLOB that the function returns
function getBinaryContent(file bfile,
                    tempBLOB IN OUT BLOB)
return BLOB
is
  targetFile      bfile;
  dest_offset     number :=  1;
  src_offset      number := 1;
  lang_context    number := 0;
  conv_warning    number := 0;
  begin
    targetFile := file;
    if (tempBLOB is null) then
      DBMS_LOB.createTemporary(tempBLOB,true,DBMS_LOB.SESSION);
    else
      DBMS_LOB.trim(tempBLOB,0);
    end if;
    DBMS_LOB.fileopen(targetFile, DBMS_LOB.file_readonly);
    DBMS_LOB.loadBlobfromFile
       tempBLOB,
       targetFile,
       DBMS_LOB.getLength(targetFile),
       dest_offset,
       src_offset
    DBMS_LOB.fileclose(targetFile);
    return tempBLOB;
end;
function getBinaryContent(file bfile)
return BLOB
is
  tempBLOB BLOB := NULL;
begin
  return getBinaryContent(file,tempBLOB);
end;
function getBinaryContent(filename varchar2,
                          directoryName varchar2 default USER,
                    tempBLOB IN OUT BLOB)
return BLOB
is
   file            bfile := bfilename(directoryName,filename);
begin
  return getBinaryContent(file,tempBLOB);
end;
function getBinaryContent(filename varchar2,
                          directoryName varchar2 default USER)               
return BLOB
is
   tempBLOB BLOB := NULL;
begin
  return getBinaryContent(filename,directoryName,tempBLOB);
end;
function getFileContent(file bfile,
                  charset varchar2 default 'WE8MSWIN1252',
                  tempCLOB IN OUT CLOB)
return CLOB
is
  targetFile      bfile;
  dest_offset     number :=  1;
  src_offset      number := 1;
  lang_context    number := 0;
  conv_warning    number := 0;
  begin
    targetFile := file;
    if (tempCLOB is null) then
      DBMS_LOB.createTemporary(tempCLOB,true,DBMS_LOB.SESSION);
    else
      DBMS_LOB.trim(tempCLOB,0);
    end if;
    DBMS_LOB.fileopen(targetFile, DBMS_LOB.file_readonly);
    DBMS_LOB.loadClobfromFile
       tempCLOB,
       targetFile,
       DBMS_LOB.getLength(targetFile),
       dest_offset,
       src_offset,
       nls_charset_id(charset),
       lang_context,
       conv_warning
    DBMS_LOB.fileclose(targetFile);
    return tempCLOB;
end;
function getFileContent(file bfile,
                  charset varchar2 default 'WE8MSWIN1252')
return CLOB
is
  tempCLOB CLOB := NULL;
begin
  return getFileContent(file,charset,tempCLOB);
end;
-- When using getFileContent() the application must explicitly free the CLOB that the function returns
function getFileContent(filename varchar2,
                        directoryName varchar2 default USER,
                  charset varchar2 default 'WE8MSWIN1252',
                  tempCLOB IN OUT CLOB)
return CLOB
is
   file            bfile := bfilename(directoryName,filename);
begin
  return getFileContent(file,charset,tempCLOB);
end;
function getFileContent(filename varchar2,
                        directoryName varchar2 default USER,
                  charset varchar2 default 'WE8MSWIN1252')               
return CLOB
is
   tempCLOB CLOB := NULL;
begin
  return getFileContent(filename,directoryName,charset,tempCLOB);
end;
procedure createHomeFolder(userName varchar2)
as
  targetResource varchar2(256);
  realUserName varchar2(64);
  result boolean;
begin
  realUserName := upper(userName);
  targetResource := '/home';
  if (not dbms_xdb.existsResource(targetResource)) then
    result := dbms_xdb.createFolder(targetResource);
    dbms_xdb.setAcl(targetResource,'/sys/acls/bootstrap_acl.xml');
    update RESOURCE_VIEW
       set res = insertChildXML
                   res,
                   '/Resource',
                   'Comment',
                   xmlelement("Comment",'Contains home folder for each XDB User.')
     where equals_path(res,targetResource) = 1;
  end if;
  targetResource := targetResource || '/' || realUserName;
  if (not dbms_xdb.existsResource(targetResource)) then
    result := dbms_xdb.createFolder(targetResource);
    update RESOURCE_VIEW
       set res = insertChildXML
                   res,
                   '/Resource',
                   'Comment',
                   xmlelement("Comment", realUserName || '''s home folder.')
     where equals_path(res,targetResource) = 1;
  end if;
  dbms_xdb.setAcl(targetResource,'/sys/acls/all_owner_acl.xml');
  update resource_view
         set res = updateXml(res,'/Resource/Owner/text()',realUserName)
  where equals_path(res,targetResource) = 1;
end;
procedure createPublicFolder
as
begin
   xdb_helper.createPublicFolder(USER);
end;
procedure createDirectoryTree(path varchar2)
as
  pathSeperator varchar2(1) := '/';
  parentFolderPath varchar2(256);
  result boolean;
  folderExists number(6):= 1;
begin
  -- dbms_output.put_line('Processing ' || path);
  select count(*)
  into folderExists
  from resource_view
  where equals_path(res,path) = 1;
  -- dbms_output.put_line('FolderExists = ' || folderExists);
  if (folderExists = 0) then
    parentFolderPath := substr(path,1,instr(path,pathSeperator,-1)-1);
    -- dbms_output.put_line('FolderExists = ' || FolderExists);   
    createDirectoryTree(parentFolderPath);
    result := dbms_xdb.createFolder(path);
  end if;
end;
procedure uploadFiles(FILE_LIST varchar2 default 'ls.xml', UPLOAD_DIRECTORY_NAME varchar2 default USER, REPOSITORY_FOLDER_PATH varchar2 default '/home/' || USER , BATCH_SIZE number default 1)
as
  pathSeperator varchar2(1) := '/';
  DIRECTORY_PATH      varchar2(256); 
  SUBDIRECTORY_PATH   varchar2(256);
  TARGET_FOLDER_PATH  varchar2(256);
  TARGET_FILE_PATH    varchar2(256);
  TARGET_FILE_NAME    varchar2(256);
  RESOURCE_PATH       varchar2(256);
  sqlStatement        varchar2(256);
  FILELIST_XML        XMLTYPE := XMLType(bfilename(UPLOAD_DIRECTORY_NAME,FILE_LIST),nls_charset_id('AL32UTF8'));
  CONTENT_XML         XMLType;
  result              boolean;
  filecount           binary_integer := 0;
  FILELIST_DOM    DBMS_XMLDOM.DOMDOCUMENT;
  FILES_NL        DBMS_XMLDOM.DOMNODELIST;
  DIRECTORY_NL    DBMS_XMLDOM.DOMNODELIST;
  FILENAME_NL     DBMS_XMLDOM.DOMNODELIST;
  FILES_NODE      DBMS_XMLDOM.DOMNODE;
  DIRECTORY_NODE  DBMS_XMLDOM.DOMNODE;
  FILE_NODE       DBMS_XMLDOM.DOMNODE;
  TEXT_NODE       DBMS_XMLDOM.DOMNODE;
  ENCODING_ATTR   DBMS_XMLDOM.DOMATTR;
  REPLACE_ATTR    DBMS_XMLDOM.DOMATTR;
  PATH            VARCHAR2(256);
  FILE_NAME       VARCHAR2(256);
  ENCODING_TEXT   VARCHAR2(32);
  ATTR_VALUE      VARCHAR2(256);
  REPLACE_OPTION  BOOLEAN; 
  REPLACE_DEFAULT BOOLEAN;
  DEBUG_BUFFER    VARCHAR2(255);
begin
  -- Create the set of Folders in the XDB Repository
  FILELIST_DOM := DBMS_XMLDOM.newDOMDocument(FILELIST_XML);
  DIRECTORY_NL := DBMS_XMLDOM.GETELEMENTSBYTAGNAME(FILELIST_DOM,'directory');
  FOR i in 0 .. (DBMS_XMLDOM.GETLENGTH(DIRECTORY_NL) - 1) LOOP
    DIRECTORY_NODE := DBMS_XMLDOM.ITEM(DIRECTORY_NL,i);
    TEXT_NODE      := DBMS_XMLDOM.GETFIRSTCHILD(DIRECTORY_NODE);
    DIRECTORY_PATH := DBMS_XMLDOM.GETNODEVALUE(TEXT_NODE);
    DIRECTORY_PATH := REPOSITORY_FOLDER_PATH || DIRECTORY_PATH;
    createDirectoryTree(DIRECTORY_PATH);
  END LOOP;
  -- Load the Resources into the XML DB Repository
  FILES_NL           := DBMS_XMLDOM.GETELEMENTSBYTAGNAME(FILELIST_DOM,'files');
  FILES_NODE         := DBMS_XMLDOM.ITEM(FILES_NL,0);
  REPLACE_DEFAULT    := FALSE;
  REPLACE_ATTR       := DBMS_XMLDOM.getAttributeNode(DBMS_XMLDOM.MAKEELEMENT(FILES_NODE),'replace');
  if not (DBMS_XMLDOM.ISNULL(REPLACE_ATTR)) then
    REPLACE_DEFAULT  := xdb_dom_helper.varchar_to_boolean(DBMS_XMLDOM.getVALUE(REPLACE_ATTR));
  end if;
  FILENAME_NL := DBMS_XMLDOM.GETELEMENTSBYTAGNAME(FILELIST_DOM,'file');
  FOR i in 0 .. (DBMS_XMLDOM.GETLENGTH(FILENAME_NL) - 1) LOOP
    FILE_NODE          := DBMS_XMLDOM.ITEM(FILENAME_NL,i);
    TEXT_NODE          := DBMS_XMLDOM.GETFIRSTCHILD(FILE_NODE);
    TARGET_FILE_PATH   := DBMS_XMLDOM.GETNODEVALUE(TEXT_NODE);
    TARGET_FILE_NAME   := substr(TARGET_FILE_PATH,instr(TARGET_FILE_PATH,pathSeperator,-1)+1);
    TARGET_FOLDER_PATH := substr(TARGET_FILE_PATH,1,instr(TARGET_FILE_PATH,pathSeperator,-1));
    TARGET_FOLDER_PATH := substr(TARGET_FOLDER_PATH,instr(TARGET_FOLDER_PATH,pathSeperator));
    TARGET_FOLDER_PATH := substr(TARGET_FOLDER_PATH,1,length(TARGET_FOLDER_PATH)-1);
    RESOURCE_PATH := REPOSITORY_FOLDER_PATH || TARGET_FOLDER_PATH || '/' || TARGET_FILE_NAME;
    -- dbms_output.put_line('Source =  ' || TARGET_FILE_PATH);
    -- dbms_output.put_line('File =  ' || TARGET_FILE_NAME);
    -- dbms_output.put_line('Target = ' || RESOURCE_PATH);
    ENCODING_ATTR      := DBMS_XMLDOM.getAttributeNode(DBMS_XMLDOM.MAKEELEMENT(FILE_NODE),'encoding');
    ENCODING_TEXT      := 'AL32UTF8';
    if not (DBMS_XMLDOM.ISNULL(ENCODING_ATTR)) then
      ENCODING_TEXT    := DBMS_XMLDOM.getValue(ENCODING_ATTR);
      dbms_output.put_line('Encoding for ' || TARGET_FILE_NAME || ' =  ' || ENCODING_TEXT);     
    end if;
    REPLACE_ATTR       := DBMS_XMLDOM.getAttributeNode(DBMS_XMLDOM.MAKEELEMENT(FILE_NODE),'Replace');
    REPLACE_OPTION     := REPLACE_DEFAULT;
    if not (DBMS_XMLDOM.ISNULL(REPLACE_ATTR)) then
      REPLACE_OPTION   := xdb_dom_helper.varchar_to_boolean(DBMS_XMLDOM.getValue(REPLACE_ATTR));
    end if;
    CONTENT_XML := xmltype(bfilename(UPLOAD_DIRECTORY_NAME,TARGET_FILE_PATH),nls_charset_id(ENCODING_TEXT));
    if (REPLACE_OPTION and dbms_xdb.existsResource(RESOURCE_PATH)) then
      dbms_xdb.deleteResource(RESOURCE_PATH);
    end if;
    result := dbms_xdb.createResource(RESOURCE_PATH,CONTENT_XML);
    filecount := filecount + 1;
    if (filecount = BATCH_SIZE) then
      filecount := 0;
      commit;
    end if;
  END LOOP;
end;
procedure put_xml(XML XMLTYPE)
as
  buffer CLOB;
  offset binary_integer := 1;
  maxLength binary_integer;
  endofLine binary_integer := 1;
  linesize binary_integer;
begin
  buffer    := xml.getClobVal();
  maxLength := dbms_lob.getLength(buffer);
  endofline := dbms_lob.instr(buffer,chr(10),offset,1);
  while (endofLine > 0) loop
     linesize  := endofline - offset;
     if (linesize > 255) then
       dbms_output.put_line(dbms_lob.substr(buffer,255,offset));
       offset := offset + 255;
     else
       dbms_output.put_line(dbms_lob.substr(buffer,linesize,offset));
       offset := offset + linesize + 1;
     end if;
     endofline := dbms_lob.instr(buffer,chr(10),offset,1);
  end loop;
  linesize := maxLength - offset;
  dbms_output.put_line(dbms_lob.substr(buffer,linesize+1,offset));
end;
function getDefaultTableName(path varchar2)
return varchar2
as
  targetURL   varchar2(4096);
  schemaURL   varchar2(1024);
  elementName varchar2(2000);
  defaultTableName  varchar2(32);
begin
  select extractValue(res,'/Resource/SchemaElement')
    into targetURL
    from resource_view
   where equals_path(res,path) = 1;
  schemaURL := substr(targetURL,1,instr(targetURL,'#')-1);
  elementName := substr(targetURL,instr(targetURL,'#')+1);
  select extractValue
            schema,
            '/xsd:schema/xsd:element[@name="' || elementName || '"]/@xdb:defaultTable',
            xdb_namespaces.XMLSCHEMA_PREFIX_XSD || ' ' || xdb_namespaces.XDBSCHEMA_PREFIX_XDB
    into defaultTableName
    from user_xml_schemas
   where schema_URL = schemaURL;
  -- dbms_output.put_line('schemaURL = ' || schemaURL);
  -- dbms_output.put_line('XPath = ' || '/xsd:schema/xsd:element[@name="' || elementName || '"]/@xdb:defaultTable');
  -- dbms_output.put_line('Namespaces = ' || xdb_namespaces.XMLSCHEMA_PREFIX_XSD || ' ' || xdb_namespaces.XDBSCHEMA_PREFIX_XDB );
  -- dbms_output.put_line('Default Table = ' || defaultTableName );
  return defaultTableName;
end;
function getXMLReferenceByResID(resoid RAW)
return REF XMLType
as
begin
  return xdb_helper.getXMLReferenceByResID(resoid);
end;
function getXMLReference(path varchar2)
return REF XMLType
as
begin
  return xdb_helper.getXMLReference(path);
end;
function isCheckedOut(PATH VARCHAR2)
return number
as
begin
  return xdb_helper.isCheckedOut(PATH);
end;
function isCheckedOutbyRESID(RESOID RAW)
return number
as
begin
  return xdb_helper.isCheckedOutByRESID(RESOID);
end;
procedure cloneXMLContent(path varchar2)
as
begin
  update resource_view
     set res = updateXML(res,'/Resource/DisplayName',extract(res,'/Resource/DisplayName'))
   where equals_path(res, path) = 1;
end;
procedure updateXMLContent(path varchar2, content xmltype)
as
   defaultTableName varchar2(32);
   sqlStatement varchar2(1000);
begin
   defaultTableName := getDefaultTableName(path);
   cloneXMLContent(path);
   sqlStatement := 'update "' || defaultTableName || '" d set object_value = :1 where ref(d) = xdb_utilities.getXMLReference(:2)';
   dbms_output.put_line('SQL Statement ' || sqlStatement);
   execute immediate sqlStatement using content , path;
end;
procedure renameCollectionTable (XMLTABLE varchar2, XPATH varchar2, COLLECTION_TABLE_PREFIX varchar2)
as
   SYSTEM_GENERATED_NAME varchar2(256);
   COLLECTION_TABLE_NAME varchar2(256);
   CLUSTERED_INDEX_NAME  varchar2(256);
   PARENT_INDEX_NAME     varchar2(256);
   RENAME_STATEMENT varchar2(4000);
begin
   COLLECTION_TABLE_NAME := COLLECTION_TABLE_PREFIX || '_TABLE';
   CLUSTERED_INDEX_NAME := COLLECTION_TABLE_PREFIX || '_DATA';
   PARENT_INDEX_NAME := COLLECTION_TABLE_PREFIX || '_LIST';
   select TABLE_NAME
     into SYSTEM_GENERATED_NAME
     from ALL_NESTED_TABLES
    where PARENT_TABLE_NAME = XMLTABLE
      and PARENT_TABLE_COLUMN = XPATH
      and OWNER = USER;
   RENAME_STATEMENT := 'alter table ' || USER || '."' || SYSTEM_GENERATED_NAME || '" rename to "' ||COLLECTION_TABLE_NAME || '"';
   -- dbms_output.put_line(RENAME_STATEMENT);
   execute immediate RENAME_STATEMENT;
   begin
     select INDEX_NAME
       into SYSTEM_GENERATED_NAME
       from ALL_INDEXES
      where TABLE_NAME = COLLECTION_TABLE_NAME
        and INDEX_TYPE = 'IOT - TOP'
        and OWNER = USER;
     RENAME_STATEMENT := 'alter index ' || USER || '."' || SYSTEM_GENERATED_NAME || '" rename to "' || CLUSTERED_INDEX_NAME || '"';
     -- dbms_output.put_line(RENAME_STATEMENT);
     execute immediate RENAME_STATEMENT;
   exception
     when NO_DATA_FOUND then
       null;
   end;
   begin
     select INDEX_NAME
       into SYSTEM_GENERATED_NAME
       from ALL_IND_COLUMNS
      where COLUMN_NAME = XPATH
        and TABLE_NAME =  XMLTABLE
        and TABLE_OWNER = USER;
     RENAME_STATEMENT := 'alter index ' || USER || '."' || SYSTEM_GENERATED_NAME || '" rename to "' || PARENT_INDEX_NAME || '"';
     -- dbms_output.put_line(RENAME_STATEMENT);
     execute immediate RENAME_STATEMENT;
   exception
     when NO_DATA_FOUND then
       null;
   end;
end;
function processNestedTable(currentLevel in out number, currentNode in out XMLType, query SYS_REFCURSOR)
return XMLType
is
  thisLevel  number;
  thisNode   xmlType;
  result xmlType;
begin
  thisLevel := currentLevel;
  thisNode := currentNode;
  fetch query into currentLevel, currentNode;
  if (query%NOTFOUND) then
    currentLevel := -1;
  end if;
  while (currentLevel >= thisLevel) loop
    -- Next Node is a decendant of sibling of this Node.
    if (currentLevel > thisLevel) then
      -- Next Node is a decendant of this Node.
      result := processNestedTable(currentLevel, currentNode, query);
      select xmlElement
                "Collection",
                extract(thisNode,'/Collection/*'),
                xmlElement
                  "NestedCollections",
                  result
         into thisNode
         from dual;
    else
      -- Next node is a sibling of this Node.
      result := processNestedTable(currentLevel, currentNode, query);
      select xmlconcat(thisNode,result) into thisNode from dual;
    end if;
  end loop;
  -- Next Node is a sibling of some ancestor of this node.
  return thisNode;
end;
function printNestedTables(XML_TABLE varchar2)
return XMLType
is
   query SYS_REFCURSOR;
   result XMLType;
   rootLevel number := 0;
   rootNode xmlType;
begin
   open query for
        select level, xmlElement
                        "Collection",
                        xmlElement
                          "CollectionId",
                          PARENT_TABLE_COLUMN
                      ) as XML
          from USER_NESTED_TABLES
       connect by PRIOR TABLE_NAME = PARENT_TABLE_NAME
               start with PARENT_TABLE_NAME = XML_TABLE;
    fetch query into rootLevel, rootNode;
    result := processNestedTable(rootLevel, rootNode, query);
    select xmlElement
              "NestedTableStructure",
              result
      into result
      from dual;
    return result;
end;
procedure printXMLToFile(xmlContent XMLType, targetDirectory varchar2, Filename VARCHAR2)
is
   fHandle utl_file.File_Type;
   xmlText CLOB := xmlContent.getClobVal();
   xmlTextCopy CLOB;
   xmlTextSize binary_integer := dbms_lob.getLength(xmlText) + 1;
   offset    binary_integer := 1;
   buffer    varchar2(32767);
   linesize  binary_integer := 32767;
   byteCount binary_integer;
   lob1 clob;
begin
   dbms_lob.createtemporary(xmlTextCopy,TRUE);
   dbms_lob.copy(xmlTextCopy, xmlText, xmlTextSize);
   -- dbms_output.put_line('Text Size = ' ||  xmlTextSize);
   fhandle  := utl_file.fopen(targetDirectory,Filename,'w',linesize);
   while (offset < xmlTextSize)  loop
     if (xmlTextSize - offset > linesize) then
       byteCount := linesize;
     else
       byteCount := xmlTextSize - offset;
     end if;
     -- dbms_output.put_line('Offset = ' || Offset || ' ByteCount = '|| byteCount);
     dbms_lob.read(xmlTextCopy, byteCount, offset, buffer);
     -- dbms_output.put_line('After Read : ByteCount = '|| byteCount);
     offset := offset + byteCount;
     utl_file.put(fHandle, buffer);
     utl_file.fflush(fHandle);
   end loop;
   utl_file.new_line(fhandle);
   utl_file.fclose(fhandle);
   dbms_lob.freeTemporary(xmlTextCopy);
end;
procedure updateBinaryContent(path VARCHAR2,content BLOB)
is
  xmllob BLOB;
begin
  update RESOURCE_VIEW
     set res = updateXML(res,'/Resource/DisplayName/text()',extractValue(res,'/Resource/DisplayName/text()'))
   where equals_path(res,path) = 1;
  select extractValue(res,'/Resource/XMLLob')
    into xmllob
    from RESOURCE_VIEW
   where equals_path(res,path) = 1;
  dbms_lob.open(xmllob,dbms_lob.lob_readwrite);
  dbms_lob.trim(xmllob,0);
  dbms_lob.copy(xmllob,content,dbms_lob.getLength(content),1,1);
  dbms_lob.close(xmllob);
end;
procedure updateCharacterContent(path VARCHAR2,content CLOB,db_charset VARCHAR2)
is
  xmllob        BLOB;
  source_offset integer := 1;
  target_offset integer := 1;
  warning       integer;
  lang_context  integer := 0;
begin
  update RESOURCE_VIEW
     set res = updateXML(res,'/Resource/DisplayName/text()',extractValue(res,'/Resource/DisplayName/text()'))
   where equals_path(res,path) = 1;
  select extractValue(res,'/Resource/XMLLob')
    into xmllob
    from RESOURCE_VIEW
   where equals_path(res,path) = 1;
  dbms_lob.open(xmllob,dbms_lob.lob_readwrite);
  dbms_lob.trim(xmllob,0);
  dbms_lob.convertToBlob(xmllob,content,dbms_lob.getLength(content),source_offset,target_offset,nls_charset_id(db_charset),lang_context,warning);
  dbms_lob.close(xmllob);
end;
function getVersionsByPath(path VARCHAR2)
return RESOURCE_ID_TABLE pipelined
as
  RESOURCE_ID raw(16);
  SOURCE_LIST DBMS_XDB_VERSION.RESID_LIST_TYPE;
begin
  select resid
    into RESOURCE_ID
    from resource_view
   where equals_path(res,path) = 1;
  pipe row (RESOURCE_ID);
  SOURCE_LIST := DBMS_XDB_VERSION.GETPREDECESSORS(PATH);
  while SOURCE_LIST.COUNT > 0 loop
    pipe row (SOURCE_LIST(1));
    SOURCE_LIST := DBMS_XDB_VERSION.GETPREDSBYRESID(SOURCE_LIST(1));
  end loop;
  return;
end;
function getVersionsByResid(RESID RAW)
return RESOURCE_ID_TABLE pipelined
as
  SOURCE_LIST DBMS_XDB_VERSION.RESID_LIST_TYPE;
begin
  pipe row (RESID);
  SOURCE_LIST := DBMS_XDB_VERSION.GETPREDSBYRESID(RESID);
  while SOURCE_LIST.COUNT > 0 loop
    pipe row (SOURCE_LIST(1));
    SOURCE_LIST := DBMS_XDB_VERSION.GETPREDSBYRESID(SOURCE_LIST(1));
  end loop;
  return;
end;
end XDB_UTILITIES_10200;
show errors
grant execute on XDB_UTILITIES_10200 to public
create or replace public synonym XDB_UTILITIES for XDB_UTILITIES_10200
desc XDB_UTILITIES
alter session set current_schema = SYS
/